Скрипты Inno Setup. Помощь и советы [часть 6]

[Nordek]

Чтобы по умолчанию всегда был 1 компонент из списка. »
[Components]
Name: a; Description: A; Flags: exclusive; Types: custom compact full
Name: b; Description: B; Flags: exclusive
Name: c; Description: C; Flags: exclusive
Name: d; Description: D; Flags: exclusive

[Optitron]

Nordek, Спасибо за ответ, но можно как-нибудь в этом случае сделать так, чтобы секция Types в инсталляторе не была видна (т.е. без Полная, Выборочная, Компактная установка)?

[Nordek]

чтобы секция Types в инсталляторе не была видна »Тут был уже пример несколько страниц назад. Не только я давал.

[Components]
Name: a; Description: A; Flags: exclusive; Types: custom compact full
Name: b; Description: B; Flags: exclusive
Name: c; Description: C; Flags: exclusive
Name: d; Description: D; Flags: exclusive

[Code]
procedure InitializeWizard();
begin
WizardForm.ComponentsList.Top := ScaleY(45);
WizardForm.ComponentsList.Height := ScaleY(160);
WizardForm.TypesCombo.Visible := False;
end;

[Dinvin4ester]

Привет всем . Ребята есть скрипт механиков - http://rghost.ru/49046726 . Реально ли его переделать вот так , как на скринах ?

[Shkutu]

nik1967, спасибо!

[Dinvin4ester]

Сам пробовал , но все равно остаются эти полосы черные , а как на скриншотах не получается .

[Aquila]

http://s47.radikal.ru/i116/1311/77/e619cbb22b0ct.jpg (http://radikal.ru/fp/4ece8164de3e42deb1f225f9c8392cff)
Скачал справку отсюда, ничего не показывает, нашёл даже поновей от тех же авторов, тоже не фурычит, помогите! Или чем ещё можно открыть?

[nik1967]

Aquila, писали уже не раз. Правой кнопкой на файл справки=>Свойства=>Разблокировать

[Mat_y]

Ребят, чего ругается?
http://s020.radikal.ru/i722/1311/7f/2af56a6ad472.png

Разобрался... лечится
DiskSpanning=true

[Uga4aka]

Есть инсталлятор ПО, но без исходников. И его необходимо дополнить. После распаковки инсталлятора, получил исходники. Насколько разобрался, в нем происходит копирование файлов при определенных условиях (версия ОС). Проверка идет командой Check, но самой функции в коде нет

Source: "{pf}\UltraVNC\ultravnc,1.ini"; DestDir: "{pf}\UltraVNC"; DestName: "ultravnc.ini"
Source: "{pf}\UltraVNC\ultravnc_64.ini"; DestDir: "{pf}\UltraVNC"
Source: "{pf}\UltraVNC\vnchooks.dll"; DestDir: "{pf}\UltraVNC"
Source: "{pf}\UltraVNC\winvnc,1.exe"; DestDir: "{pf}\UltraVNC"; DestName: "winvnc.exe"
Source: "{pf}\UltraVNC\winvnc_ru.exe"; DestDir: "{pf}\UltraVNC"
Source: "{pf}\UltraVNC\winvnc,2.exe"; DestDir: "{pf}\UltraVNC"; DestName: "winvnc.exe"Check: "isVista() or isWin2008Server() or iswin7() or iswin8()"
Source: "{pf}\UltraVNC\winvnc-108.exe"; DestDir: "{pf}\UltraVNC"Check: "isVista() or isWin2008Server() or iswin7()"
Source: "{pf}\UltraVNC\winvnc-108_ru.exe"; DestDir: "{pf}\UltraVNC"; Check: "isVista() or isWin2008Server() or iswin7()"
Source: "{pf}\UltraVNC\ultravnc,2.ini"; DestDir: "{pf}\UltraVNC"; DestName: "ultravnc.ini"; Check: "isWin64()"

не подскажете как дописать, что бы все работало.
Нашел что есть GetWindowsVersion, GetWindowsVersionEx. Но как прикрутить их в скрипт, не хватает навыков

[Raz3r]

Подскажите пожалуйста. Везде обыскал, но так и не нашел. Как сделать, чтобы в меню выбора пути установки путь отображался, но его нельзя было бы изменить? Желательно, чтобы можно было только кнопкой обзор изменить.

[Mat_y]

Ребят, кто может помочь удалить из этого (http://repacks.org.ua/engine/download.php?id=253) кода страницу с выбором компонентов. Сыпет ошибки и сыпет.

[Nordek]

Как сделать, чтобы в меню выбора пути установки путь отображался, но его нельзя было бы изменить? »
[Code]
procedure InitializeWizard();
begin
WizardForm.DirEdit.Enabled := False;
end;

[Uga4aka]

Есть инсталлятор ПО, но без исходников. И его необходимо дополнить. После распаковки инсталлятора, получил исходники. Насколько разобрался, в нем происходит копирование файлов при определенных условиях (версия ОС). Проверка идет командой Check, но самой функции в коде нет
фрагмент проблемного кода
не подскажете как дописать, что бы все работало.
Нашел что есть GetWindowsVersion, GetWindowsVersionEx. Но как прикрутить их в скрипт, не хватает навыков »
function IsVista: Boolean;
{function to check if we are running on Windows Vista}
var
version: TWindowsVersion;
begin
GetWindowsVersionEx(version);
result := false;
if Version.NTPlatform and
(Version.Major = 6) then
result := true;
end;

function IsXP: Boolean;
{function to check if we are running on Windows XP}
var
version: TWindowsVersion;
begin
GetWindowsVersionEx(version);
result := false;
if Version.NTPlatform and
(Version.Major = 5) and
(Version.Minor = 1) then
result := true;
end;

function Is2000: Boolean;
{function to check if we are running on Windows 2000}
var
version: TWindowsVersion;
begin
GetWindowsVersionEx(version);
result := false;
if Version.NTPlatform and
(Version.Major = 5) and
(Version.Minor = 0) then
result := true;
end;
function IsServer: Boolean;
{function to check if we are running on a server}
var
version: TWindowsVersion;
begin
GetWindowsVersionEx(version);
result := false;
if Version.ProductType = VER_NT_SERVER then
result := true;
end;

[FX-DENIS]

Здравствуйте знатоки форума,давно я у вас не просил помощи,El Sanchez помню и SEREGA помню.Проблема вот в чем,у меня скрипт которым я сжимал файлы средствами самого инно мне его Serega подредактировал,я пользовался им полтора года (за что поклон Serege),а тут решил попробовать Free Arc,извлечение из рядом лежащего файла.Все сделал по инструкции вроде,и скачал с сайта библиотеки, но инно ругается на многое,компилирую в Unicod версии.Даже если ошибочные строки закоментировать,то вылазит ошибка такая
http://x.picp2.com/allimage/666/665152-thumb.jpeg (http://picp2.com/15264/665152/)
и инсталлер после нажатия ок,деинсталируется,но при этом в папку с игрой распаковывается частично файлы из Arc архива,вообщем я отчаялся,помогите

[FX-DENIS]

Вот сам скрипт,потому что текстом не влез,более 33тыс символов 106841

[Shkutu]

Приветствую!
Подскажите плиз, разве в инно в нельзя объявлять классы? Например пытаюсь сделать
[CODE]type
TBackUpButton = class(TNewButton)
property order: integer; read write;
property connstring: string; read write;
end;
Ругается на "identifier expected". Причем другие типы (на основе record например) объявляются без проблем.

[tuz-veta]

Привет всем!
подскажите как добавить 2 кнопки для перехода на сайт
вот в этих местах?
http://4put.ru/pictures/small/779/2394054.jpg (http://4put.ru/view-max-picture.php?id=2394054)

[Nordek]

подскажите как добавить 2 кнопки для перехода на сайт
вот в этих местах?
http://4put.ru/pictures/small/779/2394054.jpg (http://4put.ru/pictures/max/779/2394054.jpg) »

[Code]
var
ClkSite1: TNewButton;
ClkSite2: TNewButton;
ErrorCode : Integer;

procedure URLClk1Click(Sender: TObject); forward;
procedure URLClk2Click(Sender: TObject); forward;

procedure InitializeWizard();
begin
ClkSite1 := TNewButton.Create(WizardForm);
with ClkSite1 do
begin
Parent := WizardForm.WelcomePage;
Left := ScaleX(80);
Top := ScaleY(216);
Width := ScaleX(75);
Height := ScaleY(25);
Caption := 'Сайт 1';
OnClick := @URLClk1Click;
end;

ClkSite2 := TNewButton.Create(WizardForm);
with ClkSite2 do
begin
Parent := WizardForm.WelcomePage;
Left := ScaleX(336);
Top := ScaleY(216);
Width := ScaleX(75);
Height := ScaleY(25);
Caption := 'Сайт 2';
OnClick := @URLClk2Click;
end;
end;

procedure URLClk1Click(Sender: TObject);
begin
ShellExec('open', 'http://www.ссылканасайт.com/', '', '', SW_SHOWNORMAL, ewNoWait, ErrorCode);
end;

procedure URLClk2Click(Sender: TObject);
begin
ShellExec('open', 'http://www.ссылканасайт.com/', '', '', SW_SHOWNORMAL, ewNoWait, ErrorCode);
end;

[tuz-veta]

Nordek,
спасибо большое за скрипт!
но у меня не получается прикрутить к моему скрипту,
выдает ошибку