[mwz]

И они ещё борятся за почётное звание дома высокой культуры быта! »

Скрытый текст

Ну дык как всегда... Табличка внизу слева.

[jordan_74]

megaloman,

Set "ArcMask=*.7Z" »

В этой строчке поменял 7Z на zip, иначе не срабатывало.

После изменений скрипт отработал именно так как надо!!! (см. результат работы.jpg)

Но при этом я получил сообщение, которое мне непонятно.(см.сообщение.jpg)

[megaloman]

jordan_74, переименуйте Ваш батник c расширением .TXT и прикрепите к сообщению. Похоже, вместо
GoTo :Eof У вас где-то GoTo :Eo Или GoTo :Eo f
То есть, скопипастили код криво, или случайно извратили.

[jordan_74]

megaloman,

Файл прикрепил
http://forum.oszone.net/attachment.p...1&d=1535008085

[megaloman]

jordan_74, предчувствия меня не обманули, самый последний GoTo :Eof у вас GoTo :Eo
А отрабатывает нормально, так как без этой строки в принципе можно и обойтись. Я обычно ей обозначаю конец подпрограммы, и, если вы далее ничего не наваяете своего, она не обязательна

A и B это разные источники получения чеков. в этих папках чеки разных счетов и не совпадают

можно сделать фэншуйнее, если счетов не много, то указать в батнике, какие счета принадлежат источнику A, а какие B, и, в дальнейшем, не напрягая усталость и мыслительные ресурсы, складывать все пришедшие архивы в одну папку.

[jordan_74]

можно сделать фэншуйнее, если счетов не много, то указать в батнике, какие счета принадлежат источнику A, а какие B, и, в дальнейшем, не напрягая усталость и мыслительные ресурсы, складывать все пришедшие архивы в одну папку. »

Я уточню у бухгалтеров. Но уже сейчас все работает именно так как надо! Спасибо огромнейшее!! Мегаааааа!!

[Blakx87]

Доброе утро. Прошу помощи при создании кода.
Необходимо файл 1.txt из папки с:\1\ скопировать в папку c:\2\ но с другим именем. Можно дату и время в место имени. Ее раззапускаю батник, он снова копирует, но с другим уже именем.
Заранее благодарю

[Iska]

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

set sSourceFile=c:\1\1.txt
set sDestFolder=c:\2

if exist "%sSourceFile%" (
	if exist "%sDestFolder%\." (
		for /f "usebackq delims=" %%i in (
			`2^>nul wmic.exe OS get LocalDateTime /value ^| find.exe /i "LocalDateTime"`
		) do for /f "delims=+-" %%j in ("%%i") do set s%%j
		set sLocalDateTime=!sLocalDateTime:.=!
		set sNewFileName=!sLocalDateTime:~0,-3!.txt
		>nul copy /y "%sSourceFile%" "%sDestFolder%\!sNewFileName!"
	) else (
		echo Can't find destination folder [%sDestFolder%].
		exit /b 2
	)
) else (
	echo Can't find source file [%sSourceFile%].
	exit /b 1
)

endlocal
exit /b 0

[megaloman]

Iska, Пытаюсь понять смысл задачи. Один и тот же неизменный файл копировать много раз с разными именами - нонсенс. Другое дело, копировать исходный файл с включением в имя времени последнего изменения - смысл усматриваю.

Код:

@Echo Off
	Call :@Files "C:\1\1.txt" "C:\2"
GoTo :Eof

:@Files
	If Not Exist %1 (Echo %1 -file not found &Exit /B 2)
	If Not Exist %2 (Echo %2 -folder not found &Exit /B 2)
	Set "Fin=%~1"
	For /f "tokens=1* delims=," %%a in ('wmic datafile where "name='%Fin:\=\\%'" get 'Last Modified' /format:csv') Do (
		If /I "%%a"=="%ComputerName%" Set "Df=%%b"
	)
	If Exist "%~2\%~n1_%Df:~0,14%%~x1" (Echo file already exists "%~2\%~n1_%Df:~0,14%%~x1" &Exit /B 0)
	Set Command=Copy %1 "%~2\%~n1_%Df:~0,14%%~x1"
	%Command% >nul
	Set "Err=%ErrorLevel%"
	If Not %Err%==0 (Echo Command not successful &Echo %Command% &Exit /B %Err%)
Exit /B 0

После копирования получим файл ИсходноеИмя_ГГГГММДДччммсс.Расширение
Где ГГГГММДДччммсс -время последнего изменения файла

[alpap]

Первый раз скопируется с тем же именем в нужную папку (будет создана при отсутствии)
При последующих копированиях к имени будет добавляться дата и время
(если из под dir убрать \%f%, условие будет распространяться на все файлы в папке и подпапках 1, соблюдая структуру при этом)

Код:

@echo off
set "d1=C:\1"
set "d2=C:\2"
set "f=1.txt"

set "stime=%time:~,8%"
for /f "delims=" %%a in ('dir /a-d/b/s "%d1%\%f%"') do set "d=%%a"& call :l "%%a" "%%d:%d1%=%d2%%%"
pause& exit
 
:l
 2>nul md "%~dp2"
 if not exist "%~2" (>nul copy "%~1" "%~2") else (>nul copy "%~1" "%~dp2%~n1_%date%_%stime::=.%%~x1")
exit /b