CMD/BAT - [решено] Проверка количества вводимых символов в переменную

megaloman · Отправлено: **08:50, 15-02-2023** | #2

Код:

@Echo Off
cls
	Set /A Min=8, Max=63
	Set "R=0-9A-Za-z"
	:Begin
		Echo.
		Set "KEY="
		(Set /P KEY=Input KEY %Min%^<=n^<=%Max% "%R%" or empty string for Exit ^> )
		If "%KEY%"=="" (Echo Empty string. Canceled. &Exit /B 0)
		Call :Check "%KEY%" %Min% %Max% "%R%"
	If %ErrorLevel% NEQ 0 (Echo !!! Wrong KEY="%KEY%" &GoTo :Begin)

	Echo. &Echo we continue to sculpt our ingenious script :) !!!
Pause
Exit /B

:Check
	If "%~1"=="" Exit /B 1
	Set /A MM=%2-1
	Set "In=%~1"
	Call Set "In1=%%In:~%MM%,1%%"
	Call Set "In2=%%In:~%3,1%%"
	If Not "%In1%"=="" If "%In2%"=="" Echo %~1|>nul 2>nul FindStr /R /C:"^[%~4]*$" &&Exit /B 0
Exit /B 1

megaloman · Отправлено: **09:33, 15-02-2023** | #3

Цитата sushnyak:

1 завершает работу при нажатии Enter (без ввода данных) »

так задумано. Я считаю, что должен быть простой способ выйти из цикла при вводе данных

Цитата sushnyak:

2 не проходит проверку если вводимые данные комбинированы (буквы и цифры) »

Это инсинуации

. Докажите. Свой скриншот я приложил

sushnyak · Отправлено: **10:08, 15-02-2023** | #4

Код:

If "%KEY%"=="" (Echo Empty string. Canceled. &Exit /B 0)

в этой строке заменил выделенное на

Код:

GoTo :Begin

Лишь в этом случае сценарий продолжает работать,
если поле ввода оставить пустым и нажать Enter (без ввода данных)

Можно ли скрыть лишнюю информацию из выводимой строки приглашения ?

Цитата:

Input KEY 8<=n<=63 "0-9A-Za-z" or empty string for Exit >

лишнее выделил

YuS_2 · Отправлено: **10:20, 15-02-2023** | #5

Цитата sushnyak:

проверка количества вводимых символов в переменную »

Цитата sushnyak:

символы могут быть как цифровые/текстовые/комбинированные »

Будьте осторожны в своих желаниях

Надо понимать, что попытка ввода некоторых недопустимых символов попросту будет заваливать весь код, т.е. будет вызвано исключение и прерывание работы сценария. Полностью исключить такую ситуацию в CMD затруднительно.

sushnyak · Отправлено: **10:26, 15-02-2023** | #6

Цитата megaloman:

Это инсинуации . Докажите. Свой скриншот я приложил »

Они самые

по невнимательности вводил буквы кириллицей.
так что пардоньте

sushnyak · Отправлено: **10:55, 15-02-2023** | #7

Цитата YuS_2:

попытка ввода некоторых недопустимых символов »

о спец символах не было речи, если смутило слово комбинированные,
то подразумевается ввод текстово-цифровой (46h0j35b3v86) для примера.

megaloman · Отправлено: **13:41, 15-02-2023** | #8

sushnyak,

По мотивам Ваших хотелок с косметическими изменениями

Код:

@Echo Off
cls
	Set /A Min=8, Max=63
	Set "R=0-9A-Za-z"
	:Begin
		Echo. &Set "KEY="
		(Set /P KEY=Input KEY ^> )
	Call :Check "%KEY%" %Min% %Max% "%R%" ||(Echo !!! Wrong KEY="%KEY%" &GoTo :Begin)

	Echo. &Echo KEY="%KEY%" We continue to sculpt our ingenious script :) !!!

Pause
Exit /B

:Check
	Echo %~1|>nul 2>nul FindStr /R /C:"^[%~4]*$" ||Exit /B 1
	Set /A MM=%2-1
	Set "In=%~1"
	Call Set "In1=%%In:~%MM%,1%%"
	Call Set "In2=%%In:~%3,1%%"
	If Not "%In1%"=="" If "%In2%"=="" Exit /B 0
Exit /B 1

sushnyak · Отправлено: **14:58, 15-02-2023** | #9

megaloman,

Премного благодарен за помощь,
последний код - самое, что надо

YuS_2 · Отправлено: **17:06, 15-02-2023** | #10

Цитата sushnyak:

о спец символах не было речи, если смутило слово комбинированные »

Да мне-то чего смущаться?

Элементарная логика... если Вам требуется проверка на правильность ввода, то это явно не лично для Вас (а иначе не вижу смысла в такой проверке). Далее, если символы будет вводить кто-то ещё, то ему рано или поздно придет в голову мысль, что надо попробовать набрать какое-нибудь непотребство (если есть уверенность, что не придет, то всегда на готове встречный вопрос: а зачем тогда проверка?). В общем, код будет завален, сценарий прерван, со всеми вытекающими... а вот далее, всё зависит от критичности исполнения кода и естественно, решение о приемлемости неустойчивого кода... за Вами.