[iglezz]

romfus, 1.

Код:

set "arcpath=c:\Program Files\7-zip"
"%arcpath%\7z.exe" ........

2. ключа -ep1 у 7-zip нет, но требуемые параметры несложно и недолго подобрать. Русская справка есть в теме 7-zip
3. ARJ -- зачем такое расширение?

[romfus]

Данные архивы которые я потом отправляю требуют именно такое расширение. По договору

[alpap]

архив ARJ »

с архиватором 7z такое не выйдет, хотите переименовывайте для извращения
--------------

Код:

@echo off
set "name1=Волжский"
set "d1="C:\1_Ingener\%name1%\f_оut\Выгрузка\Массив" "Массив" "*.xml" "*.p7s""
set "d2="C:\1_Ingener\%name1%\f_оut\Выгрузка\ОтчётыПоМассивам" "Отчёты" "*.bmp" "*.p7s""
set "arx=C:\Program Files\7-Zip\7z.exe"

for /l %%n in (1 1 2) do call :#arx %%d%%n%%
pause& exit

:#arx
 pushd "%~1"
  "%arx%" a "%~2%name1%.7z" "%~3" "%~4" -sdel
 popd
exit /b

[megaloman]

set mydate=%mannee%%mmois%%mjour% »

Раньше был архиватор WinRar все работало. Но данный архиватор уже нельзя использовать. Только 7zip »

Этого не может быть. Ни rar ни 7z не делают архивы в формате arj. В .zip - можно.

хотите переименовывайте для извращения »

В представленном коде в первом for потеряна скобка.

Код:

for /f "tokens=1-4 delims=/-\. " %%a in ('date /t') do (
set mjour=%%a
set mmois=%%b
set mannee=ОтчетыВолжский
)
set mydate=%mannee%%mmois%%mjour%

В каком формате дата в системе? Что должно получиться в переменной mydate? Вы явно хотите, чтобы там как-то фигурировала дата.

[romfus]

Дата это текущая дата на ПК, то есть МесяцДень. Но это необязательная переменная

Архивы может и не делает, но в скрипте раньше можно было самому задать расширение. в Винраре это срабатывало

[megaloman]

romfus, То же, что у alpap, но с датой в имени архива. В коде сейчас (жесткое порно) для архиватора 7-Zip формат архива указан как zip, при этом расширение архивного файла будет arj, так как, повторю: Ни rar ни 7z не делают архивы в формате arj. В .zip - можно. ИМХО, он наиболее совместим с остальными архиваторами

Код:

@Echo Off
cls
	Set "ArcType=zip"
	Set "ArcExt=arj"

	Set "Arc="%ProgramFiles%\7-Zip\7zG.exe" a -t%ArcType% -sdel"

	FOR /F "tokens=2 delims==." %%d in ('WMIC OS GET LOCALDATETIME /VALUE') DO SET "@Tdate=%%d"
	Set "MMDD=%@Tdate:~4,2%%@Tdate:~6,2%"

	Call :DoArc "D:\1_Ingener\Волжский\f_оut\Выгрузка\Массив"           "*.XML *.p7s" "D:\1_Ingener\Волжский\f_оut\Выгрузка\Массив\МассивВолжский%MMDD%.%ArcExt%"
	Call :DoArc "D:\1_Ingener\Волжский\f_оut\Выгрузка\ОтчётыПоМассивам" "*.bmp *.p7s" "D:\1_Ingener\Волжский\f_оut\Выгрузка\ОтчётыПоМассивам\ОтчетыВолжский%MMDD%.%ArcExt%"
pause
Exit /B 0

:DoArc
	Pushd %1 ||(Echo %1 &Exit /B 1)
	%Arc% %3 %~2
	Popd
Exit /B 0

[alpap]

раньше можно было самому задать расширение »

можно то можно, но в пределах доступного для действий используемого архиватора
я уже говорил выше, можете добавить строку для переименования именно а arj (архиватор 7zip откроет этот архив):

Код:

...
ren "МассивВолжский.7z" "МассивВолжский.arj"
...

[iglezz]

Расширение и сейчас можно задать произвольное, просто формат архива от этого не поменяется...

[alpap]

Расширение и сейчас можно задать произвольное »

при создании архива - нет, переименовать - да

просто формат архива от этого не поменяется »

ну да, но

требуют именно такое расширение »

начальство будет удовлетворено