[Anonymоus]

Код:

@Echo Off
SetLocal EnableDelayedExpansion
For /F "usebackq delims=" %%L In ("test.txt") Do (
	For %%A In (%%L) Do (
		Set Name=%%A
		If /I !Name:~-4!==.arj Echo get !Name!>>get.txt
	)
)

[Anufriev]

спасибо, бат работает, но не совсем так как надо

1. имя файла откуда берется текст upd_nsi_*, если так и написать в место "test.txt" ни чего не происходит (* - разные цифры, формат файла отсутствует)
2. в этом батнике они пишет все имена, даже если они повторяются, мне необходимо, что бы повторные не записывались

[Anonymоus]

Повторы убраны, перебор файлов по маске добавлен.

Код:

@Echo Off
SetLocal EnableDelayedExpansion
For /F "delims=" %%F In ('Dir "upd_nsi_*" /A-D /B') Do (
    For /F "usebackq delims=" %%L In ("%%F") Do (
        For %%A In (%%L) Do (
            Set Name=%%A
            If /I !Name:~-4!==.arj (
                Type "get.txt" 2>nul|Find "!Name!">nul||Echo get public %%A>>"get.txt"
            )
        )
    )
)
Pause&Exit

[alek2012]

Anufriev попробуй вот этой штукой Grep

Очень полезная вещь, мне кто то на этом форуме посоветовал.

[Anonymоus]

alek2012, grep для этой задачи - по моему мнению, излишество, хотя я и пропагандирую его использование везде, где cmd не справляется. Смотрите, скрипт с использованием grep стал короче:

Код:

@Echo Off
Set Path=%Path%;%CD%\bin
For /F "delims=" %%F In ('Dir "upd_nsi_*" /A-D /B') Do (
    For /F "delims=" %%L In ('grep -Eo "[^ ]*[.]arj" "%%F"') Do (
        Type "get.txt" 2>nul|Find "%%L">nul||Echo get public %%L>>"get.txt"
    )
)
Pause&Exit

Но при этом скрипт не запустится на любом компьютере (grep - внешняя утилита, её приходится таскать вместе со скриптом, а это около полутора мегабайт, сам exe и требуемые dll), кроме того, бывают случаи, когда использование сторонних утилит запрещено по соображениям безопасности.

[Anufriev]

Добрый день!

появилась проблема с этим батником, сам он работает стабильно, но файлы начали приходить с именами архивов в верхнем регистре, а выводить в файл "get.txt" нужно в нижнем регистре, не подскажете, как изменить регистр?

пример входящего текста

FIL.DBF ў б®бв*ўҐ KGRD0922.ARJ
F_ARX.DBF ў б®бв*ўҐ KGRD0922.ARJ
HDRUS_TU.DBF ў б®бв*ўҐ HD_LIST.ARJ
HD_LIST.DBF ў б®бв*ўҐ HD_LIST.ARJ
HD_OKATO.DBF ў б®бв*ўҐ HD_LIST.ARJ

[Foreigner]

Anufriev,

Код:

sed -r "s/.* (.+)$/\L\1/" 1.txt > 2.txt

[Anufriev]

Foreigner,

Если не ошибаюсь, то это команда из линухи? в винде она не катит

[Foreigner]

Если не ошибаюсь, то это команда из линухи? в винде она не катит

А grep катит? Он тоже из "линухи", если что.