[megaloman]

Попробуйте. Это решение именно для этой структуры Вашего файла

Код:

@Echo Off
cls
	SetLocal EnableExtensions,EnableDelayedExpansion 
	CHCP 1251 >nul

	Set  "BoxIn=Z:\Box_In"
	Set "BoxOut=Z:\Box_Out"
	Set "BoxArc=Z:\Box_Arc"

	Set "Mask=incoming*.txt"

	2>nul Md "%BoxOut%"
	2>nul Md "%BoxArc%"

	Call :Replacement

	FOR %%f IN ("%BoxIn%\%Mask%") DO (
		Echo ========= "%%f"
		>"%BoxOut%\%%~nxf" (FOR /F "usebackq tokens=1,2,3,4,5,6,7,8,9,10 delims=;=" %%i IN ("%%f") DO (
			Set "ssl=%%l"
			Set "ssn=%%n"

			Call :Substitute "ssl" "%%%%l%%"
			Call :Substitute "ssn" "%%%%n%%"
			Echo %%i=%%j;%%k=!ssl!;%%m=!ssn!;%%o=%%p;%%q=%%r;
		))
		Move /Y "%%f" "%BoxArc%\"
	)
	EndLocal
pause
Exit /B

:Substitute
	If Not "%~2"=="" Set "%~1=%~2"
Exit /B

:Replacement

Set "voronez=Воронеж"
Set "tver=Тверь"
Set "rostov=Ростов"
Set "sochi=Сочи"

Exit /B

[Stolc]

Вау, скрипты все сложнее..как тибетская клинопись. )
Не работает скрипт - пишет "для продолжения нажмите кнопку" и закрывается

[megaloman]

Не работает скрипт - пишет "для продолжения нажмите кнопку" и закрывается »

А в инбоксе файлы есть? Может, они уже в архиве после предыдущего скрипта? А файлы отображаются при работе скрипта? А в аутбокс файлы попадают? А кодировка какая? А пары для замены Вы переделали для нового формата этого батника?

[Stolc]

Да, пары переделал. В InBox файлы есть. Кодировка 1251. В OutBox не попадают файлы.

[megaloman]

А файлы отображаются при работе скрипта? »

Переименуйте ваш батник в txt-файл, предоставьте, и неплохо бы заархивировать реальный файл и приложить к сообщению, или фрагмент файла. Структура файла именно такая, или там еще какие-то заголовки присутствуют?

[Stolc]

Беру паузу до завтра. Попробую разобраться позже. Спасибо за помощь!

[Stolc]

В общем, попробовал через vbs-скрипт сделать замену в файлах. Все работает на ура.

Создал файл replace.vbs

PHP код:

Const ForReading = 1    

Const ForWriting = 2

strFileName = Wscript.Arguments(0)

Set objFSO = CreateObject("Scripting.FileSystemObject")

Set objFile = objFSO.OpenTextFile(strFileName, ForReading)

strText = objFile.ReadAll

objFile.Close



strText = Replace(strText, "voronez" , "Воронеж")

strText = Replace(strText, "tver" , "Тверь")

strText = Replace(strText, "sochi" , "Сочи")



Set objFile = objFSO.OpenTextFile(strFileName, ForWriting)

objFile.Write strText  'WriteLine adds extra CR/LF

objFile.Close 

и через bat-файл запускаю его, указав в качестве параметра имя файла.

[megaloman]

Будет папка IN, в эту папку попадают файлы для обработки. После обработки файлы попадают в папку OUT.»

Ваш скрипт это не делает.

Вот вариант. Обрабатываются все файлы в инбоксе, обработанные идут в аутбокс, исходный перемещается в архив.
Это чистый vbs, CMD не задействован

Код:

BoxIn = "Z:\Box_In"
BoxOut = "Z:\Box_Out"
BoxArc = "Z:\Box_Arc"

RegExp = "incoming.*\.txt"

Mre = Array("voronez", "Воронеж", _
            "tver", "Тверь", _
            "rostov", "Ростов", _
            "sochi", "Сочи", _
            "moskva", "Москва", _
            "orel", "Орел")

Set Mask = CreateObject("VBScript.RegExp")
Mask.Pattern = RegExp
Mask.IgnoreCase = True
Mask.Global = True
            
j = 0
With CreateObject("Scripting.FileSystemObject")
    Set Fold = .GetFolder(BoxIn)
    Set Files = Fold.Files

    For Each iFile In Files       ' Цикл по файлам в папке (как вариант решения)
        If Mask.Test(iFile.Name) Then
            Set Fin = .OpenTextFile(iFile, 1, False)
            Text = Fin.ReadAll
            Fin.Close
            
            For i = LBound(Mre) To UBound(Mre) Step 2
                Text = Replace(Text, Mre(i), Mre(i + 1))
            Next
            
            Set Fout = .OpenTextFile(BoxOut + "\" + iFile.Name, 2, True)
            Fout.Write Text
            Fout.Close
            
            If .FileExists(BoxArc + "\" + iFile.Name) Then .DeleteFile BoxArc + "\" + iFile.Name, True
            .MoveFile iFile, BoxArc + "\"
            j = j + 1
        End If
    Next
End With
MsgBox "Обработано " + CStr(j) + " файлов"

Мой второй CMD работает на порядок быстрее, чем первый, однако vbs работает мигом.