[13ghost]

Объясните пожалуйста,а то я не догоняю,не могу понять что в справке написано:
что делает ConsoleWrite? и для чего её можно применить?
зарание благодарен

[amel27]

13ghost
Штатное применение - отладка скриптов средствами SciTE, кстати неплохая альтернатива MsgBox() . Выводит заданный тект (например, значения переменных) в экран вывода - тот, что включается по F8. Из нештатных - запись данных в STDOUT при запуске скрипта через CMD.

Creat0R

Local там лишних два раза встречается

гы-гы, а я исправил раньше твоего замечания

Поздравляю со статусом Ветерана!

упс, а кем я был?

[Vadikan]

упс, а кем я был

Ты можешь быть кем хочешь, изменяя статус в профиле, - это привелегия участников, входящих в группу Contributors.

[Creat0R]

amel27

а я исправил раньше твоего замечания

Ивени, не заметил...

а кем я был?

Старожил'ом кажется

[belonesox]

Вопрос про чтение stdout'а AutoItом - наблюдаю эффект, что для некоторых программ, stdout то читается, то не читается (в зависимости от опций).
Например, рассмотрим следующий код:

Код:

Func ShowStdout($cmd)
	$stdout=""
	$foo = Run($cmd, @SystemDir, @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)
	While 1
		$line = StdoutRead($foo)
		If @error Then ExitLoop
		$stdout=$stdout & $line
	Wend
	MsgBox(0,$cmd,$stdout)
EndFunc

$cmd=@ComSpec & " /c " & " java  "
ShowStdout($cmd) ; Показывает STDOUT нормально
$cmd=@ComSpec & " /c " & " java -version "
ShowStdout($cmd) ; Показывает пустой STDOUT 
$cmd=@ComSpec & " /c " & " python -h "
ShowStdout($cmd) ; Показывает STDOUT нормально
$cmd=@ComSpec & " /c " & " python -V "
ShowStdout($cmd) ; Показывает пустой STDOUT 
Exit(0)

Если ли у кого-то идеи, с чем это может быть связано или обусловлено?

C уважением, Стас.

[Evgeniy15]

Иногда название окна не меняется. Получается, что посылая следующий {ENTER} нажимаешь на {Cancel}. Команда sleep не очень эффективна, т.к. она нормально отрабатывается на одном компе, на другом с заметной задержкой а на третьем задержки не хватает. Как быть в таком случае?

[Creat0R]

belonesox

с чем это может быть связано или обусловлено?

Если возращается пустое значение, значит произошла ошибка при первой попытке чтения, вот эту ошибку (а точнее пустое значение) можно и улавливать:

Код:

Func ShowStdout($cmd)
    $stdout=""
    $foo = Run($cmd, @SystemDir, @SW_HIDE, $STDERR_CHILD+$STDOUT_CHILD)
    While 1
        $line = StdoutRead($foo)
        If @error Then ExitLoop
        $stdout &= $line
    Wend
    If $stdout = "" Then $stdout = StderrRead($foo)
    MsgBox(0, $cmd, $stdout)
EndFunc

Evgeniy15

Как быть в таком случае?

В каком случае? я, как и многие другие, увы, гадать не умею

[amel27]

belonesox
попробуй следующий вариант (проверил только для java, python под рукой нет):

Код:

#include <Constants.au3>

$cmd=@ComSpec & " /c " & " java  2>&1"
ShowStdout($cmd) ; Показывает STDOUT нормально
$cmd=@ComSpec & " /c " & ' java -version 2>&1'
ShowStdout($cmd) ; Показывает пустой STDOUT
 $cmd=@ComSpec & " /c " & " python -h  2>&1"
ShowStdout($cmd) ; Показывает STDOUT нормально
$cmd=@ComSpec & " /c " & " python -V  2>&1"
ShowStdout($cmd) ; Показывает пустой STDOUT

 Func ShowStdout($cmd)
    Local $stdout
    $foo = Run ($cmd, @SystemDir, @SW_HIDE, $STDERR_CHILD + $STDERR_CHILD + $STDOUT_CHILD)
    While 1
        $line = StdoutRead($foo)
        If @error Then ExitLoop
        $stdout=$stdout & $line
    Wend
    MsgBox(0,$cmd,$stdout)
EndFunc

ALL
просьба не забывать добавлять в скрипты необходимые строчки #include !

[Creat0R]

Как можно получить загрузку ЦП определённого процесса? не важно, по имени образа, пути к файлу процесса, или по Pid. Это возможно узнать? (AutoIt'ом естественно ).

[amel27]

Creat0R
что-то типа такого:

Код:

MsgBox (0, '', _GetCPUUsageProcess ('winrar'))

Func _GetCPUUsageProcess ($proc, $ticks = 1000)
    Local $aCount[3], $strProc = 'Name="' & $proc & '"'
    Local $colItems, $objItem, $objWMIService = ObjGet("winmgmts:\\.\root\CIMV2")
    If IsNumber ($proc) And $proc>0 Then $strProc = "IDProcess=" & $proc
    ; Считываем необходимые характеристики процесса - попытка №1
    $colItems = $objWMIService.ExecQuery ("SELECT IDProcess,PercentProcessorTime,Timestamp_Sys100NS FROM Win32_PerfRawData_PerfProc_Process WHERE " & $strProc, "WQL", 0x30)
    For $objItem In $colItems
        $aCount[0]=$objItem.IDProcess
        $aCount[1]=$objItem.PercentProcessorTime
        $aCount[2]=$objItem.Timestamp_Sys100NS
        ExitLoop
    Next
    If $aCount[0] Then
        ; Накапливаем статистику...
        Sleep ($ticks)
        ; Считываем необходимые характеристики процесса - попытка №2
        $colItems = $objWMIService.ExecQuery ("SELECT PercentProcessorTime,Timestamp_Sys100NS FROM Win32_PerfRawData_PerfProc_Process WHERE IDProcess=" & $aCount[0], "WQL", 0x30)
        For $objItem In $colItems
            Return Round (100*($objItem.PercentProcessorTime - $aCount[1])/($objItem.Timestamp_Sys100NS - $aCount[2]))
        Next
    EndIf
    Return ""
EndFunc