[Iska]

Попробуйте так:

Скрытый текст

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

set sMask=st[0-9][0-9][0-9][0-9][0-9][0-9]\.exe

for /f "usebackq skip=1 delims=" %%i in (
	`2^>nul dir /b /a:-d /o:-n "st*.exe" ^| findstr.exe /i /r /c:"%sMask%"`
) do echo del /f /q "%%~i"

endlocal
exit /b 0

Для реального удаления уберите echo. Рассчитано строго на шесть цифр в номере.

[greg zakharov]

Силами cmd (st*******.exe файлы находятся в папке с командным сценарием):

Код:

@echo off
  setlocal enabledelayedexpansion
    for /f %%i in ('dir /b st*.exe') do (
      set "x=%%~ni"
      if not defined n (
        set "n=!x:st=!"
      ) else (
        set "x=!x:st=!"
        if !n! lss !x! set "n=!x!"
      )
    )
    for /f %%i in (
      'dir /b st*.exe ^| findstr /vrc:"st!n!.exe"'
    ) do del /f/q %%i
  endlocal
exit /b

Силами pwsh:

Код:

(ls st*.exe | sort {[Int32]($_.BaseName -replace 'st')} -Descending)[1..-1].ForEach{ri $_}

[DJ Mogarych]

Powershell:

Код:

dir st*.exe |sort name |select -SkipLast 1 |Remove-Item -Force -Confirm:$false