[megaloman]

VBS. Если в имени файла русские буквы - сохранить в 1251 кодировке

Код:

NMax = 56789
OutFile = "Z:\Box_Out\полная фигня.txt"

N1 = 32
N2 = 127
NS = N2 - N1

ReDim S(NS)

For i = 0 To NS
    S(i) = Chr(i + N1)
Next

NS1 = NS + 1
SS = ""

Randomize
For i = 1 To NMax
    SS = SS + S(Int(NS1 * Rnd))
Next

Set FSO = CreateObject("Scripting.FileSystemObject")
With FSO.CreateTextFile(OutFile, True)
    .Write SS
    .Close
End With


MsgBox Len(SS)

Вся последовательность генерируется. Работает, на вскидку, на порядок-два быстрее (не анализировал с цифрами) CMD. Но сотни символов - всё равно медленно.
Набор символов можно взять с кодами от 0 до 255. (N1 и N2).
Если можно

А может это можно ускорить копированием -вставкой? »

, то возможно сгенерировать, допустим, 50000 знаков и затем их повторить нужное число раз. Это радикально ускорит работу.

[Iska]

Код:

Option Explicit

Dim dtNow

Dim strSourceFile
Dim iCount
Dim i, j
Dim sValue


dtNow = Now()

strSourceFile = "C:\Мои проекты\0254\полная фигня 2.txt"
iCount = 2^10

Randomize Timer

With WScript.CreateObject("Scripting.FileSystemObject").CreateTextFile(strSourceFile, True)
	For i = 1 To iCount
		sValue = ""
		
		For j = 1 To iCount
			sValue = sValue & Chr(Int(96 * Rnd()) + 32)
		Next
		
		.Write sValue
	Next
	
	.Close
End With

WScript.Echo DateDiff("s", dtNow, Now())

WScript.Quit 0

Если мне не изменяет память — максимальный размер строки должен вертеться в интервале примерно от 512 до 4096 (хотя мог уже и запамятовать, а ещё раз тестировать лень).

[megaloman]

Iska, И всё-таки она вертится! Впечатлился скоростью работы Вашего скрипта. Ранее перед записью в файл я формировал всю строку целиком, затем скидывал в файл. ~500000 символов формировалось долго.

Вот vbs-вариант, в котором все символы генерируются случайным образом, но запись на диск ведётся квантами по 1024 знака как у Вас, а не целиком.
Отрабатывает за считанные секунды на моём допотопном ноуте

Код:

NMax = 543210
OutFile = "Z:\Box_Out\полная фигня 543210.txt"

N1 = 0
N2 = 255

Quant = 1024

NS = N2 - N1

ReDim S(NS)

For i = 0 To NS
    S(i) = Chr(i + N1)
Next

NS1 = NS + 1
SS = ""

Randomize

Set FSO = CreateObject("Scripting.FileSystemObject")
With FSO.CreateTextFile(OutFile, True)
	j = 0
	For i = 1 To NMax
		j = j + 1
    		SS = SS + S(Int(NS1 * Rnd))
		If j = Quant Then
			j = 0
			.Write SS
			SS = ""
		End If
	Next

    	If j > 0 Then .Write SS
    	.Close
End With

MsgBox "Скрипт завершен"

Похоже, можно пооптимизировать размер кванта, но пока это за пределами моего трудолюбия.

[Iska]

50000 — многовато, начинают сказываться издержки на конкатенацию строк.

Для примера

0004.vbs:

Код:

Option Explicit

Dim dtNow

Dim strSourceFile
Dim iCount
Dim i, j
Dim sValue


dtNow = Now()

strSourceFile = "C:\Мои проекты\0254\полная фигня 2.txt"
iCount = 2^15

Randomize Timer

With WScript.CreateObject("Scripting.FileSystemObject").CreateTextFile(strSourceFile, True)
	For i = 1 To iCount
		sValue = ""

		For j = 1 To 2^10 ' Всего — 2^25, 32Мб выйдет
			sValue = sValue & Chr(Int(96 * Rnd()) + 32)
		Next

		.Write sValue
	Next

	.Close
End With

WScript.Echo DateDiff("s", dtNow, Now())

WScript.Quit 0

и 0005.vbs:

Код:

dtNow = Now()

NMax = 2^25
OutFile = "C:\Мои проекты\0254\полная фигня 543210.txt"

N1 = 0
N2 = 255

Quant = 50000

NS = N2 - N1

ReDim S(NS)

For i = 0 To NS
    S(i) = Chr(i + N1)
Next

NS1 = NS + 1
SS = ""

Randomize

Set FSO = CreateObject("Scripting.FileSystemObject")
With FSO.CreateTextFile(OutFile, True)
	j = 0
	For i = 1 To NMax
		j = j + 1
    		SS = SS + S(Int(NS1 * Rnd))
		If j = Quant Then
			j = 0
			.Write SS
			SS = ""
		End If
	Next

    	If j > 0 Then .Write SS
    	.Close
End With

'MsgBox "Скрипт завершен"
WScript.Echo DateDiff("s", dtNow, Now())

Примерный итог:

[4zz]

megaloman, Iska,
Спасибо!!! )

[megaloman]

Iska, Уже понял и исправил. Как подсчитать оптимум?

[4zz]

Извиняюсь.., а как прописать избранные и исключенные символы?

[Iska]

Как подсчитать оптимум? »

Я тупо брал и циклически наращивал размер строки степенями двойки то ли с 64, то ли со 128 символов до то ли 32 Kb, то ли до 64 Kb, и писал некий, достаточно большой объём в файл. И подсчитывал время (всё это, разумеется, в одном скрипте, дабы не вручную). Точную цифру я уже не помню, но оптимум находился где-то в промежутке 512-4096 символов. Если вдруг найдётся время — попробую повторить.

а как прописать избранные и исключенные символы? »

В моём варианте — пока никак.

[4zz]

megaloman,
В cmd я пытался регулировать в Вашем варианте:
rem не использовать ^%&|<>"()'=
Set "Symb=+1234567890-QWERTYUIOPqwertyuiopASDFGHJKLasdfghjklZXCVBNM?zxcvbnm"

[megaloman]

а как прописать избранные и исключенные символы? »

Задавайте литерал с символами сами внутри кавычек. Кавычка " прописывается в литерале удвоением ""

Код:

NMax = 5432109
OutFile = "Z:\Box_Out\полная фигня 5432109.txt"

AllChr = "~!@#$%^&*()_+QWERTYUIOP{}ASDFGHJKL:""|ZXCVBNM<>?`1234567890-=qwertyuiop[]asdfghjkl;'\zxcvbnm,./ "

Quant = 1024

N1 = 1
N2 = Len(AllChr)
NS = N2 - N1

ReDim S(NS)

For i = 0 To NS
    S(i) = Mid(AllChr, i + 1, 1)
Next

NS1 = NS + 1
SS = ""

Randomize

Set FSO = CreateObject("Scripting.FileSystemObject")
With FSO.CreateTextFile(OutFile, True)
    j = 0
    For i = 1 To NMax
        j = j + 1
            SS = SS + S(Int(NS1 * Rnd))
        If j = Quant Then
            j = 0
            .Write SS
            SS = ""
        End If
    Next

        If j > 0 Then .Write SS
        .Close
End With

MsgBox "Скрипт завершен"

rem не использовать ^%&|<>"()'=
в CMD не есть задание исключений, это комментарий для моей/Вашей памяти
В vbs неприятностей с этими знаками нет, в строке можно задать с клавиатуры все символы.