[artem_]

Или vb script

Код:

strDriveLetter_DBS = "P:"
strRemotePath_DBS  = "\\10.10.5.1\PRIVATE$"
strDriveName_DBS   = "PRIVATE"

'----------------------------------------------------------------------------------------------------

'процедура подключения сетевых дисков
Sub MapNetDriveNamed(Letter, Path, DriveName)
  'мапим
  Set objNetwork = CreateObject("WScript.Network")
  objNetwork.MapNetworkDrive Letter, Path
  'переименовываем
  Set objShell = CreateObject("Shell.Application")
  objShell.NameSpace(Letter).Self.Name = DriveName
End Sub

'функция проверки подключения сетевых дисков
function IsNetDriveConnected(Letter)
  Set objNetwork = CreateObject("WScript.Network")
  Set CheckDrive = objNetwork.EnumNetworkDrives()
  For intDrive = 0 To CheckDrive.Count - 1 Step 2
    If (CheckDrive.Item(intDrive) = Letter) Then IsNetDriveConnected = true 
  Next 
End Function

'----------------------------------------------------------------------------------------------------

'проверка на наличие сетевых дисков в системе
If IsNetDriveConnected(strDriveLetter_DBS) Then
  'WScript.echo "ОШИБКА подключения сетевых дисков или один из дисков уже подключен"
  WScript.Quit
End If

'мапим общий сетевой диск
Call MapNetDriveNamed(strDriveLetter_DBS, strRemotePath_DBS, strDriveName_DBS)

WScript.Quit

Если несколько дисков можно сделать параметризированный скрипт или прописать массив который будет в себе держать букву, название и путь