[Iska]

phx447, что должен делать приведённый Вами кусок кода?

[DJ Mogarych]

Четвёртая ссылка вот здесь: https://www.google.ru/search?q=Application.FileSearch

Там есть решение: https://answers.microsoft.com/en-us/...5-0a83eb6bf984

[phx447]

Iska, вот что делает
` А такой LLLLLL[][i].txt - файл имеется?
CheckExist:
`Если такой же (или следующий, или схожий по первым буквам) *.txt файл уже есть в этой папке`
With Application.FileSearch
.FileName = LastTxtName & ".txt"
.LookIn = ActiveDocument.Path
.Execute

While .Execute > 0

Incrementor = Incrementor + 1
`Поддерживается до 100 файлов`
If Incrementor < 10 Then
MatchLetters = 8 `(7 букв + 1 цифра)
Else
MatchLetters = 7 ` (6 букв + 2 цифра)
End If

LastTxtName = Left (LastTxtName, MatchLetters - 1) & Incrementor

` А такой LLLLLL[][i].txt - файл имеется?
GoTo CheckExist

Wend
End With

`Коннектим к файлу в транслите расширение *.txt
FullLastTxtName = ActiveDocument.Path & "\" & LastTxtName & ".txt"

End Sub

DJ Mogarych, я в гугле искал, но я не знаю или точнее не понимаю, как воспользоваться ответами, которые там даны.

[Iska]

phx447, я не про комментирование кода, я не этого просил от Вас. Что должен делать код? Я не понимаю его предназначение. Я хочу, чтобы Вы описали задачу, для решения которой был создан данный код.

[phx447]

Iska, данный код макросом в office 2003 проверяет текст на наличие лишних пробелов, заменяет некоторые символы на нужные, выравнивает текст по ширине и сохраняет измененный *.doc файл в *.txt. Предварительно проверив папку на наличие схожих по названию файлов при сохранении.

[Iska]

Предварительно проверив папку на наличие схожих по названию файлов при сохранении. »

Расшифруйте, пожалуйста, подробнее. Что значит «схожих по названию»? Для чего проверяет?

[phx447]

Предварительно проверив папку на наличие схожих по названию файлов при сохранении. » Расшифруйте, пожалуйста, подробнее. Что значит «схожих по названию»? Для чего проверяет?

Схожих по названию, значит идентичных, одинаковых. Например повторно применяя этот макрос на файле text.doc, то на этапе сохранения он определит, что уже имеется файл text.txt и макрос этот файл сохранит как text 1.txt.

[Iska]

повторно применяя этот макрос на файле text.doc, то на этапе сохранения он определит, что уже имеется файл text.txt и макрос этот файл сохранит как text 1.txt. »

Я этого не вижу по приведённому Вами коду.

В общем, насколько я понимаю, Вам нужна функция, которая для каталога, где расположен активный документ, и указанного имени файла вернёт первое доступное имя файла, построенное по определённому принципу.

Код:

Option Explicit

Function GetFirstFreeName(strFileName As String)
    Dim objFSO As Object
    
    Dim strBaseFileName As String
    Dim strFullFileName As String
    Dim iCount As Integer
    
    Set objFSO = CreateObject("Scripting.FileSystemObject")
    
    strBaseFileName = objFSO.GetBaseName(strFileName)
    strFullFileName = objFSO.BuildPath(ActiveDocument.Path, strBaseFileName & ".txt")
    
    iCount = 1
    
    Do While objFSO.FileExists(strFullFileName)
        iCount = iCount + 1
        strFullFileName = objFSO.BuildPath(ActiveDocument.Path, strBaseFileName & " " & CStr(iCount) & ".txt")
    Loop
    
    GetFirstFreeName = strFullFileName
End Function

т.е., например, для активного документа C:\Мои проекты\0274\Doc1.doc и переданного имени файла text.doc последовательно будут возвращаться имена:

Код:

C:\Мои проекты\0274\text.txt
C:\Мои проекты\0274\text 2.txt
C:\Мои проекты\0274\text 3.txt
C:\Мои проекты\0274\text 3.txt

и т.д. Так?

[megaloman]

Что должен делать код? Я не понимаю его предназначение. »

Напрягу воображение:
ИМХО, это отрывок макроса в WORD, пробую (для себя!) описать его назначение:
Есть некие переменные, начальное значение определёно где-то выше:
LastTxtName - имя файла без расширения
Incrementor - счетчик для повторяющихся имен
В результате работы этого куска макроса длина имени LastTxtName+Пробел+Incrementor должно быть не более 8 символов, LastTxtName урезается.
Получившееся имя ActiveDocument.Path & "\" & LastTxtName & ".txt" не должно дублировать имеющееся имя файла.
Вот вариант для замены Вашего куска:

Код:

LastTxtName = "ABCDEFGHIJKLMN"


Incrementor = 0
ActiveDocumentPath = ActiveDocument.Path + "\"
Do
    If Incrementor = 0 Then
        TxtName = Left(LastTxtName, 6)
    Else
        TxtName = Left(LastTxtName, 7 - Len(CStr(Incrementor))) + " " + CStr(Incrementor)
    End If
    FullLastTxtName = ActiveDocumentPath + TxtName + ".txt"
    D = Dir(FullLastTxtName)
    If D = "" Then Exit Do
    Incrementor = Incrementor + 1
Loop


MsgBox """" + FullLastTxtName + """"

Зачеркнутые строки мне были нужны для отладки - Вы их удалте.
Incrementor = 0 - не знаю, нужно или нет, если эта переменная выше приведенного куска где-то определялась, то эту строку надо удалить.
Не очень понимаю, какое имя должно получиться при Incrementor = 0. Я сделал для отладочного имени ABCDEF.txt
В принципе, начальное значение Incrementor может быть не 0, а любое допустимое >0, например, 1 (первое имя при этом будет ABCDEF 1.txt).
Максимальная величина Incrementor в отладочном имени "A 999999.txt. Надеюсь, хватит.