[megaloman]

vbs

Код:

MyDir = "Z:\Soft_In"
Ext = "txt"

MyMask = "^.*\." + Ext + "$"

Set Reg = CreateObject("VBScript.RegExp")
Reg.IgnoreCase = True
Reg.Pattern = MyMask

With CreateObject("Scripting.FileSystemObject")
    Set Files = .GetFolder(MyDir).Files

    For Each File In Files
        FilePath = File.Path
        If Reg.Test(FilePath) Then
            .MoveFile FilePath, FilePath + ".~~~tmp~~~"
        End If
    Next

    Set Files = .GetFolder(MyDir).Files
    Reg.Pattern = "^.*\.~~~tmp~~~$"

    N = 0
    For Each File In Files
        FilePath = File.Path
        If Reg.Test(FilePath) Then
            N = N + 1
            .MoveFile FilePath, File.ParentFolder + "\" + CStr(N) + "." + Ext
        End If
    Next
End With

MsgBox "Done"

В ~2раза быстрее моего CMD. Переименовываю все файлы с указанным расширением. Если бы была гарантия, что все исходные файлы если и имеют цифровые имена, но более числа файлов, то переименование можно было бы сделать еще в 2 раза быстрее. В противном случае вижу только такое решение, реализованное в моих CMD и VBS: переименовывать дважды.