[YuS_2]

С такой постановкой задачи:

Интересует только CMD/BAT. »

Вот это вряд ли:

Если возможно, научите. Спасибо!) »

Хотя, в принципе, можно примерно так:

Код:

for /f "delims=" %%i in ('dir /b/ad "F-LDR<"') do echo ren "%%~i" "%%~i__MY"

echo - в боевых условиях удалить.
обратное действие, тоже можно накидать подобным способом, через цикл, только имена каталогов придется передавать через промежуточную переменную и затем, заменой удалять ненужные символы, примерно так:

Код:

... do (
    set "var=%%~i"
    echo ren "%%~i" "!var:__MY=!"
)

восклицательный знак тут не случайно, ибо внутри скобок придется использовать отложенное раскрытие... ну или использовать вызов call и стандартное %-раскрытие...

ЗЫ
Но возникает закономерный вопрос: Вам шашечки или ехать?
Лучше изучайте повершелл, в нем многое гораздо проще делать...

[Iska]

можно примерно так: »

Туда попадают и ранее переименованные каталоги, наподобие:

Код: C:\Мои проекты\0235\01>dir /b/ad "F-LDR<" F-LDR001__MY F-LDR002 F-LDR003__MY F-LDR004

Колитесь, коллега, откуда брали про «<» в маске, и что он даёт?

[YuS_2]

Туда попадают и ранее переименованные каталоги, наподобие: »

Ну, тут надо выбирать, либо туда, либо сюда... то бишь, сначала удаляем суффиксы, потом все скопом переименовываем, как требуется.
К тому же, в условии не сказано, что там уже присутствуют каталоги с суффиксами...

Колитесь, коллега, откуда брали про «<» в маске, и что он даёт? »

Дежавю, однако.

[dassen]

YuS_2, спасибо!

Хотя, в принципе, можно примерно так: »

F-LDR* to F-LDR*__MY работает отлично. Но гораздо больше чисто практически интересует что-то подобное именно для F-LDR*__MY to F-LDR*, т.к. можно было бы вставить готовый код в мой "рабочий" батник - поэтому:

Интересует только CMD/BAT. »

А что касается:

Лучше изучайте повершелл »

, то если бы написание более-менее сложных скриптов было бы каждодневной необходимостью (а не от случая к случаю), то так бы и сделал... (наверное, уже на пенсии).
Другими словами, на сегодняшнй день очень интересует:

Есть папки с именами F-LDR*__MY. Нужно убрать из их имен суффикс __MY, т.е. привести к виду F-LDR*. »

Вот только:

тоже можно накидать подобным способом »

- это точно не с моими теперешними навыками... Выручайте...

[Iska]

Дежавю, однако. »

Угу. Ну, ещё раза два-три спрошу, опосля, может быть, запомню .

dassen, что делать, если есть, например, и каталог F-LDR003, и каталог F-LDR003__MY?

There.cmd

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

for /f "usebackq delims=" %%i in (
	`2^>nul dir /b /a:d ^| findstr.exe /i /r /c:"^F-LDR.*" ^| findstr.exe /i /v /r /c:".*__MY$"`
) do (
	if not exist "%%~i__MY\." (
		echo Rename folder [%%~i] into [%%~i__MY].
		ren "%%~i" "%%~i__MY"
	) else (
		echo Can't rename folder [%%~i] into [%%~i__MY] because folder [%%~i__MY] already exists.
	)
)

endlocal
exit /b 0

…and…

Back Again.cmd

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

for /f "usebackq delims=" %%i in (
	`2^>nul dir /b /a:d ^| findstr.exe /i /r /c:"^F-LDR.*__MY$"`
) do (
	set sFolderName=%%~i
	set sNewFolderName=!sFolderName:~0,-4!

	if not exist "!sNewFolderName!\." (
		echo Rename folder [%%~i] into [!sNewFolderName!].
		ren "%%~i" "!sNewFolderName!"
	) else (
		echo Can't rename folder [%%~i] into [!sNewFolderName!] because folder [!sNewFolderName!] already exists.
	)
)

endlocal
exit /b 0

[dassen]

Немного помыслил...
В принципе, мне все равно, каким суффиксом изначально было для себя метить папки F-LDR*. Главное - чтобы можно было в нужный момент этот суффикс отбросить.
И если использовать суффикс

Код:

.__MY

вместо

Код:

__MY

, то с задачей F-LDR*.__MY to F-LDR* вполне справится этот код:

Код:

for /f %%i in ('dir /b/ad "F-LDR*.__MY"') do ren "%%i" "%%~ni"

(на идею натолкнул код от YuS_2 ).
Необычно? Но работает. Может, что-то "по-грамотному" подправить/добавить?
"А можно такое же, но без точки?"
P.S.
Отправил это сообщение еще до того, как обнаружил, что уже есть предыдущее от Iska.
Прошу учесть...

[dassen]

Iska, спасибо! Именно то, что требовалось!

dassen, что делать, если есть, например, и каталог F-LDR003, и каталог F-LDR003__MY? »

Именно то, что и делает ваш There.cmd:
к F-LDR* добавлять суффикс __MY
к F-LDR*__MY еще один суффикс __MY добавлять не нужно.
P.S.
Если бы прочитал Ваше сообщение до написания своего

Немного помыслил... »

, то свое бы уже не писал.

[megaloman]

Удаление суффикса

Код:

@Echo Off
cls
	Set "Pref=F-LDR"
	Set "Suff=__MY"
	Set "Ext=.*"

	Set "BoxIn=%~dp0"
	If "%BoxIn:~-1%"=="\" Set "BoxIn=%BoxIn:~0,-1%"
 
	FOR /F "usebackq delims=" %%d IN (`2^>nul Dir "%BoxIn%\%Pref%*%Suff%%Ext%" /B /A:D`) DO (
		Call :MyDel "%BoxIn%\%%d" "%Suff%"
	)	
Pause
GoTo :Eof

rem Удаление суффикса
:MyDel
	Set "Name=%~n1:"
	Call Set "Name=%%Name:%~2:=%%"
	If Not "%~n1:%~x1"=="%Name%%~x1" Ren %1 "%Name%%~x1" ||(Echo Ren %1 --^> "%Name%%~x1" already exists &Echo.)
GoTo :Eof

Добавление суффикса

Код:

@Echo Off
cls
	Set "Pref=F-LDR"
	Set "Suff=__MY"
	Set "Ext=.*"

	Set "BoxIn=%~dp0"
	If "%BoxIn:~-1%"=="\" Set "BoxIn=%BoxIn:~0,-1%"

	FOR /F "usebackq delims=" %%d IN (`2^>nul Dir "%BoxIn%\%Pref%*%Ext%" /B /A:D`) DO (
		Call :MyAdd "%BoxIn%\%%d" "%Suff%"
	)	
Pause
GoTo :Eof

rem Добавление суффикса если его еще нет
:MyAdd
	Set "Name=%~n1:"
	Call Set "Name=%%Name:%~2:=%%"
	If "%~n1:%~x1"=="%Name%%~x1" Ren %1 "%~n1%~2%~x1" ||(Echo Ren %1 --^> "%~n1%~2%~x1" already exists &Echo.)
GoTo :Eof

.__MY »

Это уже не суффикс, а окончание (или, как принято, расширение), и для него надо спеть другую песТню.

F-LDRkuku__MY F-LDRkuku__MY.ttt F-LDRkuku__MY.__MY F-LDRтра ля ля__MY F-LDRтра ля ля__MY.kkk F-LDRтра ля ля__MY.__MY

[YuS_2]

- это точно не с моими теперешними навыками... Выручайте... »

Дык, это же почти готовое решение, т.е. берем этот код:

Код:

for /f "delims=" %%i in ('dir /b/ad "F-LDR<"') do echo ren "%%~i" "%%~i__MY"

и превращаем его в такой:

Код:

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b/ad "F-LDR<"') do (
    set "var=%%~i"
    echo ren "%%~i" "!var:__MY=!"
)