[Iska]

Тогда зачем их там делать несколько штук? Или больше, чем есть mp3-файлов? Пусть один и будет.

На WSH:

Скрытый текст

Код:

Option Explicit

Dim strSourceFolder
Dim strDestFolder

Dim objFSO
Dim objFile
Dim objFile2
Dim boolFound


strSourceFolder = "C:\Мои проекты\0252\A"
strDestFolder   = "C:\Мои проекты\0252\B"

Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")

If objFSO.FolderExists(strSourceFolder) Then
	If objFSO.FolderExists(strSourceFolder) Then
		boolFound = False
		
		For Each objFile2 In objFSO.GetFolder(strDestFolder).Files
			If StrComp(objFSO.GetExtensionName(objFile2.Name), "mp4", 0) = 0 Then
				boolFound = True
				
				Exit For
			End If
		Next
		
		If boolFound Then
			boolFound = False
			
			For Each objFile In objFSO.GetFolder(strSourceFolder).Files
				If StrComp(objFSO.GetExtensionName(objFile.Name), "mp3", 0) = 0 Then
					boolFound = True
					objFile2.Copy objFSO.BuildPath(objFile2.ParentFolder, objFSO.GetBaseName(objFile.Name) & "." & objFSO.GetExtensionName(objFile2)), True
				End If
			Next
			
			If boolFound Then
				objFile2.Delete True
			End If
		Else
			WScript.Echo "Need at least one mp4 file in destination folder [" & strDestFolder & "]."
			WScript.Quit 3
		End If
	Else
		WScript.Echo "Can't find destination folder [" & strDestFolder & "]."
		WScript.Quit 2
	End If
Else
	WScript.Echo "Can't find source folder [" & strSourceFolder & "]."
	WScript.Quit 1
End If

Set objFSO = Nothing

WScript.Quit 0

Может, лучше опишете саму задачу?