[Iska]

boha, реализовать все Ваши хотелки на WSH не реально. Поменяйте тематику на PowerShell — там можно будет реализовать на форме.

[Dr.DG]

boha, вот как можно управлять IE с помощью VBS. В качестве примера показываю страницу для ввода пароля. Вы можете создать свою страницу с нужным функционалом.

Код:

strPassword = GetPassword("User", "Domain")

Function GetPassword(strUser, strDomain)

    Dim objIE
    
    Set objIE = CreateObject("InternetExplorer.Application")

    With objIE
    
        .AddressBar = False
        .Menubar = False
        .Navigate "about:blank"
        .ToolBar = 0
        .Resizable = False
        .StatusBar = False
        .Width = 340
        .Height = 230
        .Left = (.Document.ParentWindow.Screen.AvailWidth - .Width) \ 2
        .Top = (.Document.ParentWindow.Screen.AvailHeight - .Height) \ 2

        Do While .Busy
           WScript.Sleep 200
        Loop

        .Document.title = "Logon"
        .Document.body.scroll = "no"
        .Document.body.innerHTML = "<font face=Arial>" & _
            "<h3>Logon to " & strDomain & " domain</h3>" & _
            "<table><tbody><tr><td>User name:</td><td>" & strUser & "</td></tr>" & _
            "<tr><td>Password:</td><td><input type=password id=txtPassword></td></tr>" & _
            "<tr><td><input type=hidden id=txtHidden value=0></td>" & _
            "<td><input type=submit value=OK onClick=vbscript:txtHidden.Value=1>" & _
            "</td></tr></tbody></table></font>"
        
        .Visible = True

        'wait for user input
        Do While .Document.all.txtHidden.value = "0" 
            WScript.Sleep 200
        Loop

        GetPassword = .Document.all.txtPassword.value

        .Quit
        
    End With

    Set objIE = Nothing

End Function

[Iska]

Dr.DG, Вы прочитали все пожелания автора

Нужно чтоб каждую окошку пользователь не мог закрыть »

?!

[boha]

Iska
а можно тогда сделать чтоб 3000 символов можно было отобразить в одной окошке?
и эту окошку пользователь не мог бы закрыть в течении 5 минут.

[Iska]

boha, на PowerShell, думаю, можно.

P.S. Из опыта: не читали, и читать не будут. Хоть красными буквами пишите, хоть жирными, хоть аршинными. Не будут.

[boha]

тема закрыта.
спасибо Iska.

[Dr.DG]

Вы прочитали все пожелания автора »

Не понял, что мешает обрабатывать события окна браузера или после закрытия так же открывать новое окно скриптом?
Хотя зачем оно, если никто всё равно не читает... :-)

[Iska]

Dr.DG, ничто не мешает. Но это будет ровно такой же выверт, как и здесь: Серый форум / vbscript: «незакрываемый» MsgBox на заданное время.

Хотя зачем оно, если никто всё равно не читает... :-) »

И я про то же. Делал. Незакрываемое, непередвигаемое, неубиваемое, поверх всех… Если не хотят читать — не заставишь. Только организационные меры. Причём, это куда более действенный способ.

[boha]

Я опять столкнулся с одни нюансом.
помогите решить если возможно.

ниже скрипт, я запускаю его через планировщик задании на всех пользователей.
окошко с сообщение выскакивает на монитор даже тогда, когда компьютер заблокирован.
Нужно чтоб не выходила сообщение по верх блокировки, Чтоб пользователь видел окошко только при входе в сеанс.

Код:

Option Explicit

Dim objWshShell

Dim intTime4Show                                                               ' Заданное (оно же максимально возможное) время показа сообщения
Dim intMinimumTime                                                             ' Минимальное время показа сообщения
Dim intTimeStartShowing                                                        ' Время начала показа сообщения
Dim intRetValue                                                                ' Возвращаемое значение метода .Popup


Set objWshShell = WScript.CreateObject("WScript.Shell")

intTime4Show    = 60                                                           ' Заданное    время показа сообщения — 1 минута
intMinimumTime  = 5                                                           ' Минимальное время показа сообщения — 10 секунд

intTimeStartShowing = Timer                                                    ' Засекаем время

Do
    ' Выводим сообщение поверх всех окон [&H40000] на оставшееся на текущий момент,
    ' от заданного, время [intTime4Show - (Timer - intTimeStartShowing)]
    intRetValue = objWshShell.Popup( _
        "   УВАЖАЕМЫЕ КОЛЛЕГИ!" & Chr(13) & _
"Администратор домена сообщает, что....!", _
        intTime4Show - (Timer - intTimeStartShowing), _
        "СЛУЖБА СООБЩАЕТ!", _
        vbOKOnly + vbInformation + &H40000)
    
    ' Повторяем вывод сообщения, пока не будет выполнено одно из условий:
    ' 1. Истечёт отведённое время и сообщение будет закрыто по таймауту [intRetValue = -1]
    ' 2. Сообщение будет закрыто вручную и с момента первого показа
    '    сообщения до текущего момента пройдёт не менее минимального [intMinimumTime]
    '    времени [(Timer - intTimeStartShowing) > intMinimumTime]
Loop Until intRetValue = -1 Or (Timer - intTimeStartShowing) > intMinimumTime

Set objWshShell = Nothing

WScript.Quit 0