[Iska]

А глобальная цель какая?

[megaloman]

Код:

@Echo Off
cls
	Set "IP=192.168.125.223"

	chcp 437 >nul
	Set "Key1=Pinging"
	Set "IPname=Not Found"
	FOR /F "usebackq tokens=1,2,3 delims= " %%i IN (`2^>nul Ping  -a -n 1 -4 %IP%`) DO (
		If /I "%Key1%"=="%%i" If /I "[%IP%]"=="%%k" Set "IPname=%%j"
	)
Echo %IPname%
pause

[mwz]

chcp 437 »

А если в имени компьютера есть русские буквы?

[megaloman]

mwz, Я не встречал в сети имя компьютера с русскими буквами, сам никогда такое не делал, не уверен, что это возможно, как минимум, очень вероятны проблемы при использовании софта. Как вариант

Код:

@Echo Off
cls
	Set "IP=192.168.100.23"

	Set "IPname=Not Found"
	Set "N="
	FOR /F "usebackq tokens=1,2 delims=<>" %%i IN (`2^>nul nbtstat -a %IP%`) DO (
		If "%%j"=="00" (Call Set "IPname%%N%%=%%i" &Call Set /A N+=1)
	)
	If /I Not "%IPname%"=="Not Found" Set "IPname=%IPname: =%"
Echo %IPname%
pause

А глобальная цель какая? »

Подозреваю, что без этого обойтись вполне можно

[mwz]

Я не встречал в сети имя компьютера с русскими буквами, сам никогда такое не делал, не уверен, что это возможно »

Ещё как возможно — почему и спросил.
Из-за чего имели некогда ряд проблем при обслуживании таких компьютеров в сети (досталась по наследству: компы эти не мы ставили).

[megaloman]

mwz, Ну, раз пошла такая пьянка, вот еще вариант

Код:

@Echo Off
cls
	Set "IP=192.168.100.23"

	FOR /F "usebackq delims=" %%i IN (`2^>nul Ping  -a -n 1 -4 %IP%`) DO Call :NameIP %IP% "IPName" %%i &GoTo :Continue
	:Continue
Echo %IPName%
pause
GoTo :Eof

:NameIP
	Set "%~2=Not Found"
	If "%4"=="" GoTo :Eof
	If "%4"=="[%1]" (Set "%~2=%3" &GoTo :Eof)
	Shift /3
	GoTo :NameIP  	
GoTo :Eof

[Iska]

mwz, Я не встречал в сети имя компьютера с русскими буквами, сам никогда такое не делал, не уверен, что это возможно, как минимум, очень вероятны проблемы при использовании софта. »

Возможно-возможно. Я делал во времена NT4. И проблемы возможны. Не в плане доступа или общения с машиной — в плане того, что не все программисты знают про иные языки, окромя латиницы, и плевали на иные кодовые страницы.

[f0r_ce]

Огромное спасибо за код. Глобальная цель: из известного IP получить имя ПК с последующим копированием в буфер обмена. Только загвоздка вышла: имя ПК получается в виде "имя_пк.название_домена" и ни как не получается отрезать лишнее...

[megaloman]

f0r_ce, Если в "имя_пк" нет "."

Код:

	FOR /F "delims=." %%i IN ("%IPName%") Do Set "IPName=%%i"