[gora]

в Windows 8 тоже было каскадное меню »

Постараюсь исправить.

пункт для файлов .exe ... в меню "отправить" »

В меню Отправить пункты не привязываются к конкретным расширениям и присутствуют всегда, что тоже не очень удобно.

В контекстное меню для папок добавить "создать список файлов папки" »

Этот пункт требует ТЗ.
1 Список файлов в папке которая открыта или закрыта, но находится под курсором?
2 Пути в списке полные или относительно этой папки?
3 В списке только файлы или и вложенные папки?
4 Рекурсия по вложенным папкам требуется?
5 Сохранять список в буфер обмена или в файл?
6 Куда сохранять файл-список? В саму папку или рядом с ней?
7 Имя этого файла и как поступать, если одноименный файл уже имеется?
8 В какой кодировке файл, если в нем будет кириллица?

Хотелось бы услышать обоснование необходимости наличия такого пункта, для чего такой список может потребоваться?

[wolkow70]

Этот пункт требует ТЗ. »

1 Список файлов в папке которая открыта или закрыта, но находится под курсором? - Выделенная курсором папка.
2 Пути в списке полные или относительно этой папки? - Относительные к этой папке.
3 В списке только файлы или и вложенные папки? - Файлы и вложенные папки.
4 Рекурсия по вложенным папкам требуется? - Да.
5 Сохранять список в буфер обмена или в файл? - В файл.
6 Куда сохранять файл-список? В саму папку или рядом с ней? - В текстовый файл в самой папке, но без включения его наименования в сам список.
7 Имя этого файла и как поступать, если одноименный файл уже имеется? ZZZ_+Наименование папки +.txt (чтобы был в конце при сортировке по имени), перезаписать.
8 В какой кодировке файл, если в нем будет кириллица? ANSI

Хотелось бы услышать обоснование необходимости наличия такого пункта, для чего такой список может потребоваться? »

Например, при создании инсталляторов часто требуется, чтобы не копировать наименование каждого файла в скрипт. Удобно, когда уже есть список файлов в столбик, особенно когда их много.

В меню Отправить пункты не привязываются к конкретным расширениям и присутствуют всегда, что тоже не очень удобно. »

В наработанной системе, как правило, уже и так к .exe файлам цепляется много всякого контекста, приходится сокращать список.

[gora]

wolkow70, сделал батник в соответствии с ТЗ. Файлы\папки с атрибутами HRS выводятся в конце отдельными списками. Это и проще реализовать в скрипте, и удобнее для дальнейшего использования.
Проверьте результат, то ли Вы хотели.

Код:

@Echo Off& ChCp 1251>nul
:: Кодировка файла кириллица Windows (1251)
Set folder=e:\Temp 1\Dotnet11 русская папка

For %%i In ("%folder%") Do Set $name=%%~nxi&Set $path=%%~dpi
(
For /F "tokens=*" %%i In ('Dir /B /S /O:GNE "%folder%"') Do Set ti=%%i& Call Echo %%ti:%folder%\=%%
Echo -=   Hide    =-
For /F "tokens=*" %%i In ('Dir /B /S /O:GNE /A:H "%folder%"') Do Set ti=%%i& Call Echo %%ti:%folder%\=%%
Echo -= Read Only =-
For /F "tokens=*" %%i In ('Dir /B /S /O:GNE /A:R "%folder%"') Do Set ti=%%i& Call Echo %%ti:%folder%\=%%
Echo -=  System   =-
For /F "tokens=*" %%i In ('Dir /B /S /O:GNE /A:S "%folder%"') Do Set ti=%%i& Call Echo %%ti:%folder%\=%%
)>"%$path%ZZZ_%$name%.txt"

[apozlevich]

gora, добавлю пять копеек: "-= Hide =-" и остальное тогда идеально начинать с ':' или какого-нибудь другого символа, чтобы можно было самому спарсить с for /f "eol=:".

Вообще, идея wolkow70 понравилась, сам постоянно делал руками, только что сделал батник:

читать дальше »

Код:

@echo off
SetLocal EnableDelayedExpansion
ChCp 1251>nul
:: Первый аргумент - папка, если аргумента нет, то тогда текущая папка.
:: Второй аргумент - output, если аргумента нет, то тогда stdout.
:: Простите мне мои машинные комментарии :)
set Folder=%~1
if "%~1"=="" (set Folder=.)
set Output=%~2
if "%~2"=="" (set Output=CON&&ChCP 866>nul)

::Переходим в нужную папку
pushd "%Folder%"
for /f "usebackq delims=" %%i in (`dir /b /s /a-d`) do (
	:: Обрезаем путь (нужен же относительный)
	set file=%%i
	set file=!file:%CD%\=!
	:: Ну и выхлоп, собственно
	echo !file!>>"!Output!"
)
popd
:: Для дальнейшей работы в консоли лучше вернуть чарсет.
ChCp 866>nul

Выхлоп таков:

читать дальше »

Код:

C:\Users\Администратор\Рабочий стол\new>list
file1.ext
file2.ext
file3.ext
testfolder\hello.ext
testfolder\OSZone.ext

C:\Users\Администратор\Рабочий стол\new>cd ..

C:\Users\Администратор\Рабочий стол>list new
file1.ext
file2.ext
file3.ext
testfolder\hello.ext
testfolder\OSZone.ext

C:\Users\Администратор\Рабочий стол>list new file.lst

C:\Users\Администратор\Рабочий стол>type new\file.lst
file1.ext
file2.ext
file3.ext
testfolder\hello.ext
testfolder\OSZone.ext

gora, раскритикуйте

P.S.: пытался сделать так, что if "%~2"=="/d" (set Output=%Folder%\file.lst), с переменными все было хорошо, но вот на строке echo !file!>>"!Output!" говорило что-то насчет того, что файла не существует. I BAT.

P.P.S: gora, а чем вы раскрашиваете код для форума?

[wolkow70]

Проверьте результат, то ли Вы хотели. »

Да, работает отлично.
Оказалось, что если много папок, то потом неудобно их в ручную высматривать и удалять из списка. Возможен еще вариант "только файлы рекурсивно" ?
Интересует возможность выполнения подобного скрипта вызовом из контекстного меню папки.

[apozlevich]

только файлы рекурсивно »

Да, dir /b /s /a-d, если добавлять к скрипту gora, то DIR /B /S /O:GNE /A:H-D. (H тут для примера).

[wolkow70]

apozlevich, батники, это конечно отлично, но я считаю, что было бы полезно сделать еще исполняемый модуль, выполняющий скрипт батника с передачей ему аргументов через контекстное меню.

[apozlevich]

wolkow70, так я не умею

[wolkow70]

Раньше в ветке выкладывалась утилита CabTools.exe от Boa aka Yuri Safonow , там примерно так было реализовано:

copy /Y dirs.cmd %SystemRoot%\system32\*.*

@Echo Off
SetLocal EnableExtensions EnableDelayedExpansion
set filetxt="%~dp1\#files in %~n1.txt"

del /Q %filetxt%
For /F "UseBackQ Delims=" %%I In (`Dir %1 /B /ON`) Do Echo %%I>>%filetxt%
cls
exit

и в реестр :

[HKEY_CLASSES_ROOT\Directory\shell\Dirs]
@="Создать список файлов папки"

[HKEY_CLASSES_ROOT\Directory\shell\Dirs\command]
@="dirs.cmd %L"

[apozlevich]

wolkow70, так не рекурсивно же. А если добавить /s для рекурсивности, пути станут полными, а так да, то же самое.