[Painkiller]

Ivan_009, создаешь в нужной папке desktop.ini c содержимым :
Пример :

Код:

 [.ShellClassInfo]
IconResource=C:\Program Files\Uninstall Tool\UninstallTool.exe,0 -   путь к  иконке

Потом через командную строку ставишь атрибуты :
Пример :

Код:

Attrib +s "C:\Program Files\Uninstall Tool -путь к  нужной папке

Всё

[Ivan_009]

Painkiller, Спасибо конечно но меня интересут чтобы все автоматом сделалось...

[Painkiller]

Painkiller, Спасибо конечно но меня интересует чтобы все автоматом сделалось... »

А что мешает создать в папке на рабочем столе ini и через батник применить атрибуты ?

[boss911]

Код:

@Echo off

SET MYFOLDER="%UserProfile%\Рабочий стол\Справочные данные"

IF NOT EXIST %MYFOLDER% GOTO:EOF
IF EXIST %MYFOLDER%\Desktop.ini DEL /Q /AH %MYFOLDER%\Desktop.ini >nul 2>&1

1>%MYFOLDER%\Desktop.ini (
  ECHO [.ShellClassInfo]
  ECHO IconFile=%SystemRoot%\system32\SHELL32.dll
  ECHO IconIndex=23
)

ATTRIB +S +H %MYFOLDER%\Desktop.ini

EXIT

Поскольку в пакетном файле присутствует кириллица, сохраняем его в DOS (866) кодировке.

[Ivan_009]

boss911, Спасибо большое все работает...

[gora]

как папке присвоить определенную иконку... »

Положите в эту папку нужную иконку (с любым именем) и батник:

Код:

@Echo Off
ChCp 1251>Nul
Set fldr=%~dp0
If Exist "%~dp0desktop.ini" Attrib -H -S "%~dp0desktop.ini"
For %%i In ("%~dp0*.ico") Do (
	(Echo [.ShellClassInfo]
	Echo IconResource=%%~nxi,0
	Ver | Find "6.">Nul || (Echo IconFile=%%~nxi& Echo IconIndex=0)
	)>"%~dp0desktop.ini"
)
Attrib +H +S "%~dp0desktop.ini"
Attrib +R "%fldr:~0,-1%"

Запустите батник

[Cl3r1k]

Доброго времени суток. Возникла загвоздка с вашим батником, gora. Опишу подробнее последовательность действий.

читать дальше »

Требуется кастомизировать папку. Для примера и чистоты эксперимента создал новую папку в корне диска с именем 123

Поместил в нее иконку с именем 200.ico и ваш батник малость подредактированный с кодом

Код:

@Echo Off
ChCp 1251>Nul
Set fldr=%~dp0
If Exist "%~dp0Desktop.ini" Attrib -H -S "%~dp0Desktop.ini"
For %%i In ("%~dp0*.ico") Do (
	(Echo [.ShellClassInfo]
	Echo IconResource=%%~nxi,0
	Ver | Find "6.">Nul || (Echo IconFile=%%~nxi& Echo IconIndex=0)
	Attrib +S +H %%~nxi
	)>"%~dp0Desktop.ini"
)
Attrib +S +H "%~dp0Desktop.ini"
Attrib +R "%fldr:~0,-1%"

и запустил, поднялся на уровень выше, отображение папки сменилось но иконка не применилась.

содержимое созданного Desktop.ini
[.ShellClassInfo]
IconResource=200.ico,0
изменим вид на табличный (для сравнения ниже) - иконка не применяется

Причем если переместить эту папку в другое место и изменить вид на таблицу, иконка применяется.

вернув на место папку и задав вид табличный - иконка применяется.

а вот в режиме отображения плитка не отображается иконка,перегружал проводник, и по f5 толку нет. После манипуляций с перемещением, в свойствах папки через какое-то время появляется иконка

В чем может быть проблема, подскажите пожалуйста!

[boss911]

В чем может быть проблема, подскажите пожалуйста! »

А может причина в кеше иконок? Не знаю, где в Win6.x хранится кеш икнок, но в XP это делается так (пакетный файл/батник):

Код:

@Echo off

TASKKILL /F /IM explorer.exe >nul
DEL /Q /AH "%UserProfile%\Local Settings\Application Data\IconCache.db" >nul 2>&1
START explorer.exe

EXIT

Если что, то поиском поищите "IconCache.db" и пропишите правильный путь. Предполагаю (нет под рукой Win6.x), что будет лежать тут:

Код:

%UserProfile%\AppData\Local\IconCache.db

[Cl3r1k]

boss911, Подозреваю что не в кэше. IconCache.db находится по

Код:

%UserProfile%\AppData\Local\IconCache.db

Но даже запустив батник с кодом

Код:

@Echo off

TASKKILL /F /IM explorer.exe >nul
DEL /Q /AH "%UserProfile%\AppData\Local\IconCache.db" >nul 2>&1
START explorer.exe

EXIT

нет положительного эффекта.
Забыл указать ранее, что иконка не применяется после использования батника, если же указывать ее вручную, через свойства папки, то иконка применяется почти сразу (иногда нужно f5 нажать), и если сменить IconResource=D:\123\200.ico,0 на IconResource=200.ico,0 т.е указав относительный путь, то и так тоже работает, причем содержимое desktop.ini при ручной настройке имеет доп. строки.

Код:

[.ShellClassInfo]
IconResource=D:\123\200.ico,0
[ViewState]
Mode=
Vid=
FolderType=Pictures

Пробовал модифицировать батник отgora, с добавлением строк

Код:

@Echo Off
ChCp 1251>Nul
Set fldr=%~dp0
If Exist "%~dp0Desktop.ini" Attrib -H -S "%~dp0Desktop.ini"
For %%i In ("%~dp0*.ico") Do (
	(Echo [.ShellClassInfo]
	Echo IconResource=%%~nxi,0
	Echo [ViewState]
	Echo Mode=
	Echo Vid=
	Echo FolderType=Pictures
	Ver | Find "6.">Nul || (Echo IconFile=%%~nxi& Echo IconIndex=0)
	Attrib +S +H %%~nxi
	)>"%~dp0Desktop.ini"
)
Attrib +S +H "%~dp0Desktop.ini"
Attrib +R "%fldr:~0,-1%"

но так-же нет положительных результов.