[Ageron]

@file - возвращает имя файла.

а вам надо указать

@path - возвращает полный путь к файлу.

[finderhd]

@file - возвращает имя файла. а вам надо указать @path - возвращает полный путь к файлу. »

Не совсем понятно, что Вы имели в виду? Поставить в конце команды @path вместо @file ?
Попробовал указать, ничего не изменилось.

[megaloman]

Folder_main\YYYYMMDD\ »

Нужно удалить все старые папки вместе с файлами, не трогая последние три. »

Если я правильно понял, надо оставить нетронутыми последние 3 папки, допустим:
Folder_main\20200210\
Folder_main\20200205\
Folder_main\20200203\
А предыдущие:
Folder_main\20200202\
Folder_main\20200201\
Folder_main\20200128\
Folder_main\20191231\
.......
удалить.

Код:

@Echo Off
cls
	Set "BoxIn=Z:\Box_In\Folder_Main"
	Set "Mask=2???????"
	Set /A Skip=3

	FOR /F "usebackq Skip=%Skip% delims=" %%f IN (`2^>nul Dir "%BoxIn%\%Mask%" /B /A:D /O:-N`) Do Call Echo %%Time%% "%BoxIn%\%%f" &Rd /S /Q "%BoxIn%\%%f"
rem pause
Exit /B 0

ИМХО, это максимально быстрый вариант, не думаю, что стОит разбивать этот процесс на части, при такой постановке задачи опускаться до работы с подпапками и удаления файлов не комильфо - преступно медленно.Можете поставить этот скрипт в планировщик и запускать его хоть сто раз в день. Гарантировано останутся три созданные последними папки.
Вставил визуальный контроль процесса, если это не надо - уберите выделенное красным цветом. ОцЕните скорость выполнения - если посчитаете, что всё-таки надо процесс разбить - пишите.

[Iska]

не думаю, что стОит разбивать этот процесс на части, при такой постановке задачи опускаться до работы с подпапками и удаления файлов не комильфо - преступно медленно. »

Да нет, нормально будет, хоть спускаясь рекурсией внутрь по дереву (я бы так и делал — спускался вниз рекурсией, удалял старые файлы, а на возврате из рекурсии вверх проверял каталог на пустоту и, если это так — тогда удалял бы его).

P.S. Первый раз можно и «ручками» удалить .

[megaloman]

Iska, в чём смысл? Вижу цель - оставить несколько последних по датам в имени папок. Счюпать каждый файл - никакого смысла.
Если уж очень хочется, то и рекурсия - не оптимум. ИМХО эффективнее сделать dir папок и конвейером на обратную сортировку. Убивать в папке файлы и после удаления файлов удалять папку без /s /q.
Но это по времени не знаю на сколько порядков медленнее, чем удалять сразу старые папки.
Эх, не хватает оценки, сколько тратится времени на удаление каждого дня.
Если принять, что за 10 лет создалось 3600 папок по дням и если каждая папка удаляется 1сек, то это уже 1 час.
Кстати, echo в моём коде наверное может хорошо замедлить процесс.

[DJ Mogarych]

finderhd, а не хотите отталкиваться от даты создания файла вместо "трёх последних папок"?

[megaloman]

Вот вариант с ограничением количества удаленных папкодней

Код:

@Echo Off
cls
	Set "BoxIn=Z:\Box_In\Folder_Main"
	Set "Mask=2???????"
	Set /A Skip=3

	Set /A MaxCount=365

	FOR /F "usebackq Skip=%Skip% delims=" %%d IN (`2^>nul Dir "%BoxIn%\%Mask%" /B /A:D /O:-N`) Do Set /A MaxDay=%%~nd &GoTo :Begin
	
	:Begin
	Set /A iCount=0
	FOR /F "usebackq delims=" %%f IN (`2^>nul Dir "%BoxIn%\%Mask%" /B /A:D /O:N`) Do (
		If %MaxDay% GEQ %%f (
			Rd /S /Q "%BoxIn%\%%f"
			Call :Counter || GoTo :End
		)
	)
	:End
rem pause
Exit /B 0

:Counter
	Set /A iCount+=1
	If %iCount% EQU %MaxCount% Exit /B 1
Exit /B 0

Set "BoxIn=Z:\Box_In\Folder_Main" - здесь пропишИте свой путь
Set /A Skip=3 -здесь количество дней, которые нужно оставить
Set /A MaxCount=365 -здесь количество дней (не более), удаляемых за один запуск батника.
Батник можно поместить в планировщик, запускать хоть раз в день, хоть несколько (надо при этом быть уверенным, что предыдущий запуск уже успел отработать).
При указанных параметрах и если задание в планировщике запускать раз в сутки, за 10 дней 10 лет Вы убьете и в последующем будут всегда оставаться три последних дня.

[Iska]

Iska, в чём смысл? »

В большей гибкости. Когда внутри могут оказаться файлы возрастом много младше каталогов, например.

[megaloman]

Когда внутри могут оказаться файлы возрастом много младше каталогов, например. »

Их нет, даже если они существуют. При том количестве файлов если какой-то файл нарушает чем-то порядок хранения - его нет. А если работает автоматизированная система- то их и в принципе быть не должно.