[DJ Mogarych]

Как через bat включить защиту системы, если она выключена? »

Код:

powershell -c "Enable-ComputerRestore -Drive C:"

И как установить лимит размера точек восстановления в 3%? »

Код:

vssadmin resize shadowstorage /for=C: /on=C: /maxsize=3%

[biffick]

DJ Mogarych, привет. А без повэршэлла не получится и vssadmin? Допустим, через wmic. Чтобы на вин7 не было проблем.

Я нашёл такое, но не тестировал ещё:

Код:

Включение защиты
wmic.exe /namespace:\\root\default Path SystemRestore Call enable "C:\"
(Полагаю сработает вместо C:\ - %systemdrive%)

[DJ Mogarych]

А без повэршэлла не получится и vssadmin? »

Зачем? На Win7 проблем быть не должно.

Код:

To run this cmdlet on Windows Vista and later versions of Windows,
open Windows PowerShell with the Run as administrator option.

Через wmic тоже должно работать, Enable-ComputerRestore и есть обёртка над wmic SystemRestore.

https://learn.microsoft.com/en-us/po...powershell-5.1

[biffick]

Вот скрипт с PowerShell для системного диска (%systemdrive%)

Код:

rem Создание точки восстановления
echo.
echo Включение Защиты системы...
@powershell -ex Unrestricted -c "Enable-ComputerRestore -Drive '%systemdrive%'"
vssadmin Resize ShadowStorage /On=%systemdrive% /For=%systemdrive% /Maxsize=10.5GB
echo Выполнено.
echo.
echo Создание точки восстановления системы...
reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\SystemRestore" /v "SystemRestorePointCreationFrequency" /t REG_DWORD /d "1" /f
@powershell -ex Unrestricted -c "Checkpoint-Computer -description '1-До оптимизации' -RestorePointType 'APPLICATION_INSTALL'"
reg delete "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\SystemRestore" /v "SystemRestorePointCreationFrequency" /f
echo Выполнено.

Вот скрипт с wmic для системного диска (%systemdrive%)
(Говорят, что с Win11 23H2 wmic будет выключен по умолчанию, поэтому и PowerShell добавил)

Код:

rem Создание точки восстановления
echo.
echo Включение Защиты системы...
wmic /Namespace:\\root\default Path SystemRestore Call Enable "%systemdrive%"
vssadmin Resize ShadowStorage /On=%systemdrive% /For=%systemdrive% /Maxsize=10.5GB
echo Выполнено.
echo.
echo Создание точки восстановления системы...
reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\SystemRestore" /v "SystemRestorePointCreationFrequency" /t REG_DWORD /d "1" /f
wmic /Namespace:\\root\default Path SystemRestore Call CreateRestorePoint "1-До оптимизации", 100, 12
reg delete "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\SystemRestore" /v "SystemRestorePointCreationFrequency" /f
echo Выполнено.

Скрипты протестированы в Win7 и Win11.
Тему можно закрывать.

[Anton04]

Тему можно закрывать. »

Для этого и существует пометить тему решённой. И это доступно только создателю темы.