[storm2005]

Интересует взлом скомпилированного AutoIt .exe. Можно или нет это сделать, если при компиляции был выставлен пароль или убрана галка позволяющая декомпилировать?

[Creat0R]

storm2005

Можно или нет это сделать, если при компиляции был выставлен пароль или убрана галка позволяющая декомпилировать?

Если был выставлен пароль, то естественно при его наличии это возможно, а вот если была убрана галка позволяющая декомпилировать, то нет.

[storm2005]

Если был выставлен пароль, то естественно при его наличии это возможно, а вот если была убрана галка позволяющая декомпилировать, то нет.

если есть пароль но он неизвестен. можно ли декомпилировать?

интересует этот вопрос т. к. хочу устанавливать некоторый софт через логонный скрипт юзера. но проблема в том, что под юзером большинство софта не ставится т. к. юзер не обладает административными правами. в AutoIt нашел замечательную функцию RunAsSet в которой можно передать пароль в отличие от команды runas. но хотелось быть уверенным, что скомпилировав скрипт под паролем его никто не декомпилирует.

[amel27]

storm2005

если есть пароль но он неизвестен. можно ли декомпилировать?

Можно, причем это ответ не мой, а разработчиков... Говорят есть хакнутый aut2exe, декомпилирующий такие скрипты, хотя сам я его не видел... впрочем и не искал.

проблема в том, что под юзером большинство софта не ставится т. к. юзер не обладает административными правами

такие задачи обычно решаются клиент-серверным методом, когда один модуль работает с правами системы/админа и заточен на выполнение конкретных задач (например, установки софта), а второй - под обычным юзером и дает ему "команды"... Для этого можно использовать технологии COM, WMI или обычный скрипт, запущенный в качестве службы.

[NikLok]

storm2005

но хотелось быть уверенным, что скомпилировав скрипт под паролем его никто не декомпилирует.

Очень хочется примеры таких скриптов узнать! В смысле какую такую инфу ты защищаешь от пользователя.?!
ALL
Последнее время при адаптации скриптов под новые версии программ наталкиваюсь на странное поведение AutoIT.

А именно при выполнении команды ControlClick как бы не происходит отработки нажатия кнопки.
Например это началось в Wintools Net Pro начиная с версии после 8.1.1
Есть такой же проблемный кусок и в установке OutPost (вернее он всегда там был)

Код:

	WinWaitActive("Configuration Wizard","")
	$text = WinGetText("Configuration Wizard","")
	If StringRegExp($text,"Some applications that can cause system stability issues") Then
		If Not WinActive("Configuration Wizard","Some applications that can cause system stability issues") Then WinActivate("Configuration Wizard","Some applications that can cause system stability issues")
		WinWaitActive("Configuration Wizard","Some applications that can cause system stability issues")
		Send("{TAB}{ENTER}")
	EndIF

	If StringRegExp($text,"Advanced security") Then
		If Not WinActive("Configuration Wizard","Advanced security") Then WinActivate("Configuration Wizard","Advanced security")
		WinWaitActive("Configuration Wizard","Advanced security")
		Sleep(30)
		ControlClick("Configuration Wizard","Advanced security","Button3")
		Sleep(30)
		Send("{ENTER}")
	EndIF

Не получается выбрать "Advanced security" и пройти далее.

Может кто-то уже решал такую проблему?!
Может как-то можно задавать длительность нажатия кнопки?!

[Angel_19]

В обсуждаемом продукте вроде есть запись макросов - как это можно осуществить и можно ли?

[VelDmi]

Имеется каталог CutDir. в нем куча файлов. Есть файл (file.txt) содержащий строки вида:
C:\Compare\CutDir\Bin\SD0405.dll
C:\Compare\CutDir\Bin\LOA\SD0434.dll
C:\Compare\CutDir\WEZ\BIGz\erwg.dll

Как правильнее удалить из каталога все файлы, не содержащиеся в списках?
Пробовал

$line = FileReadLine($file)
FileMove ($CutDir & $line2, $DestDir & $line2, 0)
Работает, только для файлов в корне каталога CutDir, т.е. он не создает автоматически вложенные каталоги при копировании. А мне нужно оставить только файлы, перечисленные в списке, причем и во всех вложенных каталогах тоже.

[Creat0R]

VelDmi
amel27 как то написал функцию возвращающую массив дерева каталогов включая подкаталоги, с её помощью эту задачу реализовать довольно просто:

Код:

#include <Array.au3>
#include <File.au3>

;Создаём нужные переменные и массив для содержания списка файлов которые удалять не нужно
$Dir = "CutDir"
$ExcludeListFile = "file.txt"
Dim $ExcludeListArr[1]

;Получаем массив структуры каталогов в папке "CutDir" (из переменной $Dir)
$DirsArray =  _DirListToArray($Dir)

;Получаем массив со списком файлов которые не нужно удалять (из файл от переменной $ExcludeListFile)..
_FileReadToArray($ExcludeListFile, $ExcludeListArr)

;Проходим по массиву структуры каталогов, получаем массив со списком файлов в каждом каталоге, и удаляем файлы не находящиеся в списке.
For $i = 1 To UBound($DirsArray)-1
    ;Получаем массив со списком файлов текущего каталога...
    $InDirFilesArr = _FileListToArray($DirsArray[$i], "*.*", 1)

        ;Если в текущем каталоге найдены файлы, то проходимся по массиву и ищем текущий элемент в массиве списка исключенных файлов.
    If IsArray($InDirFilesArr) Then
        For $iF = 1 To UBound($InDirFilesArr)-1
            ;Поиск элемента (текущего файла включая полный путь)...
            $SearchInArr = _ArraySearch($ExcludeListArr, $DirsArray[$i] & "\" & $InDirFilesArr[$iF])
            ;Если не найден, то удаляем файл...
            If $SearchInArr = -1 Then FileDelete($DirsArray[$i] & "\" & $InDirFilesArr[$iF])
        Next
    EndIf
Next

;Функция возвращает массив структуры подкаталогов
Func _DirListToArray ($sPath)
    Local $i, $j, $rlist[1]=[0], $blist, $alist=_FileListToArray ($sPath, '*', 2)
    If IsArray ($alist) Then
        For $i=1 To $alist [0]
            _ArrayAdd ($rlist, $sPath & "\" & $alist [$i])
            $blist = _DirListToArray ($sPath & "\" & $alist [$i])
            If $blist[0]>0 Then
                For $j=1 To $blist [0]
                    _ArrayAdd ($rlist, $blist [$j])
                Next
            EndIf
        Next
    EndIf
    $rlist [0] = UBound ($rlist) - 1
    Return $rlist
EndFunc

P.S
Я не тестировал скрипт, написал на скорую руку.

[VelDmi]

Creat0R
Уфф, мне не дано такое понять...
Написал сам через попу, но работает вроде:

Код:

RunWait (@COMSPEC & ' /c fsum.exe -r -d".\CutDir" *.* > sums.md5', @ScriptDir, @SW_HIDE)
;через эту прогу создается список файлов
$filesums = FileOpen(@ScriptDir& '\sums.md5', 0)
If $filesums = -1 Then
     MsgBox(0, "Ошибка.", "Не могу открыть файл sums.md5")
     Exit
 EndIf
$filesums2 = FileOpen(@ScriptDir& '\sums2.md5', 0)
If $filesums2 = -1 Then
     MsgBox(0, "Ошибка.", "Не могу открыть файл sums2.md5")
     Exit
 EndIf

While 1
	$i = FileReadLine($filesums2)
	If @error = -1 Then ExitLoop
	$Count2 = $Count2 + 1
WEnd
FileClose($filesums2)

While 1
     $line = FileReadLine($filesums)
	 If @error = -1 Then ExitLoop
     If StringLeft ($line, 1) = ';' Then ContinueLoop
		 $filesums2 = FileOpen(@ScriptDir& '\sums2.md5', 0)
		 $Del = 1
		For $i = 1 To $Count2
			If $line = FileReadLine($filesums2) Then 
				$Del = 0
				ExitLoop
			EndIf
		Next
		If $Del = 1 Then FileDelete ($CutDir & StringTrimLeft( $line, 34 ))
		FileClose($filesums2)
WEnd
FileClose($filesums)

теперь попробую твой способ.

[Creat0R]

VelDmi

Уфф, мне не дано такое понять...

Время покажет, я так тоже раньше думал, если бы мне, где то пол года назад показали подобный код, я бы точно также отреагировал

Вот превратил всё это дело в функцию, теперь проверил работоспособность, вроде работает

Переменная $ExcludeList также может иметь сразу список файлов для исключения, вот пример - $ExcludeList = "C:\CutDir\test.txt|C:\CutDir\test2.txt" - файлы C:\CutDir\test.txt и C:\CutDir\test2.txt не будут тронуты функцией. Также можно передать во второй параметр функции _DeleteFilesWithExcludes() массив содержащий список файлов для исключения, ну и как показанно в примере, поддерживается и обычный путь к файлу, с которого будет браться список исключении.

При успешной операции, возвращает @extended, макрос будет содержать число файлов которые были удалены (именно удалены, не просто количество файлов в соответствии со списком исключении).

Код:

#include <Array.au3>
#include <File.au3>

$Dir = @ScriptDir & "\CutDir"

;Эта переменная может быть массивом, полным списком файлов исключении (разделённый через |),
;а так-же это можт быть путь к файлу содержащий список файлов которые будут исключены при удалении.
$ExcludeList = @ScriptDir & "\file.txt" ;Пример переменной - "c:\CutDir\test.txt|c:\CutDir\test2.txt" ... и т.д

_DeleteFilesWithExcludes($Dir, $ExcludeList)

If Not @error Then MsgBox(262144+64, "Finish", "Было удалено <" & @extended & "> файлов")

;Функция для удаления файлов из всех подкаталогов заданного каталога, в соответствии со списком исключении.
Func _DeleteFilesWithExcludes($sPath, $ExcludeList)
    Local $ExcludeListArr[1], $Extended = 0
    ;Если не существует каталога (в котором следует производить удаление) или переменная $sPath не является каталогом,
    ;возвращаем ошибку №1.
    If Not StringInStr(FileGetAttrib($sPath), "D") Then Return SetError(1, 0, 0)
    ;Получаем массив структуры каталогов в папке "CutDir" (из переменной $Dir)
    Local $DirsArray =  _DirListToArray($sPath)

        If Not IsArray($ExcludeList) And FileExists($ExcludeList) Then
        ;Получаем массив со списком файлов которые не нужно удалять (из файл от переменной $ExcludeList)..
        _FileReadToArray($ExcludeList, $ExcludeListArr)
    ElseIf IsString($ExcludeList) And StringInStr($ExcludeList, "|") Then
        ;Превращаем переменную в массив (разделяя этим символом |)
        $ExcludeListArr = StringSplit($ExcludeList, "|")
    ElseIf IsArray($ExcludeList) Then
        ;Присваиваем внутреннему массиву (ранее созданному) то же значение что и у массива $ExcludeList
        $ExcludeListArr = $ExcludeList
    Else
        ;Не предвиденная ошибка, передана пустая переменная или неверный формат массива/переменной - возвращаем ошибку №2.
        Return SetError(2, 0, 0)
    EndIf

        ;Получаем массив со списком файлов корневого каталога ($sPath)...
    $RootFilesArr = _FileListToArray($sPath, "*.*", 1)
    If IsArray($RootFilesArr) Then
        For $iR = 1 To UBound($RootFilesArr)-1
            ;Поиск элемента (текущего файла включая полный путь)...
            $SearchInArr = _ArraySearch($ExcludeListArr, $sPath & "\" & $RootFilesArr[$iR])
            ;Если не найден, то удаляем файл...
            If $SearchInArr = -1 Then $Extended += FileDelete($sPath & "\" & $RootFilesArr[$iR])
        Next
    EndIf

        ;Проходим по массиву структуры каталогов, получаем массив со списком файлов в каждом каталоге,
    ;и удаляем файлы не находящиеся в списке.
    For $i = 1 To UBound($DirsArray)-1
        ;Получаем массив со списком файлов текущего каталога...
        $InDirFilesArr = _FileListToArray($DirsArray[$i], "*.*", 1)

                ;Если в текущем каталоге найдены файлы, то проходимся по массиву и ищем текущий элемент в массиве списка исключенных файлов.
        If IsArray($InDirFilesArr) Then
            For $iF = 1 To UBound($InDirFilesArr)-1
                ;Поиск элемента (текущего файла включая полный путь)...
                $SearchInArr = _ArraySearch($ExcludeListArr, $DirsArray[$i] & "\" & $InDirFilesArr[$iF])
                ;Если не найден, то удаляем файл...
                If $SearchInArr = -1 Then $Extended += FileDelete($DirsArray[$i] & "\" & $InDirFilesArr[$iF])
            Next
        EndIf
    Next
    Return SetError(0, $Extended, 1)
EndFunc

;Функция возвращает массив структуры подкаталогов
Func _DirListToArray ($sPath)
    Local $i, $j, $rlist[1]=[0], $blist, $alist=_FileListToArray ($sPath, '*', 2)
    If IsArray ($alist) Then
        For $i=1 To $alist [0]
            _ArrayAdd ($rlist, $sPath & "\" & $alist [$i])
            $blist = _DirListToArray ($sPath & "\" & $alist [$i])
            If $blist[0]>0 Then
                For $j=1 To $blist [0]
                    _ArrayAdd ($rlist, $blist [$j])
                Next
            EndIf
        Next
    EndIf
    $rlist [0] = UBound ($rlist) - 1
    Return $rlist
EndFunc