Скрипты Inno Setup. Помощь и советы [часть 3]

Rostlv · Конфигурация компьютера

Всем здравствуйте!

Проблема первая, как проверить версию .Net Framework при установке программы, запакованной в Inno Setup? В частности мне нужна версия 3.5 и выше. В нете нашёл много примеров, но они мне либо не подходят по функционалу, либо вызывают ошибку ещё на этапе компилляции. Хочется проверять версию .Net в реестре. Сам дистрибутив .Net входит в состав моего пакета, но пока-что устанавливается всегда, даже если в системе уже есть установленный Framework, что естественно плохо. Да и к тому же, на Vista и Seven установка dotNetFx40_Client_x86_x64.exe, который входит в состав моего пакета и устанавливается из секции Run, вызывает автоматическую перезагрузку системы даже с ключем /norestart еще на этапе установки, не позволяя её завершить, на XP такого не замечено.

Проблема вторая, из секции Run кроме .Net Framework устанавливается ещё и другое ПО, установка занимает дополнительное время, но прогресс уже не отображается, стандартный прогрессбар уже показывает все 100%. Вопрос, как добавить второй прогрессбар для программ из секции Run с правильным расчетом процентов при установке доп. ПО (не фейковый)? Ну или хотя бы чтобы было видно только сами проценты при установке каждого пакета из дополнительного ПО, что именно из доп. ПО сейчас устанавливается в мастере отображается. Находил варианты для 7-zip, FreeArc архивов, но мне нужен способ для разных дистрибутивов, в том числе для msi-пакетов. Доп. ПО запускается из {tmp}.

Gnom_aka_Lexander · Отправлено: **21:43, 25-12-2010** | #**262**

Rostlv,
Если решиш, особенно по второму вопросу, буду рад узнать это решение, сам ищу...

Serega · Конфигурация компьютера

Цитата Rostlv:

как проверить версию .Net Framework при установке программы »

уже отвечал на похожий вопрос...

Пример

Код:

; определение версии установленного .Net Framework

[Setup]
AppName=NetFramework
AppVerName=NetFramework
DefaultDirName={pf}\NetFramework
OutputDir=.
Compression=lzma/ultra64
InternalCompressLevel=ultra64
SolidCompression=yes
VersionInfoCopyright=Serega

[Languages]
Name: russian; MessagesFile: compiler:Languages\Russian.isl

[Code]
const
  MinNetFrameWork = 'v4.0'; // минимальная версия NetFrameWork
  // Возможные версии = 'v1.0', 'v1.1', 'v2.0', 'v3.0', 'v3.5', 'v4.0'

var
  url: string;

procedure GetUrlNetFrameWork(ver: string);
begin
  // страница загрузок http://www.microsoft.com/downloads/results.aspx?pocId=&freetext=Framework&DisplayLang=ru
  case ver of
    // по этой ссылке v1.1, т.к. ссылку на v1.0, я не нашёл... раритет... ;)
    'v1.0': url := 'http://download.microsoft.com/download/0/8/6/086e7824-ddad-45c0-b765-721e5e28e4c5/dotnetfx.exe';
    'v1.1': url := 'http://download.microsoft.com/download/0/8/6/086e7824-ddad-45c0-b765-721e5e28e4c5/dotnetfx.exe';
    'v2.0': url := 'http://download.microsoft.com/download/5/6/7/567758a3-759e-473e-bf8f-52154438565a/dotnetfx.exe';
    'v3.0': url := 'http://download.microsoft.com/download/4/d/a/4da3a5fa-ee6a-42b8-8bfa-ea5c4a458a7d/dotnetfx3setup.exe';
    'v3.5': url := 'http://download.microsoft.com/download/7/0/3/703455ee-a747-4cc8-bd3e-98a615c3aedb/dotNetFx35setup.exe';
    'v4.0': url := 'http://download.microsoft.com/download/1/B/E/1BE39E79-7E39-46A3-96FF-047F95396215/dotNetFx40_Full_setup.exe';
  else
    url := 'http://download.microsoft.com/download/5/6/7/567758a3-759e-473e-bf8f-52154438565a/dotnetfx.exe';
  end;
end;

function CompareMinVer(const ver: string): Boolean;
var
  min_ver: string;
begin
  Result := False;
  min_ver := MinNetFrameWork;
  if (Length(min_ver) > 2) and (Length(ver) > 2) then
    if (min_ver[2] > #47) and (min_ver[2] < #58) and (ver[2] > #47) and (ver[2] < #58) then
      Result := ver[2] > min_ver[2];
end;

function DetectInstallNetFrameWork: Boolean;
var
  VerNetFrameWorkInstalled: TArrayOfString;
  i: Integer;
begin
  Result := False;
  if RegGetSubkeyNames(HKLM, 'SOFTWARE\Microsoft\NET Framework Setup\NDP', VerNetFrameWorkInstalled) then
    case CompareMinVer(VerNetFrameWorkInstalled[0]) of
      True : Result := True;
      False:
        for i := 0 to GetArrayLength(VerNetFrameWorkInstalled)-1 do
          if Pos(MinNetFrameWork, VerNetFrameWorkInstalled[i]) > 0 then
            begin
              Result := True;
              Break;
            end;
    end;
end;

function SearchNetFrameWork: Boolean;
var
  ErrorCode: Integer;
begin
  Result := DetectInstallNetFrameWork;
  if not Result then
    if MsgBox('Для этой программы требуется установленный .NET Framework не ниже ' + MinNetFrameWork + '. ' +
              'Пожалуйста загрузите и установите .NET Framework и запустите установку снова. ' +
              'Вы хотите загрузить .NET Framework сейчас?', mbConfirmation, MB_YESNO) = idYes then
      begin
        GetUrlNetFrameWork(MinNetFrameWork);
        ShellExec('open', url, '', '', SW_SHOWNORMAL, ewNoWait, ErrorCode);
      end;
end;

function InitializeSetup: Boolean;
begin
  Result := SearchNetFrameWork;
end;

Цитата Rostlv:

Проблема вторая »

Всё что вы хотите, всё это реализуемо, только если вы заставите свою запускаемую программу отвечать, насколько она процентов выполнилась...
Если это не задано автором программы, то вам это никогда не получиться, отображать реальный процент.
Но как говорится если очень сильно хочится...
1. Вариант:
Берём распакованный размер программы и в момент установки, сверяем размеры папок и уже от этого увеличиваем прогрессбар.
2. Вариант:
Просто задаём прогрессбару стиль, такой же как у прогрессбара при установке IE, т.е. нет реального процента, а полоска бегает и пользователь видит, что программа не зависла.

Duality · Отправлено: **23:46, 25-12-2010** | #**264**

Как прявязать к радибаттонам в этом [code]

Код:

var
  MyNewPage: TWizardPage;
  MyRadioBtn_1, MyRadioBtn_2: TRadioButton;

procedure GetMyNewPage();
begin
  MyNewPage := CreateCustomPage(wpWelcome, 
    ExpandConstant('{cm:HeaderLabelPage}'), '');

  MyRadioBtn_1 := TRadioButton.Create(WizardForm);
  with MyRadioBtn_1 do
  begin
    Top := ScaleY(50);
    Width := ScaleX(150);
    Height := ScaleY(13);
    Caption := ExpandConstant('{cm:MyRadioCaption_1}');
    Checked := True;
    Parent := MyNewPage.Surface;
  end;

  MyRadioBtn_2 := TRadioButton.Create(WizardForm);
  with MyRadioBtn_2 do
  begin
    Top := ScaleY(120);
    Width := ScaleX(150);
    Height := ScaleY(13);
    Caption := ExpandConstant('{cm:MyRadioCaption_2}');
    Parent := MyNewPage.Surface;
  end;
end;

procedure InitializeWizard();
begin
  GetMyNewPage();
end;

копирование определенного файла (т.е для одной радиокнопки это один из секкции [Files] для второй другой)
например такие

Код:

Source: d:\Programs\!Install\norm\boot1.ini; DestDir: {app}; Components: a; 
Source: d:\Programs\!Install\port\boot2.ini; DestDir: {app}; Components: b;

(раньше я их привязывал в секциях компоненты к радиокнопкам, но охота сделать на новой странице это.

serg aka lain · Отправлено: **00:05, 26-12-2010** | #**265**

Цитата ksunechkin:

Как прявязать к радибаттонам »

Код:

[Files]
Source: d:\Programs\!Install\norm\boot1.ini; DestDir: {app}; Components: a; Check: GetRadio_1Checked;
Source: d:\Programs\!Install\port\boot2.ini; DestDir: {app}; Components: b; Check: GetRadio_2Checked;

[code]
function GetRadio_1Checked(): Boolean;
begin
  Result := MyRadioBtn_1.Checked;
end;

function GetRadio_2Checked(): Boolean;
begin
  Result := MyRadioBtn_2.Checked;
end;

Rostlv · Конфигурация компьютера

С первой проблемой разобрался путём замены дистрибутива .Net с версии 4.0 на 3.5, которая, в отличие от 4.0, сама проверяет наличие установленной в системе версии .Net Framework и не устанавливает повторно то, что уже есть. Serega, приведённый код на Seven работает некорректно, в указанной ветке реестра на чистой системе есть только v2.0, хотя в системе установлена v3.5.

По второму вопросу полноценный прогрессбар сделать не получится, поэтому придётся довольствоваться фейковым, как при установке IE. Где найти код для него и как "прикрутить" его к секции Run? У меня сейчас уже задействован код для отображения процентов при распаковке всех файлов моего дистрибутива, поэтому нужно соединить обе части кода, первую привожу:

Код:

 
var 
  ProgressLabel, SizeLabel: TLabel; 
   
procedure Progress(); 
var 
  size: integer; 
   
begin 
  with WizardForm.ProgressGauge do 
    ProgressLabel.Caption:= IntToStr((Position-Min)/((Max - Min)/100)) + '%'; 
 
  FileSize(ExpandConstant(CurrentFileName), size); 
  SizeLabel.Caption:= IntToStr(size) + ' bytes'; 
end; 
 
procedure InitializeWizard(); 
begin 
  ProgressLabel := TLabel.Create(WizardForm); 
  with WizardForm.ProgressGauge do 
    begin 
      ProgressLabel.Top := Top + Height + ScaleY(8); 
      ProgressLabel.Left:= Left + Width/2 - ScaleX(8); 
      ProgressLabel.AutoSize := True; 
      ProgressLabel.Parent := WizardForm.InstallingPage; 
    end; 
     
  SizeLabel := TLabel.Create(WizardForm); 
  with WizardForm.ProgressGauge do 
    begin 
      SizeLabel.Top := Top + Height + ScaleY(8); 
      SizeLabel.Left:= Left; 
      SizeLabel.AutoSize := True; 
      SizeLabel.Parent := WizardForm.InstallingPage; 
    end; 
end;

R.i.m.s.k.y. · Конфигурация компьютера

Rostlv,
загляни в реестр HKLM\SOFTWARE\Microsoft\NET Framework Setup\NDP\ - по подключам типа 3.5 можно узнавать какая версия фреймворка стоит

Serega · Конфигурация компьютера

Цитата Rostlv:

Serega, приведённый код на Seven работает некорректно »

Переписал код в предыдущем сообщении, теперь должно работать нормально.

Цитата Rostlv:

Где найти код для него »

Только самому написать

Вот накидал простой пример:

Пример

gur74 · Отправлено: **20:39, 26-12-2010** | #**269**

Лександер

Спасибо.

Кто - нибудь может помочь поправить скрипт. Компилируется и программа устанавливается нормально, но при удалении выскакивают ошибки:

первая:

а за ней вторая:

Вот скрипт:

Duality · Отправлено: **20:59, 26-12-2010** | #**270**

в дополнение к этому вопросу (который решен) - http://forum.oszone.net/post-1573479-236.html, что сделать в

Скрипте

чтобы под радибаттаноми можно было написать текст -

.
попытался просто в секции [CustomMessages] в MyRadioCaption_1 и MyRadioCaption_2 дальше писать - вставив после Обыная установка" и "Портативная" переменную %n (вроде как это же перенос каретки), и написал делее нужный текст, но текст написался в строку и не был виден. (только начало, см на скрине)