CMD/BAT

megaloman · Отправлено: **19:09, 01-04-2018** | #2

Цитата Alexander_88:

К примеру нужный нам файл "hello world - 15" (в скрипте мы должны указать его имя без цифры) »

Без числа, ИМХО. Каким образом? "hello world"? "hello world - "?
"-" обязательно обрамляются пробелами " - "?

Iska · Отправлено: **19:36, 01-04-2018** | #3

Цитата Alexander_88:

цифра в имени нужного файла »

Цитата Alexander_88:

К примеру нужный нам файл "hello world - 15" »

Тогда не «цифра». Число.

Цитата Alexander_88:

(в скрипте мы должны указать его имя без цифры) »

Зачем указывать в самом пакетном файле, а не параметром пакетного файла? Зачем указывать имя без числа, а не просто имя? И с какого тогда числа начинать перебор значений в сторону уменьшения (пакетные файлы хоть и ограничены, но позволяют манипулировать относительно большими числами)?

Alexander_88 · Отправлено: **20:11, 01-04-2018** | #4

Цитата megaloman:

Без числа, ИМХО. Каким образом? "hello world"? "hello world - "?
»

забыл я одно.. пару файлов у меня с цифрами (которые уменьшать не надо.. нужно уменьшать только те числа, которые в конце имени).
Пусть в скрипте я буду указывать все символы до числа (которое нужно уменьшать)...
пример.. для файлов
1 - "hello world - 15"
2 - "windows 3 - 12"
3 - "guten tag 2 - 25"

В соответствующих скриптах мы будет указывать:
1 - "hello world - "
2 - "windows 3 - "
3 - "guten tag 2 - "

Цитата megaloman:

"-" обязательно обрамляются пробелами " - "? »

В имени файла бывают пробелы, а именно дефис нет, не обязательно, я просто так хотел сделать, но если из - за этих пробелов сложности, я могу без них сделать.. ("hello world-15", "windows 3-12")

Цитата Iska:

Зачем указывать имя без числа, а не просто имя? »

Потому что полностью имя мы не знаем.. (мы не знаем число, которое в конце.. мы знаем только все символы до этого числа).

Цитата Iska:

И с какого тогда числа начинать перебор значений в сторону уменьшения (пакетные файлы хоть и ограничены, но позволяют манипулировать относительно большими числами)? »

в конце имени файла будет число не больше 30

Цитата Iska:

Зачем указывать в самом пакетном файле, а не параметром пакетного файла? »

Я просто не знаю, как это параметром

Мне на самом деле без разницы где указывать, цель - чтобы батник переименовывал указанный файл.. конкретно, чтобы число в конце (именно в конце) имени файла уменьшалось на 1.. если в конце имени файла "0" или вообще числа нету, скрипт просто должен завершиться и ничего не переименовывать.

megaloman · Отправлено: **21:02, 01-04-2018** | #5

Alexander_88,

Не важно, есть ли расширение или дефисы. Важно чтобы файл по указанной маске был единственный. Маска для файла без расширения должна завершаться точкой.

Код:

@Echo Off

Set "InFile=Z:\Box_In\ok likes 2 - *." 

FOR %%f IN ("%InFile%") DO (Set "Full=%%f" &Set "NFile0=%%~nf"  &Set "Ext=%%~xf")
If "%Full%"=="" Exit /B 2

Set "NFile=%NFile0: =z%"
Set "NFile=%NFile:-=z%"

FOR /L %%i IN (1,1,9999) DO Call Set /A M=1%%NFile:~-%%i%%*10 2>nul ||(Set /A N=%%i &GoTo :Cont)
:Cont
If %N% EQU 1 Exit /B 1

Set /A N=%N%-1

Call Set /A M=%%NFile0:~-%N%%%*1
If %M% EQU 0 Exit /B 0
Set /A M=%M%-1

Call Set "NFile=%%NFile0:~0,-%N%%%%M%%Ext%"

Ren "%Full%" "%NFile%" ||Exit /B 4
Exit /B 0

Iska · Отправлено: **21:05, 01-04-2018** | #6

Цитата Alexander_88:

Я просто не знаю, как это параметром »

Например, вот так:

Скрытый текст

Цитата Alexander_88:

Потому что полностью имя мы не знаем.. (мы не знаем число, которое в конце.. мы знаем только все символы до этого числа). »

Почему не знаете? Вы же его видите?

megaloman · Отправлено: **21:14, 01-04-2018** | #7

Alexander_88,

Вот батник. Если Вы сделаете на него на рабочем столе иконку, то, затягивая в проводнике файл на нее, получите нужный результат с переименованием.
Либо можете распорядиться этим батником и файлом как это показал Iska

Код:

@Echo Off

Set "Full=%~1" 
Set "NFile0=%~n1"  
Set "Ext=%~x1"

Set "NFile=%NFile0: =z%"
Set "NFile=%NFile:-=z%"

FOR /L %%i IN (1,1,9999) DO Call Set /A M=1%%NFile:~-%%i%%*10 2>nul ||(Set /A N=%%i &GoTo :Cont)
:Cont
If %N% EQU 1 Exit /B 1

Set /A N=%N%-1

Call Set /A M=%%NFile0:~-%N%%%*1
If %M% EQU 0 Exit /B 0
Set /A M=%M%-1

Call Set "NFile=%%NFile0:~0,-%N%%%%M%%Ext%"

Ren "%Full%" "%NFile%" ||Exit /B 4
Exit /B 0

Alexander_88 · Отправлено: **22:05, 01-04-2018** | #8

Цитата Iska:

Почему не знаете? Вы же его видите? »

Этот бат я буду запускать не в ручную... его будет запускать другой скрипт, также этот скрипт будет менять файлы, поэтому никогда не знаешь, какое там будет число.

megaloman, Спасибо, я проверил, у меня все работает, кроме файлов, в имени которых есть цифры.

Цитата Alexander_88:

забыл я одно.. пару файлов у меня с цифрами (которые уменьшать не надо.. нужно уменьшать только те числа, которые в конце имени). »

например такой файл
"ok likes 2 - 15"

В скрипте указал "C:\ok likes 2 - *."

после применения бата, файл стал называться
"ok likes 2 -14"

при последующих запусках конечное число начинает увеличиваться. ("ok likes 2 -14", "ok likes 2 -15", "ok likes 2 -16" и т.д.)

megaloman · Отправлено: **22:13, 01-04-2018** | #9

Цитата Alexander_88:

при последующих запусках конечное число начинает увеличиваться. ("ok likes 2 -14", "ok likes 2 -15", "ok likes 2 -16" и т.д. »

Не верю! Проверил, работает. Переименуйте свой батник в txt и прикрепите его к сообщению.

Alexander_88 · Отправлено: **22:31, 01-04-2018** | #10

Цитата megaloman:

при последующих запусках конечное число начинает увеличиваться. ("ok likes 2 -14", "ok likes 2 -15", "ok likes 2 -16" и т.д. » »

Да это лишнее наболтал, дефисы в бате забыл поставить..

Получается так

Цитата Alexander_88:

после применения бата, файл стал называться
"ok likes 2 -14" »

А потом после последующих запусков ничего не происходит, я полагаю из - за того, что удалился пробел перед числом.
Возможно, как то не полностью я в бате исправил что - то (прикрепил).