[13ghost]

Здравия желаю!
Простите если повторюсь,просто не нашёл(а может плохо искал).
Есть скрипт ,который архивирует,а потом с помощью встроенного в винду ftp клиента отсылает архив восвояси.так вот хотелось бы перехватывать сообщения ftp и писать их в лог ,что бы занать что и когда
как это можно сделать?

[Creat0R]

amel27

Если заметил, то перед чтением выходного потока StdoutRead($Pid) я добавил проверку на наличие данных в потоке StdoutRead ($foo,0,True) - это позволяет избежать подвисания окна AutoIT на время отсутствия выходных данных (об этом кстати сказано в справке к StdoutRead())...

Интересно, я если честно не обратил внимания, спасибо, пойду поправлю свой пример

так пробовал?

Нет, но мне уже на офф. форуме подсказали, нужно точно также но чтобы $hwnd = 0 был как первый параметр, иначе не работает (не знаю даже почему, вроде никак не должо влиять) - но всё же биг сенкс!

13ghost

перехватывать сообщения ftp и писать их в лог

Если это консольная утилита, то попробуй применить методы из примера для архивирования тут.

[13ghost]

Creat0R
завтра попробую

[Creat0R]

amel27

так вот второй параметр (после имени инициатора) отвечает за тип подключения

Где именно мне в функции поравить 0 на 1 (это я ещё по поводу _InetGetSource() )?

Вот исходник функции:
(если не трудно, укажи где именно нужно менять)

Код:

Func _INetGetSource($s_URL, $s_Header = '')
	
	If StringLeft($s_URL, 7) <> 'http://' And StringLeft($s_URL, 8) <> 'https://' Then $s_URL = 'http://' & $s_URL
	
	Local $h_DLL = DllOpen("wininet.dll")
	
	Local $ai_IRF, $s_Buf = ''
	
	Local $ai_IO = DllCall($h_DLL, 'int', 'InternetOpen', 'str', "AutoIt v3", 'int', 0, 'int', 0, 'int', 0, 'int', 0)
	If @error Or $ai_IO[0] = 0 Then
		DllClose($h_DLL)
		SetError(1)
		Return ""
	EndIf
	
	Local $ai_IOU = DllCall($h_DLL, 'int', 'InternetOpenUrl', 'int', $ai_IO[0], 'str', $s_URL, 'str', $s_Header, 'int', StringLen($s_Header), 'int', 0x80000000, 'int', 0)
	If @error Or $ai_IOU[0] = 0 Then
		DllCall($h_DLL, 'int', 'InternetCloseHandle', 'int', $ai_IO[0])
		DllClose($h_DLL)
		SetError(1)
		Return ""
	EndIf
	
	Local $v_Struct = DllStructCreate('udword')
	DllStructSetData($v_Struct, 1, 1)
	
	While DllStructGetData($v_Struct, 1) <> 0
		$ai_IRF = DllCall($h_DLL, 'int', 'InternetReadFile', 'int', $ai_IOU[0], 'str', '', 'int', 256, 'ptr', DllStructGetPtr($v_Struct))        
		$s_Buf &= StringLeft($ai_IRF[2], DllStructGetData($v_Struct, 1))
	WEnd
	
	DllCall($h_DLL, 'int', 'InternetCloseHandle', 'int', $ai_IOU[0])
	DllCall($h_DLL, 'int', 'InternetCloseHandle', 'int', $ai_IO[0])
	DllClose($h_DLL)
	Return $s_Buf
EndFunc

[amel27]

Creat0R

Код:

Local $ai_IO = DllCall($h_DLL, 'int', 'InternetOpen', 'str', "AutoIt v3", 'int', 1, 'int', 0, 'int', 0, 'int', 0)

[Creat0R]

amel27
Спасибо!

---

Такой вопрос по регулярным вырожениям - Как возможно получить определённый текст, который находится между двумя заранее известными символами?

Т.е к примеру, имеем такой текст:

Код:

test1*этот текст нам нужен*test2

Заранее известны только разделители *, и нужно бы получить всё что между ними... я конечно могу использовать разного рода ухитрения со StringSplit, StringInStr, StringLeft...Right и т.д, но мне хотелось бы узнать как это можно достичь регулярными выражениями, и тем более, что подобные методы будут не очень надёжны.

[amel27]

Creat0R
что-то подобное я делал в скрипте "расцветки":

Код:

$str='test1*этот текст нам нужен*test2'
$chr='\*'
MsgBox (0,'Результат',StringRegExpReplace ($str,'^.*' & $chr & '(.*)' & $chr & '.*$','\1'))

PS: естественно, разделителей должно быть два

[Creat0R]

amel27
Я имел ввиду получить текст между двумя символами, но они могут быть разные, к примеру если этот метод использовать так (как функию):

Код:

$String = '1теперь нам нужен этот текст2'

MsgBox(0, "", _StringInside($String, "1", "2"))

Func _StringInside($String, $Start, $End)
	Return StringRegExpReplace($String, '^.*\' & $Start & '(.*)\' & $End & '.*$', '\1')
EndFunc

То результат будет не верный, нужно как то получать текст между двумя заданными символами, и неважно какие символы, или где они стоят, если между ними ничего нет, то можно возвращать весь $String...

Добавлено:
Во! сделал, правда я не уверен что учёл все символы...

Код:

$String = '_теперь нам нужен этот текст^'

MsgBox(0, "", _StringInside($String, "_", "^"))

Func _StringInside($String, $Start, $End)
    If StringRegExp($Start, "[\+\|\*\^\$\.\[\]\(\)\?\\]") Then $Start = "\" & $Start
    If StringRegExp($End, "[\+\|\*\^\$\.\[\]\(\)\?\\]") Then $End = "\" & $End
    Local $Ret = StringRegExpReplace($String, '^.*' & $Start & '(.*)' & $End & '.*$', '\1')
    If $Ret = "" Then Return $String
    Return $Ret
EndFunc

Спасибо!

Хм, но теперь другая проблема - если более чем два совпадения символов, то возвращается последнее межсимвольное значение, а нужно чтобы в таком случае возвращалось первое совпадение (с левой стороны, т.е сначала).

[amel27]

Creat0R
ну... вот еще вариант, выбирающий фрагмент от первого вхождения 1-го символа до первого вхождения 2-го:

Код:

$String = '_теперь нам нужен этот текст^'

MsgBox(0, "", _StringInside($String, "_", "^"))

Func _StringInside($String, $Start, $End)
    $Start = StringRegExpReplace ($Start, '([\+\|\*\^\$\.\[\]\(\)\?\\])', '\\\1')
    $End = StringRegExpReplace ($End, '([\+\|\*\^\$\.\[\]\(\)\?\\])', '\\\1')
    Local $pattern = '^[^' & $Start & ']*' & $Start & '([^' & $End & ']*)' & $End & '.*$'
    Return StringRegExpReplace($String, $pattern, '\1')
EndFunc

[Creat0R]

amel27

вот еще вариант

Во! это то что нужно (правда Local там лишних два раза встречается ), спасибо большое (см. ниже полный пример для подобной функции, я её уже переименовал )...

Поздравляю со статусом Ветерана!

Код:

$String = 'Это нам не нужно. Нам нужен этот текст, :и этот тоже:, а :этот нам не нужен:'

MsgBox(0, "", _StringMidle($String, ".", ","))

MsgBox(0, "", _StringMidle($String, ":", ":"))

Func _StringMidle($String, $Start, $End)
    $Start = StringRegExpReplace ($Start, '([\+\|\*\^\$\.\[\]\(\)\?\\])', '\\\1')
    $End = StringRegExpReplace ($End, '([\+\|\*\^\$\.\[\]\(\)\?\\])', '\\\1')
    Local $pattern = '^[^' & $Start & ']*' & $Start & '([^' & $End & ']*)' & $End & '.*$'
    Return StringRegExpReplace($String, $pattern, '\1')
EndFunc