[Iska]

1. С какого пути начинать искать — с «HKCU\Software\ConsultantPlus»?
2. Что делать, если очередной найденный файл совпадёт по имени с уже скопированным?

[V!RTuE]

1. С какого пути начинать искать — с «HKCU\Software\ConsultantPlus»? »

Да. Только в этой ветке искать все значения с параметром WrkDir. Каждое значение и является директорией, где надо искать файлы (и в подпапках этой директории)

2. Что делать, если очередной найденный файл совпадёт по имени с уже скопированным? »

Если совпадает, то сохранять наиболее "свежий"

[Iska]

V!RTuE, а сделайте-ка экспорт этого подраздела в *.reg, упакуйте его в архив и выложите — чтобы было с чем работать.

Если совпадает, то сохранять наиболее "свежий" »

«Свежий» — надо понимать как тот файл, у которого наиболее близкие дата/время последней модификации к текущей дате, так?

[V!RTuE]

V!RTuE, а сделайте-ка экспорт этого подраздела в *.reg, упакуйте его в архив и выложите — чтобы было с чем работать. »

прикрепил K+ reestr.zip

«Свежий» — надо понимать как тот файл, у которого наиболее близкие дата/время последней модификации к текущей дате, так? »

Да, всё верно.

И еще, возможно не всегда директория, указанная в качестве значения параметра в реестре, будет существовать на компьютере (Могли удалить папку, а реестр не почистить. Батник должен просто пропускать эту директорию и искать в других. Но точно хоть одна, из указанных в реестре, будет существовать).

[Iska]

Сделаем чуть иначе. Пробуйте:

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

if not exist "%~dp0123" md "%~dp0123"

for /f "usebackq tokens=3" %%i in (
	`reg.exe query "HKEY_CURRENT_USER\Software\ConsultantPlus" /s 2^>nul ^| findstr.exe /r /c:"WrkDir.*REG_SZ"`
) do if exist "%%~i\." xcopy "%%~i\*.stt" "%~dp0123" /i /s /d

endlocal
exit /b 0

[V!RTuE]

Iska, Так работает. Но копирует не только файлы, но и папки, в которых эти *.stt файлы располагаются. Как переделать чтобы в итоге в папке 123 были только файлы без папок?

Код:

C:\ConsLocalUserData\7_008390_35625.STT
C:\ConsLocalUserData\CONS.CFG\7_008390_35625.STT
C:\ConsLocalUserData\CONS.CFG\dddfd\7_003872_35625.STT
C:\ConsLocalUserData\CONS.CFG\dddfd\7_008390_35625.STT
Скопировано файлов: 4.
Для продолжения нажмите любую клавишу . . .

ну и соответсвенно в папке 123 получилось

Код:

\123\7_008390_35625.STT
\123\CONS.CFG\7_008390_35625.STT
\123\CONS.CFG\dddfd\7_003872_35625.STT
\123\CONS.CFG\dddfd\7_008390_35625.STT

И еще, код должен работать, даже если запускается на сервере. Для этого использовал такой ход

Код:

SET f=%~dp0%

и везде вместо %~dp0 использовал %f%
Что тут надо переделать тогда?

[Georgio]

Как переделать чтобы в итоге в папке 123 были только файлы без папок? »

Заменить строку

Код:

) do if exist "%%~i\." xcopy "%%~i\*.stt" "%~dp0123" /i /s /d

на строку

Код:

) do if exist "%%~i\." for /f "delims=" %%j in ('dir /a-d/b/s "%%~i\*.stt" 2^>nul') do copy "%%j" "%~dp0123">nul

.

[V!RTuE]

РЕШЕНО!!!
Georgio, Iska, Большое спасибо.
Вот получился такой код. Работает и на локальной машине и на сервере:

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

if not exist "%~dp0123" md "%~dp0123"

for /f "usebackq tokens=3" %%i in (
	`reg.exe query "HKEY_CURRENT_USER\Software\ConsultantPlus" /s 2^>nul ^| findstr.exe /r /c:"WrkDir.*REG_SZ"`
) do if exist "%%~i\." for /f "delims=" %%j in ('dir /a-d/b/s "%%~i\*.stt" 2^>nul') do copy "%%j" "%~dp0123">nul

endlocal
exit /b 0

PS. Использовать SET f=%~dp0% здесь мне не надо было, как я думал (использовал в другой части кода, где действительно это необходимо было. наверное)

[Iska]

Но копирует не только файлы, но и папки, в которых эти *.stt файлы располагаются. »

Я специально так оставил («Сделаем чуть иначе»), поскольку в простом copy нет:

Если совпадает, то сохранять наиболее "свежий" »