[Foreigner]

Код:

@echo off
setlocal

pushd "c:\soft\program\files" || goto:eof

for /f "tokens=*" %%i in ('dir /b *.qxx') do (

    2>nul md "c:\soft\backup\%date:~-2%_%date:~3,2%_%date:~0,2%"
    copy "%%i" "c:\soft\backup\%date:~-2%_%date:~3,2%_%date:~0,2%"

)

popd

[Georgio]

Код:

@echo off
set Folder_Name=%DATE:~-2%_%DATE:~0,-8%_%DATE:~-7,2%
if not exist "C:\soft\Backup\%Folder_Name%" (
 md "C:\soft\Backup\%Folder_Name%"
)
set m=0
set n=0
for /r "C:\soft\program\files\" %%i in (*.QXX) do (
 set /a m+=1
 copy "%%i" "C:\soft\Backup\%Folder_Name%">nul 2>&1&& set /a n+=1
)
echo The %m% files were found.
echo The %n% files were copied.
pause>nul

[Опиум]

я так понимаю, что красивая конструкция %DATE:~-2%_%DATE:~0,-8%_%DATE:~-7,2%
зависит от региональных установок и не универсальна )

[i-Lex]

Прошу прощения.
Писал вечером - мозг не работал.
Нужно создать в папке C:\soft\Backup\ папку c датой в том же формате, а в ней rin480.
т.к. в C:\soft\, есть ещё папки, к которой так же будет создан скрипт, который бэкапит их содержимое в ту же папку с датой, но с другими названиями папок.

[Georgio]

Писал вечером - мозг не работал. »

Наверно, и у меня был тот же симптом: перепутал местами расширенные переменные, и у Вас создавалась папка с названием по формату даты "гг_дд_мм" вместо "гг_мм_дд". Правильный код такой:

Код:

@echo off
set Folder_Name=%DATE:~-2%_%DATE:~-7,2%_%DATE:~0,-8%
if not exist "C:\soft\Backup\%Folder_Name%" (
 md "C:\soft\Backup\%Folder_Name%"
)
set m=0
set n=0
for /r "C:\soft\program\files\" %%i in (*.QXX) do (
 set /a m+=1
 copy "%%i" "C:\soft\Backup\%Folder_Name%">nul 2>&1&& set /a n+=1
)
echo The %m% files were found.
echo The %n% files were copied.
pause>nul

Нужно создать в папке C:\soft\Backup\ папку c датой в том же формате, а в ней rin480. »

Код:

@echo off
set Folder_Name=%DATE:~-2%_%DATE:~-7,2%_%DATE:~0,-8%\rin480
if not exist "C:\soft\Backup\%Folder_Name%" (
 md "C:\soft\Backup\%Folder_Name%"
)
set m=0
set n=0
for /r "C:\soft\program\files\" %%i in (*.QXX) do (
 set /a m+=1
 copy "%%i" "C:\soft\Backup\%Folder_Name%">nul 2>&1&& set /a n+=1
)
echo The %m% files were found.
echo The %n% files were copied.
pause>nul

Ничего менять не пришлось, кроме значения переменной "Folder_Name".

[Foreigner]

я так понимаю, что красивая конструкция %DATE:~-2%_%DATE:~0,-8%_%DATE:~-7,2% зависит от региональных установок и не универсальна ) »

Да, это так. Просто не хотелось дергать за wmi:

Код:

@echo off
setlocal

set "wmi=wmic path win32_localtime get * /value"

for /f %%i in (' "%wmi%" ') do 1>nul set "%%i"

set /a year-=2000
set /a month+=100
set /a day+=100

echo %year%_%month:~-2%_%day:~-2%

Или пользоваться другими средствами автоматизации, например PowerShell:

Код:

$d = get-date -u '%y_%m_%d'
$d

[Georgio]

я так понимаю, что красивая конструкция %DATE:~-2%_%DATE:~0,-8%_%DATE:~-7,2% зависит от региональных установок и не универсальна ) »

Возможен такой вариант:

Код:

@echo off
set "#=[0-3][0-9][\.\/][0-1][0-9][\.\/][0-9]*#%DATE:~-2%_%DATE:~3,2%_%DATE:~0,2%"
set "##=[1-9][\.][1-9][\.][0-9][0-9]#%DATE:~-2%_0%DATE:~2,1%_0%DATE:~0,1%"
set "###=\<[1-9][\.][0-1][0-9][\.][0-9][0-9]#%DATE:~-2%_%DATE:~2,2%_0%DATE:~0,1%"
set "####=[0-3][0-9][\.][1-9][\.][0-9][0-9]#%DATE:~-2%_0%DATE:~3,1%_%DATE:~0,2%"
set "#####=[0-9][0-9][0-9][0-9][\-][0-1][0-9][\-][0-3][0-9]#%DATE:~2,2%_%DATE:~5,2%_%DATE:~8,2%"
for /f "tokens=1,2 delims=#=" %%i in ('set #') do (
 date /t|>nul findstr /rc:"%%i"&& set Date_Format=%%j
)
echo %Date_Format%
pause>nul

Насколько он универсален и точен не скажу.

[i-Lex]

Насчёт powershell.
Как будет выглядить скрипт полностью на нём?

[Foreigner]

Насчёт powershell. Как будет выглядить скрипт полностью на нём? »

Код:

$d = get-date -uformat "%y_%m_%d"

get-childitem 'c:\soft\program\files\*.qxx' | % { 

	if ( !( test-path "c:\soft\backup\$d" )) { new-item -type directory "c:\soft\backup\$d" }
	copy-item $_ "c:\soft\backup\$d"

}