[senseye]

Классно! получилось! папки создаются правильно, по первой букве фирмы, дальше - весь пучок папок в "фирме - партнере", но вот мой скрипт как то странно работает, права назначает, но совершенно левые, у меня на группы стоит назначение он назначает отдельны людям... странно вот лог:

[NiOl]

1. Что сразу бросилось в глаза - я тупо скопировал список команд по назначению прав. В строках по назначению прав на Other Correspondence название каталога обязательно нужно заключить в кавычки - скрипт xcacls пытается назначать права каталогу Other.

2. Других ошибок не вижу. Попробуйте рукчами запустить Xcacls на кокой-нить каталог - если окажется, что вместо групп (на примере группы "DL contracts FA") права прописаны пользователям, то это дело рук скрипта Xcacls и тогда советую воспользоваться просто командой cacls - синтаксис тотже (можно добавить ключ /T), но группам права назначаются гарантированно (у меня на ней реализована автоматическая шара бэкапного диска).

3. Уточнение - "otccorporation" - это Ваш домен? Если да и компьютер, с которого скрипт запущен, также в домене, то название домена можно опускать.

[senseye]

1. Что сразу бросилось в глаза - я тупо скопировал список команд по назначению прав. В строках по назначению прав на Other Correspondence название каталога обязательно нужно заключить в кавычки - скрипт xcacls пытается назначать права каталогу Other. »

Да, Вы правы, в кавычки заключил.

2. Других ошибок не вижу. Попробуйте рукчами запустить Xcacls на кокой-нить каталог - если окажется, что вместо групп (на примере группы "DL contracts FA") права прописаны пользователям, то это дело рук скрипта Xcacls и тогда советую воспользоваться просто командой cacls - синтаксис тотже (можно добавить ключ /T), но группам права назначаются гарантированно (у меня на ней реализована автоматическая шара бэкапного диска). »

Xcacls назначал все правильно, я его тестил где-то неделю (наверное, в силу незнания), сейчас все правильно назначилось! дело было в том, что в F:/ лежал скрипт test.bat и каким то макаром цеплялся и выполнялся а в нем то и были мои тесты )

3. Уточнение - "otccorporation" - это Ваш домен? Если да и компьютер, с которого скрипт запущен, также в домене, то название домена можно опускать. »

пробовал, получилось не ахти лучше так, от этого ж хуже не становится.


идем дальше: натолько что созданную папку - партнера нужно следующее: xcacls *letter*/G "otccorporation\DL name RO":R вот тут то и затык, получается, папку создал, как то проверил что только что создал, и назначил на него разрешение...и еще, надо бы убрать наследование в скрипте...

[NiOl]

Думаю, что на "букву" также стоит дать права Системе и админу (полные), чтобы потом не корячится.
Фирмы унаследуют права "DL name RO", Системе и админу а для Contracts .. Projects права будут без наследования (первая команда назначения без ключа /E).

Код:

@Echo Off
SetLocal EnableDelayedExpansion

set Wrk=D:\Test
set List=D:\Partners.txt
set Log=%~dpn0.log

if not Exist %List% (
echo Error: List-file not found!>>%Log%
exit
)
for /F "Tokens=* Delims=" %%P in (%List%) do (
cd /D %Wrk%
echo Preparing "%%P" at %Wrk% >>%Log%
Title Preparing "%%P"
set Letter=%%P
set Letter=!Letter:~0,1!
if not exist !Letter! (
md !Letter!
xcacls !Letter! /G "otccorporation\DL name RO":R
xcacls !Letter! /E /G System:F
xcacls !Letter! /E /G "otccorporation\Administrator":F
)
cd !Letter!
if not exist "%%P" md "%%P"
cd "%%P"
for %%N in (Contracts,Information,"Other Correspondence",Pricebooks,Products,Projects) do md %%N
dir /b /on>>%Log%

echo Y|xcacls Contracts /G "otccorporation\DL contracts FA":F
xcacls Contracts /E /G "otccorporation\Administrator":F
xcacls Contracts /E /G "otccorporation\DL contracts RO":R
echo Y|xcacls Information /G "otccorporation\DL Information FA":F
xcacls Information /E /G "otccorporation\Administrator":F
xcacls Information /E /G "otccorporation\DL Information RO":R
echo Y|xcacls Other Correspondence /G "otccorporation\DL other correspondence FA":F
xcacls Other Correspondence /E /G "otccorporation\Administrator":F
echo Y|xcacls Pricebooks /G "otccorporation\DL Pricebooks FA":F
xcacls Pricebooks /E /G "otccorporation\Administrator":F
xcacls Pricebooks /E /G "otccorporation\DL Pricebooks RO":R
echo Y|xcacls Products /G "otccorporation\DL Products FA":F
xcacls Products /E /G "otccorporation\Administrator":F
xcacls Products /E /G "otccorporation\DL Products RO":R
echo Y|xcacls Projects /G "otccorporation\DL Projects FA":F
xcacls Projects /E /G "otccorporation\Administrator":F
)

Вроде так...

[senseye]

Прям то что надо! спасибо большое! создает, читает из файла, назначает права. благодарю!

[MMariarti]

Здравствуйте, можно опять поднять эту тему, мне интересна самим схема и если чесно, помощь в написании скрипта, делаем батник к нему txt, с описанием необходимых папок. помогите сделать данный скрипт