 |
|
Поиск файлов во вложенных папках и копирование в другую
В общем надо считать с реестра значения параметра WrkDir (=путь к рабочей директории программы) . В реестре может быть несколько параметров WrkDir (разные пути) . После полученные директории просканировать и найти в них все *.stt файлы (Искать файлы надо также во всех подпапках данных директорий) и скопировать их в папку, созданную рядом с батником (например папка будет \123).
Естественно такой код у меня не заработал
Код:
For %%A In (HKCU\Software\ConsultantPlus /v WrkDir) Do (
For /F "Tokens=3" %%B In ('Reg Query %%A /S ^| Find /I "WrkDir"') Do ( Set dir=%%B
for /f %%i in (%dir%) do (
Set FILES=%%i
Set TARGET= "%~dp0123\"
for /r %FILES% %%f in (*.stt) do (
xcopy %%f %TARGET% /y
)
)
)
)
Подскажите как это реализовать?
Например этот код:
Код:
For %%A In (HKCU\Software\ConsultantPlus /v WrkDir) Do (
For /F "Tokens=3" %%B In ('Reg Query %%A /S ^| Find /I "WrkDir"') Do Echo %%B>> "%~dp0result.txt"
)
запишет в файл 2 строки:
Код:
C:\ConsLocalUserData
C:\ConsUserData
|
1. С какого пути начинать искать — с «HKCU\Software\ConsultantPlus»?
2. Что делать, если очередной найденный файл совпадёт по имени с уже скопированным?
|
Цитата:
Цитата Iska
1. С какого пути начинать искать — с «HKCU\Software\ConsultantPlus»? »
|
Да. Только в этой ветке искать все значения с параметром WrkDir. Каждое значение и является директорией, где надо искать файлы (и в подпапках этой директории)
Цитата:
Цитата Iska
2. Что делать, если очередной найденный файл совпадёт по имени с уже скопированным? »
|
Если совпадает, то сохранять наиболее "свежий" |
V!RTuE, а сделайте-ка экспорт этого подраздела в *.reg, упакуйте его в архив и выложите — чтобы было с чем работать.
Цитата:
Цитата V!RTuE
Если совпадает, то сохранять наиболее "свежий" »
|
«Свежий» — надо понимать как тот файл, у которого наиболее близкие дата/время последней модификации к текущей дате, так?
|
Вложений: 1
Цитата:
Цитата Iska
V!RTuE, а сделайте-ка экспорт этого подраздела в *.reg, упакуйте его в архив и выложите — чтобы было с чем работать. »
|
прикрепил Файл 116470
Цитата:
Цитата Iska
«Свежий» — надо понимать как тот файл, у которого наиболее близкие дата/время последней модификации к текущей дате, так? »
|
Да, всё верно.
И еще, возможно не всегда директория, указанная в качестве значения параметра в реестре, будет существовать на компьютере (Могли удалить папку, а реестр не почистить. Батник должен просто пропускать эту директорию и искать в других. Но точно хоть одна, из указанных в реестре, будет существовать). |
Сделаем чуть иначе. Пробуйте:
Код:
@echo off
setlocal enableextensions enabledelayedexpansion
if not exist "%~dp0123" md "%~dp0123"
for /f "usebackq tokens=3" %%i in (
`reg.exe query "HKEY_CURRENT_USER\Software\ConsultantPlus" /s 2^>nul ^| findstr.exe /r /c:"WrkDir.*REG_SZ"`
) do if exist "%%~i\." xcopy "%%~i\*.stt" "%~dp0123" /i /s /d
endlocal
exit /b 0
|
Iska, Так работает. Но копирует не только файлы, но и папки, в которых эти *.stt файлы располагаются. Как переделать чтобы в итоге в папке 123 были только файлы без папок?
Код:
C:\ConsLocalUserData\7_008390_35625.STT
C:\ConsLocalUserData\CONS.CFG\7_008390_35625.STT
C:\ConsLocalUserData\CONS.CFG\dddfd\7_003872_35625.STT
C:\ConsLocalUserData\CONS.CFG\dddfd\7_008390_35625.STT
Скопировано файлов: 4.
Для продолжения нажмите любую клавишу . . .
ну и соответсвенно в папке 123 получилось
Код:
\123\7_008390_35625.STT
\123\CONS.CFG\7_008390_35625.STT
\123\CONS.CFG\dddfd\7_003872_35625.STT
\123\CONS.CFG\dddfd\7_008390_35625.STT
И еще, код должен работать, даже если запускается на сервере. Для этого использовал такой ход
и везде вместо %~dp0 использовал %f%
Что тут надо переделать тогда?
|
Цитата:
Цитата V!RTuE
Как переделать чтобы в итоге в папке 123 были только файлы без папок? »
|
Заменить строку
Код:
) do if exist "%%~i\." xcopy "%%~i\*.stt" "%~dp0123" /i /s /d
на строку
Код:
) do if exist "%%~i\." for /f "delims=" %%j in ('dir /a-d/b/s "%%~i\*.stt" 2^>nul') do copy "%%j" "%~dp0123">nul
. |
РЕШЕНО!!!
Georgio, Iska, Большое спасибо.
Вот получился такой код. Работает и на локальной машине и на сервере:
Код:
@echo off
setlocal enableextensions enabledelayedexpansion
if not exist "%~dp0123" md "%~dp0123"
for /f "usebackq tokens=3" %%i in (
`reg.exe query "HKEY_CURRENT_USER\Software\ConsultantPlus" /s 2^>nul ^| findstr.exe /r /c:"WrkDir.*REG_SZ"`
) do if exist "%%~i\." for /f "delims=" %%j in ('dir /a-d/b/s "%%~i\*.stt" 2^>nul') do copy "%%j" "%~dp0123">nul
endlocal
exit /b 0
PS. Использовать SET f=%~dp0% здесь мне не надо было, как я думал (использовал в другой части кода, где действительно это необходимо было. наверное)
|
Цитата:
Цитата V!RTuE
Но копирует не только файлы, но и папки, в которых эти *.stt файлы располагаются. »
|
Я специально так оставил («Сделаем чуть иначе»), поскольку в простом copy нет:
Цитата:
Цитата V!RTuE
Если совпадает, то сохранять наиболее "свежий" »
|
|
Время: 06:46.
© OSzone.net 2001-