[Armsinglom]

Код:

Option Explicit

Const READYSTATE_COMPLETE = 4


Dim objIE

Dim objRange
Dim arrRow

Dim boolIsFirstRow


Set objIE = Nothing

With WScript.CreateObject("Excel.Application")
	With .Workbooks.Open("C:\Users\gzg\Desktop\ip.xlsx")
		With .Worksheets.Item(1)
			If .AutoFilterMode Then
				boolIsFirstRow = True
				
				For Each objRange In .AutoFilter.Range.Rows
					If boolIsFirstRow Then
						boolIsFirstRow = False
					Else
						arrRow = .Application.Transpose(.Application.Transpose(objRange.Value2))
						
						If objIE Is Nothing Then
							Set objIE = WScript.CreateObject("InternetExplorer.Application")
						End If
						
						With objIE
							.Navigate "http://admin:password@" & arrRow(1) & "/chgpassw.htm"
							
							Do
								WScript.Sleep 100
							Loop Until Not .Busy And .ReadyState = READYSTATE_COMPLETE
							
							
							With .Document.forms("frm")
								.elements("user_no").value = "130"
								
								.submit()
							End With
							
							Do
								WScript.Sleep 100
							Loop Until Not .Busy And .ReadyState = READYSTATE_COMPLETE
							
							With .Document.forms("frm")
								.elements("oldpassw").value  = "password"
								.elements("newpassw1").value = arrRow(3)
								.elements("newpassw2").value = arrRow(3)
								
								.submit()
							End With
							
							' А результат-то где?!
						End With
					End If
				Next
			Else
				WScript.Echo "Probably no Autofilter in first worksheet in this workbook."
			End If
		End With
		
		.Close
	End With
	
	.Quit
End With

If Not objIE Is Nothing Then
	objIE.Quit
	Set objIE = Nothing
End If
WScript.Quit 0