[amel27]

Creat0R
как и следовало ожидать, piccaso предложил свой новый безDLL'ный метод... хотя он и позволяет использовать все возможности диалоговых окон (в т.ч. Explorer style) по причине нехватки времени пока тупо перегнал _FileSelectFolderOldStyle()

Код:

#include <GUIConstants.au3>
#include <DllCallBack.au3>

Global Const $BFFM_INITIALIZED = 1
Global Const $BFFM_SETSELECTION = $WM_USER + 102

Global Const $BIF_BROWSEFORCOMPUTER = 0x1000 ; Only return computers
Global Const $BIF_BROWSEFORPRINTER = 0x2000 ; Only allow the selection of printers
Global Const $BIF_BROWSEINCLUDEFILES = 0x4000 ; The browse dialog box will display files as well as folders
Global Const $BIF_DONTGOBELOWDOMAIN = 0x2 ; Do not include network folders below the domain level
Global Const $BIF_EDITBOX = 0x10 ; Include an edit control in the browse dialog box
Global Const $BIF_RETURNONLYFSDIRS = 0x1 ; Only return file system directories

Global Const $BIF_ALLOLDSTYLEFLAGS = BitOR ($BIF_BROWSEFORCOMPUTER, $BIF_BROWSEFORPRINTER, $BIF_BROWSEINCLUDEFILES, $BIF_DONTGOBELOWDOMAIN, $BIF_EDITBOX, $BIF_RETURNONLYFSDIRS)

; Simple GUI for sample
$hWndMain = GUICreate ("Test GUI", 200, 45, -1, -1)
$Button_1 = GUICtrlCreateButton ("Select folder",  55, 10)
GUISetState()
While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            ExitLoop
        Case $msg = $Button_1
            $res = _FileSelectFolderOldStyle ('Here the prompt', 0, $BIF_RETURNONLYFSDIRS, 'C:\_1', $hWndMain)
            MsgBox (0, "Your choise:", $res)
    EndSelect
Wend

; Initial folder procedure
Func _BrowseCallbackProc ($hWnd, $Msg, $wParam, $lParam)
    If $Msg = $BFFM_INITIALIZED Then
         $ret = DllCall ("user32.dll", "int", "SendMessage", _
            "hwnd",$hWnd, "int", $BFFM_SETSELECTION, "int", 1, "ptr", $lParam )
    EndIf
    Return 0
EndFunc ;==> _BrowseCallbackProc

Func _FileSelectFolderOldStyle ($text = '', $root = 0, $flags = 0, $iniDir = '', $hwnd = 0)
    Local $ret, $pidl, $res = ''
    ; Creating Structures
    Local $ubi = DllStructCreate ("hwnd;ptr;ptr;ptr;int;ptr;ptr;int") ; BROWSEINFO
    Local $utl = DllStructCreate ("char[512],char") ; Browse text
    Local $urs = DllStructCreate ("char[260]") ; MAX_PATH
    Local $ulf = BitAnd ($flags, $BIF_ALLOLDSTYLEFLAGS) ; Supported flags
    ; Filling structures
    DllStructSetData ($utl, 1, $text)
    DllStructSetData ($ubi, 1, $hwnd)
    DllStructSetData ($ubi, 3, DllStructGetPtr($urs))
    DllStructSetData ($ubi, 4, DllStructGetPtr($utl))
    DllStructSetData ($ubi, 5, $ulf)
    If ($iniDir <> '') And ($hwnd <> 0) Then
        Local $udr = DllStructCreate ("char[" & StringLen ($iniDir)+1 & "]")
        DllStructSetData ($udr, 1, $iniDir)
        Local $pBrowseCallbackProc = _DllCallBack("_BrowseCallbackProc","hwnd;uint;long;ptr") ; return function pointer
        DllStructSetData ($ubi, 6, $pBrowseCallbackProc)
        DllStructSetData ($ubi, 7, DllStructGetPtr($udr))
    EndIf
    $ret = DllCall ("shell32.dll", "ptr", "SHGetSpecialFolderLocation", _
        "int", 0 , "int", $root , "ptr", DllStructGetPtr($ubi, 2) )
    If $ret[0]=0 Then
        $pidl = DllCall ("shell32.dll", "ptr", "SHBrowseForFolder", "ptr", DllStructGetPtr ($ubi)) ; Start browse window
        If $pidl[0] Then
            $ret = DllCall ("shell32.dll", "int", "SHGetPathFromIDList", _
                "ptr", $pidl[0], "ptr", DllStructGetPtr ($urs))
            If $ret[0] Then $res = DllStructGetData ($urs, 1)
            DllCall ("ole32.dll", "int", "CoTaskMemFree", "ptr", $pidl[0]) ; clear memory
        EndIf
        DllCall ("ole32.dll", "int", "CoTaskMemFree", "ptr", DllStructGetData ($ubi, 2))
    EndIf
    _DllCallBack_Free ($pBrowseCallbackProc) ; clear memory
    Return $res
EndFunc ;==> _FileSelectFolderOldStyle

P.S. линк на DllCallBack.au3 от piccaso: http://www.autoitscript.com/forum/in...=post&id=15441

[Creat0R]

amel27

хотя он и позволяет использовать все возможности диалоговых окон (в т.ч. Explorer style)

Отлично... спасибо за то что узнал у picaso.
Правда теперь выбрать другой каталог практический невозможно

[amel27]

Правда теперь выбрать другой каталог практический невозможно

действительно... исправил

[Creat0R]

amel27

исправил

Спасибо.

Я так понял теперь можно и стильный диалог отображать? какой флаг для этого используется? (перепробовал все стандартные, не один не подошел).

Diamond

теперь этот способ можно смело использовать

Не совсем ...
Сегодня у меня были траблы с инетом, интернет судя по настройкам (Папка “Сетевые подключения”) был подключен, однако не одно приложение не могло получить доступ в сеть - твоя функция вернула True, подключение есть, однако используя пример от amel27, я получил совсем другой результат (соеденение отсутствует), и при этом ещё получил описание ошибки в (не)доступе к сети .

Так что через объект winhttp.winhttprequest.5.1 намного надёжнее и функциональнее.... хотя у меня такое подозрение, что если с Internet Explorer в системе есть проблемы, то и эта функция провалится

[amel27]

Я так понял теперь можно и стильный диалог отображать? какой флаг для этого используется? (перепробовал все стандартные, не один не подошел).

да не, вроде пашет... правда там отличие только в ресайзе:

Код:

Global Const $BIF_NEWDIALOGSTYLE = 0x40 ; Use the new user interface
;...
Global Const $BIF_ALLOLDSTYLEFLAGS = BitOR ($BIF_BROWSEFORCOMPUTER, $BIF_BROWSEFORPRINTER, $BIF_BROWSEINCLUDEFILES, $BIF_DONTGOBELOWDOMAIN, $BIF_EDITBOX, $BIF_RETURNONLYFSDIRS, $BIF_NEWDIALOGSTYLE)

[Diamond]

Creat0R
Я не знаю, может тебе уже попадалась функция от Gafrost, но там с ней тоже какие-то проблемы. Лично у меня, она вернула "пусто" когда я был в offline.

[Creat0R]

amel27

Работает!!!
Спасибо ещё раз.

Правда теперь стиль $BIF_RETURNONLYFSDIRS не действует если использовать стиль нового диалога - т.е при выборе папки компьютера к примеру, кнопка ОК не становится не активной... но это не страшно.... а, и ещё - в функции небольшая т.н программная опечатка - Переменная $pBrowseCallbackProc не обьявляется в начале скрипта, а только в условии, что естественно в свою очередь вызывает ошибку (она используеться позже в функции вне условия).

Кстати, а это нормально что при выборе системной папки (к примеру Мой компьютер), возвращается пустое значение? в оригинальной функции возвращается имя выбранного элемента (“Мой компьютер”).

там отличие только в ресайзе

Что-то не заметил отличие .... а можно использовать новый вид диалога, но без кнопки “Создать папку”?

[amel27]

Creat0R

теперь стиль $BIF_RETURNONLYFSDIRS не действует если использовать стиль нового диалога

да, есть такой косяк... надо программировать средствами CallBack-функции, там есть такая возможность

Переменная $pBrowseCallbackProc не обьявляется в начале скрипта

спасибо, исправил... там еще была неточность с закрытием хэндла при выходе

в оригинальной функции возвращается имя выбранного элемента (“Мой компьютер”).

да, API-функция возвращает "пусто"... имхо это решаемо

а можно использовать новый вид диалога, но без кнопки “Создать папку”?

используй флаг $BIF_NONEWFOLDERBUTTON = 0x200

[DenchikK]

Чудовищно туплю!
Надо сделать так, чтоб по нажатию клавиши, в поле вписывалась бы первая строчка текстового файла, повторное нажатие - 2 строчка, и.т.п. Вроде сделал как в хелпе описано и как мне показали ранее:

Код:

     Case $Proxy

          For $i = 1 To UBound($Proxy_Array)-1
          ControlSetText ( 'Programs', '', 'Edit4', $proxy_Array[$i])
          Next

Но получается - что все считанные данные промелькивают в поле заполнения!

Туплю по страшному, не знаю как исправить...

[Maza Faka]

Как отключить монитор используя WinApi?