[amel27]

Не поможешь? Пытаюсь получить список расшаренных ресурсов компьютера »

примерно так:

Код:

#include <array.au3>
$a = _NetGetShareList("")
_ArrayDisplay($a)

Func _NetGetShareList($sComputer)
    Local $EntriesRead = DllStructCreate("int")
    Local $TotalEntries = DllStructCreate("int")
    Local $pBuffer = DllStructCreate("ptr"), $tBuffer
    $aRet = DllCall("netapi32.dll", "int", "NetShareEnum", _
        "wstr", $sComputer, _
        "dword", 0, _
        "ptr", DllStructGetPtr($pBuffer), _
        "dword", -1, _
        "ptr", DllStructGetPtr($EntriesRead), _
        "ptr", DllStructGetPtr($TotalEntries), _
        "ptr", 0)
    If $aRet[0] Then Return SetError(1, $aRet[0], 0)
    $EntriesRead = DllStructGetData($EntriesRead, 1)
    Local $aRes[$EntriesRead+1]=[$EntriesRead]
    Local $SHARE_INFO_0 = DllStructCreate("ptr["& $EntriesRead &"]", DllStructGetData($pBuffer,1))
    For $i=1 To $EntriesRead
        $tBuffer = DllStructCreate("wchar[256]", DllStructGetData($SHARE_INFO_0, 1, $i))
        $aRes[$i] = DllStructGetData($tBuffer, 1)
    Next
    DllCall("netapi32.dll", "int", "NetApiBufferFree", "ptr", DllStructGetData($pBuffer,1))
    Return $aRes
EndFunc

SvetlanaK

там попадается окно с чекбоксами »

все зависит от контрола - точнее от того, насколько он совместим со стандартными от Microsoft, нужно пробовать... анализ пикселей это крайний случай