[Iska]

«Брюки превращаются, брюки превращаются…»™

kot900, а почему Вы решили, что это UTF-8? BOM нет, символов за пределами первой половины таблицы ASCII нет, почему UTF-8-то?!

Итак:

• есть некий «корневой» каталог;
• в нём расположено N каталогов;
• в каждом из этих N каталогов находится файл «information.log», а также прочие файлы и каталоги, нас не интересующие;
• мы должны пройтись по каждому из N каталогов, осуществив поиск некоей искомой подстроки text1 в файле «КорневойКаталог\КаталогNN\information.log»;
• если искомая подстрока text1 будет найдена в файле «КорневойКаталог\КаталогNN\information.log», требуется скопировать «КаталогNN» под тем же именем из «КорневойКаталог» в некий каталог назначения «КаталогНазначения».

Так?

Скрытый текст

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

set sRootFolder=C:\Мои проекты\0208
set sDestFolder=C:\Мои проекты\0209
set sFileName=information.log
set "sText4Find=wininit.exe"

if exist "%sRootFolder%\." (
	if exist "%sDestFolder%\." (
		for /d %%i in ("%sRootFolder%\*.*") do (
			echo ===================================
			echo [%%~i]
			if exist "%%~i\%sFileName%" (
				>nul 2>&1 find.exe /i "%sText4Find%" "%%~i\%sFileName%" && (
					echo Found text [%sText4Find%] in file [%%~i\%sFileName%].
					2>nul md "%sDestFolder%\%%~nxi"
					echo -----------------------------------
					xcopy.exe /e /c /f /y "%%~i" "%sDestFolder%\%%~nxi\"
					echo -----------------------------------
				) || (
					echo Not found text [%sText4Find%] in file [%%~i\%sFileName%].
				)
			) else (
				echo Can't find file [%sFileName%] in folder [%%~i].
			)
			echo.
		)
	) else (
		echo Can't find destination folder [%sDestFolder%].
		exit /b 2
	)
) else (
	echo Can't find 'root' folder [%sRootFolder%].
	exit /b 1
)

endlocal
exit /b 0