[amel27]

Creat0R

Или что-то другое имеется в виду? покажи плиз на примере »

ура, дошло! ...извиняюсь, невнимательно читал твой код
провел вот такой эксперимент:

Код:

#include <GUIConstants.au3>
#include <GuiTreeView.au3>
Opt("GuiOnEventMode", 1)

$Gui = GUICreate("Test", 300, 200)
GUISetOnEvent(-3, "OnExit")

$TreeView = GUICtrlCreateTreeView(20, 20)
$hTreeView= IDToHwnd($Gui, $TreeView) ; хэндл $TreeView

$TV_ID1 = GUICtrlCreateTreeViewItem("Created1", $TreeView)
$hItem = _GUICtrlTreeViewInsertItem($TreeView, "Inserted1")
$TV_ID2 = GUICtrlCreateTreeViewItem("Created2", $TreeView)

GUISetOnEvent(-3, "OnExit")
GUISetState()

; отсюда видно что элемент, вставленный через _GUICtrlTreeViewInsertItem()
; не получает своего ControlID (нумерация ID сквозная)
ConsoleWrite($TreeView&@CRLF) ; ControlID $TreeView
ConsoleWrite($TV_ID1  &@CRLF) ; ControlID $TV_ID1
                              ; тут должен был быть ControlID $hItem
ConsoleWrite($TV_ID2  &@CRLF) ; ControlID $TV_ID2

; это просто хэндл $TreeView
ConsoleWrite(@CRLF)
ConsoleWrite('0x'&Hex($hTreeView)&@CRLF)

; видно, что Hwnd элементов TreeView не являетя Hwnd окна:
ConsoleWrite(@CRLF)
ConsoleWrite('0x'&Hex(IDToHwnd($Gui, 4))&@CRLF)
ConsoleWrite('0x'&Hex(IDToHwnd($Gui, 5))&@CRLF)
; или даже так, один фиг:
ConsoleWrite(@CRLF)
ConsoleWrite('0x'&Hex(IDToHwnd($hTreeView, 4))&@CRLF)
ConsoleWrite('0x'&Hex(IDToHwnd($hTreeView, 5))&@CRLF)

While 1
    Sleep(100)
WEnd

Func HwndToID($hWnd)
    Local $iRet = DllCall("user32.dll", "int", "GetDlgCtrlID", "hwnd", $hWnd)
    Return $iRet[0]
EndFunc

Func IDToHwnd($hWndMain, $CtrlID)
    Local $iRet = DllCall("user32.dll", "int", "GetDlgItem", "hwnd", $hWndMain, "int", $CtrlID)
    Return $iRet[0]
EndFunc

Func OnExit()
    Exit
EndFunc

ведь если поставить событие для TreeView, то оно не срабатывает как таковое »

Хм... вот это странно, ведь ControlID у него есть... можно было и сделать для случая клика на любом пункте TreeView

но с ограничением в количестве создаваемых элементов »

откуда инфа и чем ограничено количество?...
может ограничение как раз и связано с присвоением пунктам ControlID?

так глядишь и сам начну понимать кой-чего в ГУИ

[Creat0R]

amel27,

ура, дошло!

Хм... вот это странно, ведь ControlID у него есть... можно было и сделать для случая клика на любом пункте TreeView

С ListView подобна структура срабатывает, видимо потому что у него есть заголовок.

откуда инфа и чем ограничено количество?

Инфа из справки как ни странно

Maximum number of GUI controls per window: 4096

Но как говорится, «Доверяй но проверяй», вот я и проверяю:

Код:

#include <GUIConstants.au3>
Opt("GuiOnEventMode", 1)

$Gui = GUICreate("Test", 300, 200)
GUISetOnEvent(-3, "OnExit")

$TreeView = GUICtrlCreateTreeView(20, 20)

GUISetState()

For $i = 1 To 4100
    $Item = GUICtrlCreateTreeViewItem("Item " & $i, $TreeView)
    If $Item Then
        PrintF("Created Item: " & $i)
    Else
        PrintF("Oops, we have reached the limit on Item: " & $i-1)
        ExitLoop
    EndIf
Next

While 1
    Sleep(100)
WEnd

Func PrintF($Str, $Line=@ScriptLineNumber)
    ConsoleWrite(@LF & "+======================================================" & @LF & _
                "--> Script Line (" & $Line & "):" & @LF & "!" & @TAB & $Str & @LF & _
                "+======================================================")
EndFunc

Func OnExit()
    Exit
EndFunc

Создание останавливается на 4095 потому что создание самого TreeView это уже первый контрол.

[TERMINAL]

какая команда делает печать?

[amel27]

Creat0R
может через GUIRegisterMsg() типа такого?

Код:

#include <GUIConstants.au3>
#include <A3LConstants.au3>
#include <GuiTreeView.au3>

Opt("GuiOnEventMode", 1)

$Gui = GUICreate("Test", 300, 200)
GUISetOnEvent(-3, "OnExit")
$nTreeView = GUICtrlCreateTreeView(20, 20)
$hTreeView = IDToHwnd($Gui, $nTreeView)
$nTV1_ID = _GUICtrlTreeViewInsertItem($nTreeView,"Inserted1")
$nTV2_ID = _GUICtrlTreeViewInsertItem($nTreeView,"Inserted2")

GUIRegisterMsg ($WM_NOTIFY, "TV_Event")
GUISetState()

While 1
    Sleep(100)
WEnd

Func TV_Event($hWnd, $Msg, $wParam, $lParam)
    If $Msg = $WM_NOTIFY Then
        Local $NMHDR = DllStructCreate("hwnd;uint;short", $lParam)
        If DllStructGetData($NMHDR, 1)=$hTreeView And DllStructGetData($NMHDR,3)=-451 Then
            ConsoleWrite(_GUICtrlTreeViewGetTree($nTreeView,'\')&@CRLF)
        EndIf
    EndIf
    Return $GUI_RUNDEFMSG
 EndFunc

Func OnExit()
    Exit
EndFunc

Func HwndToID($hControlID)
    $iRet = DllCall("user32.dll", "int", "GetDlgCtrlID", "hwnd", $hControlID)
    Return $iRet[0]
EndFunc

Func IDToHwnd($hWnd, $CtrlID)
    $iRet = DllCall("user32.dll", "int", "GetDlgItem", "hwnd", $hWnd, "int", $CtrlID)
    Return $iRet[0]
EndFunc

З.Ы. я уже сталкивался ранее с контролами без ControlID при установке специфического софта... вот я с ними тогда помучился... собсно из-за них и пришлось лезть в дебри

[mikola1983]

как передать строку?
вобщем есть вот это:
$file = FileOpen("c:\1.txt", 0)
$line = FileReadLine($file)
If @error = -1 Then ExitLoop
Run ("notepad.exe")
WinWait("Untitled - Notepad","")
If Not WinActive("Untitled - Notepad","") Then WinActivate("Untitled - Notepad","")
WinWaitActive("Untitled - Notepad","")
Send(GUICtrlRead($line))
но в нотпаде пишет НОЛЬ вместо определенного ключа . есть ли возможность вставить этот ключ в окно программы желательно посимвольно через SEND т.к. 4 окна.
и еше хотелось бы удалять использованный ключ

[Maza Faka]

mikola1983

Send(GUICtrlRead($line))

Это что?
Как я понял ты хочешь выслать строку в блокнот?
Сделай так:

Код:

ControlSend("Untitled - Notepad", "", "Edit1", $line)

[Creat0R]

TERMINAL,

какая команда делает печать?

Конкретной такой команды нет, но для печати документа с файла можно использовать ShellExecute()....

Код:

ShellExecute("MyFile.txt", "", @ScriptDir, "Print")

amel27,

может через GUIRegisterMsg() типа такого?

О, оно работает получше чем все мои попытки (я пробовал через другие сообщения, например улавливал нажатия мышки, но не всегда срабатывало).
Спасибо!

P.S
Функция IDToHwnd() не обязательна в этом случае, можно просто использовать GUICtrlGetHandle($nTreeView)

[amel27]

Creat0R

Конкретной такой команды нет

Как же нет?.. по справке как минимум две: _FilePrint() и _WordDocPrint()
первая по сути тот же ShellExecute(), а вторая специально для печати документов MS Word, пример:

Код:

#include <Word.au3>

$sDocPath = @ScriptDir & "\Test.doc" ; путь к документу Word

$oWordApp = _WordCreate ("") ; создаем объект MS Word
$oDoc = _WordDocOpen ($oWordApp, $sDocPath) ; открываем существующий файл
_WordDocPrint ($oDoc) ; печатаем документ
_WordQuit ($oWordApp, 0) ; закрываем окно и освобождаем объект

необязательные параметры:

$b_Background - ожидать или нет завершения печати;
$i_Copies - количество экземпляров;
$i_Orientation - ориентация страницы (книга/альбом);
$b_Collate - разобрать по копиям;
$s_Printer - выбор принтера (имя);
$i_Range - выбор страниц для печати;
$i_From - с какой страницы (для $i_Range=3);
$i_To - по какую страницу печатать (для $i_Range=3);
$s_Pages - список страниц через запятую (для $i_Range=4);
$i_PageType - все/четные/нечетные;
$i_Item - печать дополнительных элементов.

оно работает

угу, только я не совсем понял насчет сообщения $TVN_SELCHANGED - в "A3LTreeView.au3" определен $TVN_SELCHANGEDA = $TVN_FIRST-2 (-402), а по факту приходит $TVN_SELCHANGEDW = $TVN_FIRST-51 (-451)

[Creat0R]

amel27,

по справке как минимум две: _FilePrint() и _WordDocPrint()

Я про UDF'ы забыл, прошёлся поиском по обычной справке, а там только ShellExecute всплыл как вариант.

[fak1r]

Добрый вечер.
Вот есть 2 вопроса:

1 Как сделать чтобы можно было скомпилированому файлу автоита передавать даные через ключи, например так:

Код:

script.exe /f "list.txt"

или так

Код:

script.exe /h /d /s

?

2 Как сделать так чтобы результат выполнения например функции ProcessList(выводит массив со списком процесов) выдавался в командную строку windows?