[Creat0R]

mrak1990

Просто уменя не пашет через реестр одна из опций: Скрывать защищённые системные файлы.

Всё очень просто:

Код:

RegWrite("HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced", "ShowSuperHidden", "REG_DWORD", 1) ;если 0, тогда файлы будут показываться.

Если нужно обновить программно все папки и даже рабочий стол, см. мою утилитку для отката расширении файлов и скрытых папок тут (исходники естественно в архиве прилагаются ).

раскопал справочник по WinAPI

На русском? можно ссылку на источник?

[qeraser]

Задача - запуск и работа 1с с конкретной конфигурацией с флэш-диска на любом компьютере.
Платформа + база находятся на флэш.
Т.е подключив флэшку и запустив 1с с нее же, загружалась нужная конфигурация.
Чтобы 1с видел базы пути к ним должны быть прописаны пути в реестре.

Я могу написать bat, au3 файл который вносил бы соотв. записи в реестр, но в путях к базам нужно указать букву диска. Проблема в том, что компьютеры разные, соответственно флэш-диск будет иметь разные буквы в системе.

Как можно поэлегантнее реализовать?

[amel27]

qeraser

для BAT подстановка %~d0 возвращает букву диска, откуда запущен скрипт
для AU3 выражение StringLeft (@ScriptDir, 2) работает аналогично

[qeraser]

amel27
Спасибо, разобрался

[TERMINAL]

Как определить - есть ли на диске свободных 1 гиг, если есть то вывести сообщений №1, если нет-вывести сообщение №2?!

amel27
А возможно чтобы обновления записывальсь в текстовый файл?
где изменения сделать?

[mrak1990]

На русском? можно ссылку на источник?

Без проблем:

http://foxpopuli.narod.ru/books/api_help.zip

[mrak1990]

Creat0R

Код:

Func UpdateExplorer()
	Local $WinExpListArr = _ExplWinGetList()
	Local $OldOpt = Opt("WinTitleMatchMode", 4)
	Local $GetWinState, $Hwnd
	If IsArray($WinExpListArr) Then
		For $iWin = 1 To $WinExpListArr[0]
			$GetWinState = WinGetState($WinExpListArr[$iWin])
			$Hwnd = WinGetHandle($WinExpListArr[$iWin])
			DllCall("user32.dll", "long", "SendMessage", "hwnd", $hWnd, "int", 0x111, "int", 28931, "int", 0)
		Next
	EndIf
	
	$Hwnd = WinGetHandle("classname=Progman")
	DllCall("user32.dll", "long", "SendMessage", "hwnd", $hWnd, "int", 0x111, "int", 28931, "int", 0)
	Opt("WinTitleMatchMode", $OldOpt)
EndFunc

Func _ExplWinGetList()
	Local $OldOpt = Opt("WinTitleMatchMode", 4)
	Local $WinList = WinList("classname=CabinetWClass")
	Opt("WinTitleMatchMode", $OldOpt)
	If IsArray($WinList) Then
		Local $WinListArr[$WinList[0][0]+1]
		For $iW = 1 To $WinList[0][0]
			$WinListArr[$iW] = $WinList[$iW][0]
		Next
		$WinListArr[0] = $WinList[0][0]
		Return $WinListArr
	Else
		Return ""
	EndIf
EndFunc

У меня вопрос вот по этому коду. Можешь просто описать в общих чертах, как он работает?

[Creat0R]

TERMINAL

Как определить - есть ли на диске свободных 1 гиг, если есть то вывести сообщений №1, если нет-вывести сообщение №2?!

Код:

$CD = "C:\"
$FreeSpace = DriveSpaceFree($CD)
If $FreeSpace >= 1024 Then
    MsgBox(64, "", "Ok, есть на диске <" & $CD & "> " & $FreeSpace & " мб свободного места.")
Else
   MsgBox(48, "", "На диске <" & $CD & "> не хватает свободного места (" & $FreeSpace & " мб).")
EndIf

mrak1990

Без проблем:

Спасибо!

Можешь просто описать в общих чертах, как он работает?

Конечно...

Первая функция ( UpdateExplorer() ), в начале использует вторую ( _ExplWinGetList() ), чтобы получить список заголовок всех окон которые являются папками (мы же не хотим обновлять к примеру Internet Explorer ).
Затем для каждого найденого окна (из полученного списка в массиве), происходит обновление (это делает вызов Dll), всё это в принципе для одной цели - обновить программно все открытые эксплореровские окна (в том числе и рабочий стол), не активируя их и не используя никаких посылании клавишь типа F5 , а просто прямой вызов функции (для конкретного окна) обновления окна (та же функция которая выполняется Windows после нажатия F5).

[mrak1990]

Creat0R
Остался один вопрос. Для чего ты вызываешь два раза функцию DllCall? Один раз для папок, а другой для рабочего стола?

[Creat0R]

mrak1990

Для чего ты вызываешь два раза функцию DllCall? Один раз для папок, а другой для рабочего стола?

Да, для рабочего стола класс заголовка окнка немного другой, поэтому получить его из списка одновременно не получается... хотя можно было конечно во второй функции добавить последний элемент в массив который содержал бы заголовок окна для рабочего стола, но так тоже нормально работает

И ещё, $GetWinState = WinGetState($WinExpListArr[$iWin]) там уже лишнее, это раньше у меня не получалось напрямую обновлять окна, поэтому приходилось активировать их, посылать им обновление, и затем возвращать окно в исходное положение (свёрнутое/развёрнутое, активное/не активное).

Вот обновил функции, теперь список всех окон возвращается средствами функции _ExplWinGetList(), а также убрал лишние строчки:

Код:

Func UpdateExplorer()
    Local $OldOpt = Opt("WinTitleMatchMode", 4)
    Local $WinExpListArr = _ExplWinGetList()
    Local $Hwnd
    If IsArray($WinExpListArr) Then
        For $iWin = 1 To $WinExpListArr[0]
            $Hwnd = WinGetHandle($WinExpListArr[$iWin])
            DllCall("user32.dll", "long", "SendMessage", "hwnd", $hWnd, "int", 0x111, "int", 28931, "int", 0)
        Next
    EndIf
    Opt("WinTitleMatchMode", $OldOpt)
EndFunc

Func _ExplWinGetList()
    Local $WinList = WinList("classname=CabinetWClass")
    If IsArray($WinList) Then
        Local $WinListArr[$WinList[0][0]+2]
        For $iW = 1 To $WinList[0][0]
            $WinListArr[$iW] = $WinList[$iW][0]
        Next
        $WinListArr[0] = $WinList[0][0]+1
        $WinListArr[$WinListArr[0]] = "classname=Progman"
        Return $WinListArr
    Else
        Return ""
    EndIf
EndFunc