[Tier2]

Сохранил в vbs - выдает ошибку с ассоциацией файла, хотя стоит ассоциация с Microsoft ® Windows Based Script Host

[Iska]

Tier2, у меня работает.

Покажите скриншот, где будет видно, как Вы задали запуск скрипта. Укажите местоположение файла проекта.

[Tier2]

[Tier2]

Ссылка на скрипт и сам скрипт срабатывает (видно по мелькающему окну консоли) , но вот OneVolumeViewer.exe не запускает

Что в скрипте надо удалить чтоб консоль не закрывалась и можно было прочитать что там написано?

[Iska]

Вы не указали:

Укажите местоположение файла проекта. »

Жду.

Ссылка на скрипт и сам скрипт срабатывает (видно по мелькающему окну консоли) »

Не должно быть окна консоли.

Попробуйте такой вариант для отладки:

читать дальше »

Код:

Option Explicit

Const strFileName = "OneVolumeViewer.exe"

Dim objFolder
Dim strPath


With WScript.CreateObject("Scripting.FileSystemObject")
	For Each objFolder In .GetDrive(.GetDriveName(WScript.ScriptFullName)).RootFolder.SubFolders
		strPath = .BuildPath(objFolder.Path, strFileName)
		
		MsgBox strPath
		
		If .FileExists(strPath) Then
			MsgBox strPath, vbOKOnly + vbInformation, "Found!"
			
			WScript.CreateObject("WScript.Shell").Run strPath, 1, True
			
			Exit For
		End If
	Next
End With

MsgBox "That All!"

WScript.Quit 0

Будет перечислять все пути, в которых будет искать искомый файл.

[Tier2]

файл находит, но

[Iska]

Tier2, файл действительно называется «OneVolumeViewer.exe»? Покажите текст окна сообщения «Found!» из отладочного варианта скрипта:

Код: --------------------------- Found! --------------------------- E:\qww\OneVolumeViewer.exe --------------------------- ОК ---------------------------

(достаточно просто нажать «Ctrl-C» для копирования содержимого окна в буфер обмена).

[Tier2]

затем по нажатии ок

[Iska]

Tier2, спасибо, ясно. Наличие пробелов в пути . Пробуйте:

читать дальше »

Код:

Option Explicit

Const strFileName = "OneVolumeViewer.exe"

Dim objFolder
Dim strPath


With WScript.CreateObject("Scripting.FileSystemObject")
	For Each objFolder In .GetDrive(.GetDriveName(WScript.ScriptFullName)).RootFolder.SubFolders
		strPath = .BuildPath(objFolder.Path, strFileName)
		
		If .FileExists(strPath) Then
			WScript.CreateObject("WScript.Shell").Run """" & strPath & """", 1, False
			
			Exit For
		End If
	Next
End With

WScript.Quit 0

[Tier2]

Iska это Вам приогромнейшее спасибо - теперь все заработало!!!
Теперь как прикрутить сохранение к этому? Например чтоб при нажатии на кнопку выскакивало диалоговое окно проводника с предложением сохранить папку с имеющимся названием на HDD
Вернее не к этому скрипту а просто отдельным скриптом - чтоб название имеющейся папки не изменялось?