[Maza Faka]

DenchikK
Может так:

Код:

Case $Proxy

          For $i = 1 To UBound($Proxy_Array)-1
          ControlSend ('Programs', '', 'Edit4', $proxy_Array[$i] & @CR)
          Next

[Creat0R]

amel27

используй флаг $BIF_NONEWFOLDERBUTTON = 0x200

Спасибо.

DenchikK

чтоб по нажатию клавиши, в поле вписывалась бы первая строчка текстового файла, повторное нажатие - 2 строчка

Имхо, нужно установить счётчик кликании...

Код:

#include <GuiConstants.au3>

$Gui = GuiCreate("Programs")

$Edit = GUICtrlCreateInput("", 20, 60)

$Button = GUICtrlCreateButton("Заполнить", 20, 350)

$Clicks = 0
$File = "C:\File.txt"

GUISetState()

While 1
    $Msg = GUIGetMsg()
    Switch $Msg
        Case -3
            Exit
        Case $Button
            $Clicks += 1
            ControlSetText('Programs', '', $Edit, FileReadLine($File, $Clicks))
    EndSwitch
WEnd

[Diamond]

Maza Faka

Как отключить монитор используя WinApi? >>>

Посмотрите функцию MonitorToggle() от greenmachine.

[Creat0R]

Maza Faka

Как отключить монитор используя WinApi?

Немного изменённый пример с оф. форума:

Код:

#NoTrayIcon

Opt("TrayMenuMode", 1)
Opt("WinTitleMatchMode", 4)

HotKeySet("{F11}", "Monitor_Off")
HotKeySet("{F10}", "Monitor_On")
HotKeySet("{Esc}", "Quit")

While 1
    Sleep(100)
WEnd

Func Quit()
    Monitor_On()
    Exit
EndFunc

Func Monitor_On()
    Local $hwnd = WinGetHandle('classname=Progman')
    DllCall('user32.dll', 'int', 'SendMessage', 'hwnd', $hwnd, 'int', 274, 'int', 61808, 'int', -1)
EndFunc

Func Monitor_Off()
    Local $hwnd = WinGetHandle('classname=Progman')
    Sleep(500)
    DllCall('user32.dll', 'int', 'SendMessage', 'hwnd', $hwnd, 'int', 274, 'int', 61808, 'int', 2)
EndFunc

[Creat0R]

Есть такая задача:

Нужно отключить полностью интернет, и подключить через несколько секунд заного..

Пробовал Rasdial, он только отключает, подключать не хочет... хотелось как нибудь добиться этого надёжным путём, т.е чтобы не зависило от типа/имени/настроек подключения.

P.S
Более полу часа провёл в поисках решения на оф. форуме и естествеено в этой ветке, но увы не нашёл .

[Maza Faka]

Creat0R
Спасибо, а где можно найти подробное описание этой функции? А то в справке очень кратко. В частности не понятны числа "274" и "61808", что они означают?

[Creat0R]

Maza Faka

то они означают?

Эх, чтоб я так знал - Это что то вроде адресов (параемтры) для вызова функции в Dll'ке.

[Diamond]

Maza Faka

не понятны числа "274" и "61808", что они означают? >>>

WM_SysCommand = 0x0112
WM_SysCommand - Уведомляет окно о том что выбран именно системный элемент меню, обычно эта команда высылается окну если пользователь щёлкает кнопку свёртывания, развёртывания или закрытия, на панели окна справа.
Что такое SC_MonitorPower = 0xF170 я к сожалению не знаю... самому интересно...

[amel27]

что они означают?

http://msdn2.microsoft.com/en-us/library/ms646360.aspx

Creat0R

Нужно отключить полностью интернет, и подключить через несколько секунд заного..

к примеру, временно выставить настройки на несуществующий прокси

[Diamond]

Я немного изменил функцию от greenmachine.

Код:

MonitorState(2) ; выключить
Sleep(20000)
MonitorState(-1) ; включить

;~ $mode:
;~ -1 - переводит монитор в нормальный, рабочий режим;
;~ 0 - переводит монитор в режим легкого засыпания
;~ 1 - переводит монитор в спящий режим
;~ 2 - монитор выключается.

Func MonitorState($mode)
	$Old_Opt = Opt("WinTitleMatchMode", 4)
	Local Const $WM_SYSCommand = 0x112
	Local Const $SC_MonitorPower = 0xF170
	Local $HWND = WinGetHandle("classname=Progman")
	DllCall("user32.dll", "int", "SendMessage", "hwnd", $HWND, "int", $WM_SYSCommand, _
	"int", $SC_MonitorPower, "int", $mode)
	Opt("WinTitleMatchMode", $Old_Opt)
EndFunc

P.S. Некоторые режимы($mode), поддерживаются не всеми мониторами.
Например у меня не работает режим легкого засыпания($mode=0).