[Maza Faka]

Creat0R

Твой пример не работает?

Работает, но только для RadioButton, а мне надо для Button.

[Creat0R]

amel27,

во замутил!

у меня вроде получилось без RegExp:

Класс.. правда пока не понял как оно работает.. кстати, тут тоже проблема с буквами е/ё.. если выделить две буквы одна из которых буква е, то выделение неверно делается.
Но в сравнении моя функция всё же быстрее - но полагаю твой пример будет надёжнее (если поправить недочёты с е/ё и т.п).

Ранее уже постил свой вариант через API

Спасибо, но это не совсем то, мне нужно не позиции, а проверить существование элементов - Я заранее не знаю как именуется Мой компьютер (к примеру), на разных машинах по разному, мне нужно получить универсальное название, и сравнить со списком (который я получаю с рабочего стола, но другим методом, используются функции от A3LLibrary).
Т.е по сути нужно проверить типа..

Код:

If FileExists(@DesktopDir & "\Мой компьютер") Then...

Естественно так не работает...

А зачем Send('{CTRLDOWN}') Send('{CTRLUP}'), от залипаний Ctrl?

да, от залипании, не знаю почему, но иногда залипает (сейчас наверно можно убрать, т.к Ctrl не используется при вызове конвертировании).

[Maza Faka]

Почему функция AdlibEnable начинает работать только после того, как файл скопировался?

Код:

#include <Misc.au3>
Opt("MouseCoordMode", 2)

AdlibEnable("Check", 100)

Dim $title = "Копирование..."
Dim $dll = DllOpen("user32.dll")

$sCopy = CopyFile("d:\Video\Films\video.avi", "c:\")

Func CopyFile($source, $dest)
    $WinShell = ObjCreate("shell.application")
    If Not @error Then
        $WinShell.NameSpace($dest).CopyHere($source)
        AdlibDisable()
    Else
        MsgBox(16, "Error", "Obj not create")
    EndIf
EndFunc

Func Check()
    MsgBox(0, "", "test") ;Это для проверки вызова функции
    If WinActive($title) Then
        If _IsPressed(01, $dll) Then
            $mousePos = MouseGetPos()
            If $mousePos[0] > 303 And $mousePos[0] < 362 And $mousePos[1] > 102 And $mousePos[1] < 124 Then MsgBox(0, "", "Button pressed")
            EndIf
        EndIf
    EndFunc

[amel27]

не понял как оно работает

если грубо... выделяем с CTRL пока размер выделенного фрагмента не превысит исходный (из буфера), потом возвращаемся обратно но уже без CTRL

тут тоже проблема

исправил, алгоритм не зависит от текста

не знаю как именуется Мой компьютер

там же добавил линк на параметры реестра

[Creat0R]

amel27,

выделяем с CTRL пока размер выделенного фрагмента не превысит исходный (из буфера), потом возвращаемся обратно но уже без CTRL

Вот если бы можно было быстрее это делать... при длинном выделении очень медленно получается.

Мне удалось в моей функции преодалеть проблемы когда выделялся весь текст если исходное выделение было посредине слова.. плюс я вспомнил, ведь есть ещё Opt("SendKeyDelay", 0) и Opt("SendKeyDownDelay", 0) - увеличивает скорость в несколько раз (на коротком выделении почти мгновенно)...

Вот финальная версия (с использованием обычного массива, без Dictionary, мне если честно немного не привычно ориентироваться в нём):

Код:

#NoTrayIcon
Opt("SendKeyDelay", 0)
Opt("SendKeyDownDelay", 0)
HotKeySet("`", "ConvertProc")
HotKeySet("^q", "Quit")

While 1
    Sleep(100)
WEnd

Func ConvertProc()
    Local $OldClip = ClipGet()
    ClipPut("")
    Send("^{Insert}")
    Local $SelectedText = ClipGet()
    If $SelectedText = "" Then
        HotKeySet("`")
        Send("`")
        HotKeySet("`", "ConvertProc")
        Return
    EndIf

    Local $NewClip = ConvertText($SelectedText)

    ClipPut($NewClip)
    Send("+{Insert}")
    RestoreSelection($NewClip)
    ClipPut($OldClip)
EndFunc

;If $Mode = 0 Then Russian language used
;If $Mode = 1 Then English language used
;If $Mode = -1 Then String Inverted
Func ConvertText($Text, $Mode=-1)
    Local $StringIsUpper = 0, $TextRet = ""
    Local $SplitTextArr = StringSplit($Text, "")
    Local $LettersArr = GetLettersArr()

    For $i = 1 To $SplitTextArr[0]
        Local $i_0 = 1, $i_1 = 0
        $StringIsUpper = 0
        If StringIsUpper($SplitTextArr[$i]) Then $StringIsUpper = 1

        If $Mode = 0 Or ($Mode = -1 And StringIsASCII($Text)) Then Local $i_0 = 0, $i_1 = 1

        For $j = 1 To $LettersArr[0][0]
            If $SplitTextArr[$i] = $LettersArr[$j][$i_0] Then
                $SplitTextArr[$i] = $LettersArr[$j][$i_1]
                ExitLoop
            EndIf
        Next

        If $StringIsUpper = 1 Then $SplitTextArr[$i] = StringUpper($SplitTextArr[$i])
        $TextRet &= $SplitTextArr[$i]
    Next
    Return $TextRet
EndFunc

Func GetLettersArr()
    Local $AnsiStr = "ёйцукенгшщзхъфывапролджэячсмитьбю.?"
    Local $AsciiStr = "`qwertyuiop[]asdfghjkl;'zxcvbnm,./&"
    Local $StrLenght = StringLen($AnsiStr)

    Local $LettersArr[$StrLenght+1][2]
    $LettersArr[0][0] = $StrLenght

    For $i = 1 To $StrLenght
        $LettersArr[$i][0] = StringMid($AsciiStr, $i, 1)
        $LettersArr[$i][1] = StringMid($AnsiStr, $i, 1)
    Next

    Return $LettersArr
EndFunc

Func RestoreSelection($rText)
    Local $LeftJumps = GetLeftJumps($rText)
    Send("^+{LEFT " & $LeftJumps & "}")
    Send("^{Insert}")
    Local $NewSelText = ClipGet()
    If StringLen($NewSelText) > StringLen($rText) Then Send("+{RIGHT " & StringLen($NewSelText) - StringLen($rText) & "}")
EndFunc

Func GetLeftJumps($Text)
    StringRegExpReplace($Text, '\n', '')
    Local $Extended = @extended

    $Text = StringStripWS($Text, 3)
    $Text = StringRegExpReplace($Text, '\s+|\t+', ' ')
    $Text = StringRegExpReplace($Text, '~|`|!|#|%|\^|&|\*|\(|\)|-|\+|=|\{|\}|''|"|;|:|/|\\|<|>|\?|,|\[|\]|ч|Ч|ё|Ё', '|')
    $Text = StringRegExpReplace($Text, '\|+', '|')

    Local $WordsCountArr = StringRegExp($Text, "[\s\.:;,]*([а-яА-Яa-zA-Z0-9-_]+)[\s\.:;,]*", 3)
    StringRegExpReplace($Text, '\|', '')
    $Extended += @extended + UBound($WordsCountArr)
    Return $Extended
EndFunc

Func Quit()
    Exit
EndFunc

там же добавил линк на параметры реестра

Спасибо, полезный линк - правда нужной инфы я там не нашёл, а я прочитал каждую строчку на той страничке

[Creat0R]

Maza Faka,

Почему функция AdlibEnable начинает работать только после того, как файл скопировался?

Она не успевает срабатывать, и функция AdlibDisable() её отключает, попробуй уменьшить время запуска Adlib...
Просто ставим MsgBox под AdlibDisable и мы в этом убеждаемся

Я так понял нужно определить было ли отменено копирование? попробуй использовать Callback функции из примера что я приводил ранее, там скрипт не останавливается на момент копирования.

Вот кстати полезная ссылка по обьекту shell.application - http://msdn2.microsoft.com/en-us/library/aa969392.aspx (в вот конкретно по CopyHere).

[amel27]

нужной инфы я там не нашёл »

Добавляет Мой Компьютер,Мои Документы,Мое Сетевое окружение,Internet Explorer на Рабочий Стол

как Punto Switcher распознаёт текст в любом месте? »

как тебе точка зрения Absurd: http://forum.developing.ru/archive/i...hp/t-1365.html
у меня получилось только открывать/читать URL непосредственно с вкладок:

Код:

Global Const $DMLERR_NO_ERROR = 0x0
Global Const $DMLERR_ADVACKTIMEOUT = 0x4000
Global Const $DMLERR_BUSY = 0x4001
Global Const $DMLERR_DATAACKTIMEOUT = 0x4002
Global Const $DMLERR_DLL_NOT_INITIALIZED = 0x4003
Global Const $DMLERR_DLL_USAGE = 0x4004
Global Const $DMLERR_EXECACKTIMEOUT = 0x4005
Global Const $DMLERR_INVALIDPARAMETER = 0x4006
Global Const $DMLERR_LOW_MEMORY = 0x4007
Global Const $DMLERR_MEMORY_ERROR = 0x4008
Global Const $DMLERR_NOTPROCESSED = 0x4009
Global Const $DMLERR_NO_CONV_ESTABLISHED = 0x400A
Global Const $DMLERR_POKEACKTIMEOUT = 0x400B
Global Const $DMLERR_POSTMSG_FAILED = 0x400C
Global Const $DMLERR_REENTRANCY = 0x400D
Global Const $DMLERR_SERVER_DIED = 0x400E
Global Const $DMLERR_SYS_ERROR = 0x400F
Global Const $DMLERR_UNADVACKTIMEOUT = 0x4010
Global Const $DMLERR_UNFOUND_QUEUE_ID = 0x4011

; Возвращает/открывает URL страницы на заданной вкладке Оперы.
; $sURL - адрес открываемой страницы,
;   если задана пустая строка возвращает адрес заданного окна.
; $hWin - номер вкладки обозревателя,
;    0 новая вкладка (при открытии),
;   -1 текущая вкладка.
; $iWait - таймаут ожидания в миллисекундах, при превышении будет выдана ошибка.
Func OperaOpenURL($sURL = "", $hWin = -1, $iWait = 10000)
    Local $ret, $err, $uIdInst = DllStructCreate("int")
    Local $hServer[1], $hTopic[1], $hItem[1], $hConv[1], $hData[1], $sData[1]
    Local $sTopic = "WWW_OpenURL", $sItem = $sURL&',,0x'&Hex($hWin)
    If $sURL='' Then
         $sTopic = "WWW_GetWindowInfo"
        $sItem = "0x"&Hex($hWin)
    EndIf
    Local $hDll = DllOpen("user32.dll")
    If $hDll=-1 Then Return SetError(1, 0, "") ; Ошибка открытия DLL
    $ret = DllCall("user32.dll", "int", "DdeInitialize", "ptr", DllStructGetPtr($uIdInst), "ptr", 0, "int", 0, "int", 0)
    If $ret[0] Then Return SetError(2, $ret[0], "") ; Ошибка инициализации DDE
    $hServer = DllCall($hDll, "int", "DdeCreateStringHandle", "int", DllStructGetData($uIdInst,1), "str", "opera", "int", 1004)
    If $hServer[0] Then
        $hTopic = DllCall($hDll, "int", "DdeCreateStringHandle", "int", DllStructGetData($uIdInst,1), "str", $sTopic, "int", 1004)
        If $hTopic[0] Then
            $hItem = DllCall($hDll, "int", "DdeCreateStringHandle", "int", DllStructGetData($uIdInst,1), "str", $sItem, "int", 1004)
            If $hItem[0] Then
                $hConv = DllCall($hDll, "int", "DdeConnect", "int", DllStructGetData($uIdInst,1), "int", $hServer[0], "int", $hTopic[0], "int", 0)
                If $hConv[0] Then
                    $hData = DllCall($hDll, "int", "DdeClientTransaction", "ptr", 0, "int", 0, "int", $hConv[0], "int", $hItem[0], "int", 1, "int", 0x20B0, "int", $iWait, "ptr", 0)
                    If $hData[0] Then
                        $sData = DllCall($hDll, "str", "DdeAccessData", "int", $hData[0], "ptr", 0)
                    EndIf
                EndIf
            EndIf
        EndIf
    EndIf
    $err = DllCall($hDll, "int", "DdeGetLastError", "int", DllStructGetData($uIdInst,1))
    If $hData[0] Then DllCall($hDll, "int", "DdeFreeDataHandle", "int", $hData[0])
    If $hConv[0] Then DllCall($hDll, "int", "DdeFreeDataHandle", "int", $hConv[0])
    If $hItem[0] Then DllCall($hDll, "int", "DdeFreeDataHandle", "int", $hItem[0])
    If $hTopic[0] Then DllCall($hDll, "int", "DdeFreeDataHandle", "int", $hTopic[0])
    If $hServer[0] Then DllCall($hDll, "int", "DdeFreeDataHandle", "int", $hServer[0])
    If $err[0] Then Return SetError(3, $err[0], "") ; Другие ошибки DDE
    DllCall($hDll, "int", "DdeUninitialize", "int", DllStructGetData($uIdInst,1))
    DllClose($hDll)
    If $sURL='' Then $sURL = StringRegExpReplace($sData[0],'^"([^"]*?)".*','\1')
    Return $sURL
EndFunc

[Maza Faka]

Creat0R

Я так понял нужно определить было ли отменено копирование?

Сделал так:
Основной скрипт:

Код:

$sCopy = CopyFile("d:\Video\Films\video.avi", "c:\")

Func CopyFile($source, $dest)
    $WinShell = ObjCreate("shell.application")
    If Not @error Then
        Run("c:\Program Files\AutoIt3\AutoIt3.exe " & @ScriptDir & "\check.au3")
        $WinShell.NameSpace($dest).CopyHere($source)
    Else
        MsgBox(16, "Error", "Obj not create")
    EndIf
EndFunc

А это дополнительный, который вызывается перед копированием:

Код:

#include <Misc.au3>
Opt("MouseCoordMode", 2)

Dim $title = "Копирование..."
Dim $dll = DllOpen("user32.dll")

WinWait($title)

While WinExists($title)
    If WinActive($title) Then
        If _IsPressed(01, $dll) Then
            $mousePos = MouseGetPos()
            If $mousePos[0] > 303 And $mousePos[0] < 362 And $mousePos[1] > 102 And $mousePos[1] < 124 Then
                WinClose($title)
                MsgBox(16, "Error", "Copying aborted")
                Exit
            EndIf
        EndIf
    EndIf
    Sleep(10)
WEnd
MsgBox(64, "Success", "File copying successfuly")

Теперь бы оформить всё это красиво, например прописать содержимое доп. скрипта в основной, что бы скрипт вызывал сам себя, а не доп. скрипт. Помоги плиз.

[Creat0R]

amel27,

Добавляет Мой Компьютер,Мои Документы...

Это я видел, но это не помагает решить полностью проблему - У меня список содержит имена, как я проверю что именно эти имена (элементы) на рабочем столе?

как тебе точка зрения Absurd

Абсурдная

у меня получилось только открывать/читать URL непосредственно с вкладок:

Прямой доступ к DDE!!! я это давно искал, биг Thanks!!!

Maza Faka,
Такое лучше сделать через Callback... щас попробую нарисовать пример...

попробую нарисовать

Вот:

Код:

#include <GUIConstants.au3>
#include <Misc.au3>
#include "DllCallBack.au3"
Opt("GuiOnEventMode", 1)

Global $pTimerProc, $uiTimer

$sCopy = CopyFile("d:\Video\Films\video.avi", "c:\")

MsgBox(64, "Success", "File copying successfuly")

Quit()

Func CopyFile($source, $dest)
    $WinShell = ObjCreate("shell.application")
    If Not @error Then
        InitializeCallBack(100)
        $WinShell.NameSpace($dest).CopyHere($source)
    Else
        MsgBox(16, "Error", "Obj not create")
    EndIf
EndFunc

Func InitializeCallBack($CallEvery, $FuncName="MyCallBackFunc")
    $pTimerProc = _DllCallBack($FuncName, "hwnd;uint;uint;dword")
    $uiTimer = DllCall("user32.dll", "uint", "SetTimer", "hwnd", 0, "uint", 0, "int", $CallEvery, "ptr", $pTimerProc)
    $uiTimer = $uiTimer[0]
EndFunc

Func MyCallBackFunc($hWnd, $uiMsg, $idEvent, $dwTime)
    Opt("MouseCoordMode", 2)

    Local $Title = "Копирование..."
    If WinExists($Title) And WinActive($Title) Then
        If _IsPressed(01) Then
            $mousePos = MouseGetPos()
            If $mousePos[0] > 303 And $mousePos[0] < 362 And $mousePos[1] > 102 And $mousePos[1] < 124 Then
                WinClose($Title)
                MsgBox(16, "Error", "Copying aborted")
                Quit()
            EndIf
        EndIf
    EndIf
EndFunc

Func Quit($Exit=1)
    _DllCallBack_Free($pTimerProc)
    DllCall("user32.dll", "int", "KillTimer", "hwnd", 0, "uint", $uiTimer)
    If $Exit Then Exit
EndFunc

Саму библиотеку DllCallBack.au3 скачать можно тут.

[amel27]

Creat0R

У меня список содержит имена, как я проверю что именно эти имена (элементы) на рабочем столе? »

смотри HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\CLSID, параметр "по умолчанию"... если пусто, значит берется дефолтовый из HKLM\SOFTWARE\Classes\CLSID