[Maza Faka]

Можно примерчик кода небольшой »

Что-то вроде этого:

Код:

#include <GuiConstants.au3>

Global $CfgFile = @ScriptDir & "\Config.ini"

Global $Input_State = IniRead($CfgFile, "Settings", "Input", "")
Global $Radio1_State = IniRead($CfgFile, "Settings", "Radio1", 4)
Global $Radio2_State = IniRead($CfgFile, "Settings", "Radio2", 4)
Global $CheckBox1_State = IniRead($CfgFile, "Settings", "CheckBox1", 4)
Global $CheckBox2_State = IniRead($CfgFile, "Settings", "CheckBox2", 4)

$hGUI = GUICreate("Test GUI", 320, 240)

$hInput = GUICtrlCreateInput("", 10, 10, 160, 20)
GUICtrlSetData(-1, $Input_State)

GUICtrlCreateGroup("Group", 10, 50, 160, 100)
$Radio1 = GUICtrlCreateRadio("Radio1", 20, 75, 60, 16)
GUICtrlSetState(-1, $Radio1_State)
$Radio2 = GUICtrlCreateRadio("Radio2", 20, 120, 60, 16)
GUICtrlSetState(-1, $Radio2_State)
GUICtrlCreateGroup("", -99, -99, 1, 1)

$CheckBox1 = GUICtrlCreateCheckbox("Param 1", 200, 75, 60, 20)
GUICtrlSetState(-1, $CheckBox1_State)

$CheckBox2 = GUICtrlCreateCheckbox("Param 2", 200, 120, 60, 20)
GUICtrlSetState(-1, $CheckBox2_State)

$AcceptButton = GUICtrlCreateButton("Ok", 10, 200, 60, 25)

$CancelButton = GUICtrlCreateButton("Cancel", 250, 200, 60, 25)

GUISetState()

While 1
    $msg = GUIGetMsg()

    Switch $msg
    Case $GUI_EVENT_CLOSE, $CancelButton
        ExitLoop
    Case $AcceptButton
        _SaveCfg()
        ExitLoop
    EndSwitch
WEnd

Func _SaveCfg()
    IniWrite($CfgFile, "Settings", "Input", GUICtrlRead($hInput))
    IniWrite($CfgFile, "Settings", "Radio1", GUICtrlRead($Radio1))
    IniWrite($CfgFile, "Settings", "Radio2", GUICtrlRead($Radio2))
    IniWrite($CfgFile, "Settings", "CheckBox1", GUICtrlRead($CheckBox1))
    IniWrite($CfgFile, "Settings", "CheckBox2", GUICtrlRead($CheckBox2))
EndFunc