Имя пользователя:
Пароль:  
Помощь | Регистрация | Забыли пароль?  | Правила  

Компьютерный форум OSzone.net » Сфера Microsoft » Microsoft Office (Word, Excel, Outlook и т.д.) » 2007 - [решено] Печать из командной строки.

Ответить
Настройки темы
2007 - [решено] Печать из командной строки.

Новый участник


Сообщения: 2
Благодарности: 0

Профиль | Отправить PM | Цитировать


Посоветуйте, как из командной строки напечатать выбранный лист MS World?

Отправлено: 01:37, 04-08-2018

 

Ветеран


Contributor


Сообщения: 22508
Благодарности: 6510

Профиль | Отправить PM | Цитировать


Скриптом. WSH или PowerShell.

Например, так (на WSH):
Скрытый текст
Код: Выделить весь код
Option Explicit

Const wdPrintFromTo      = 3
Const wdDoNotSaveChanges = 0

Dim strSourceFile
Dim intPage


If WScript.Arguments.Named.Count = 2 Then
	If WScript.Arguments.Named.Exists("SourceFile") Then
		strSourceFile = WScript.Arguments.Named.Item("SourceFile")
		
		With WScript.CreateObject("Scripting.FileSystemObject")
			If .FileExists(strSourceFile) Then
				Select Case LCase(.GetExtensionName(strSourceFile))
					Case "doc", "docx", "docm"
						If WScript.Arguments.Named.Exists("Page") Then
							If IsNumeric(WScript.Arguments.Named.Item("Page")) Then
								intPage = WScript.Arguments.Named.Item("Page")
								
								With WScript.CreateObject("Word.Application")
									With .Documents.Open(strSourceFile, False, True, False)
										.PrintOut False,, wdPrintFromTo,, intPage, intPage
										.Close
									End With
									
									.Quit wdDoNotSaveChanges
								End With
							Else
								ShowUsage "Argument <Page> [" & WScript.Arguments.Named.Exists("Page") & "] is not a numeric value."
								WScript.Quit 4
							End If
						Else
							ShowUsage "Argument <Page> is missing."
							WScript.Quit 4
						End If
					Case Else
						ShowUsage "Source file [" & strSourceFile & "] probably not an Microsoft Word document file."
						WScript.Quit 4
				End Select
			Else
				ShowUsage "Can't find source file [" & strSourceFile & "]."
				WScript.Quit 3
			End If
		End With
	Else
		ShowUsage "Argument <SourceFile> is missing."
		WScript.Quit 2
	End If
Else
	ShowUsage ""
	WScript.Quit 1
End If

WScript.Quit 0
'=============================================================================

'=============================================================================
Sub ShowUsage(strComment)
	Dim strShowUsage
	
	strShowUsage = _
		"Usage:   wscript.exe """ & WScript.ScriptName & """ /SourceFile:<Source file> /Page:<Page number>" & vbCrLf & _
		"" & vbCrLf & _
		"Example: wscript.exe """ & WScript.ScriptName & """ /SourceFile:""c:\Users\User\Documents\My document.doc"" /Page:4"
	
	If Len(strComment) > 0 Then
		WScript.Echo strComment & vbCrLf & vbCrLf & strShowUsage
	Else
		WScript.Echo strShowUsage
	End If
End Sub
'=============================================================================
Это сообщение посчитали полезным следующие участники:

Отправлено: 03:16, 04-08-2018 | #2



Для отключения данного рекламного блока вам необходимо зарегистрироваться или войти с учетной записью социальной сети.

Если же вы забыли свой пароль на форуме, то воспользуйтесь данной ссылкой для восстановления пароля.


Новый участник


Сообщения: 2
Благодарности: 0

Профиль | Отправить PM | Цитировать


@Iska, Спасибо!

Отправлено: 08:54, 04-08-2018 | #3


Аватара для ziku

Старожил


Сообщения: 432
Благодарности: 37

Профиль | Отправить PM | Цитировать


Сильно заумно такие скипты писать. почитайте ТУТ просто и сердито. А можно очень просто создать BAT фаил где печать пойдет по умолчанию. А не простынь скрипта.

-------
Опыт - это учитель, который очень дорого берет за свои уроки.Лучше один раз взяться за ум, чем потом всю жизнь хвататься за голову.


Отправлено: 13:43, 11-08-2018 | #4


Ветеран


Contributor


Сообщения: 22508
Благодарности: 6510

Профиль | Отправить PM | Цитировать


ziku, ну, Вы же нам не просто ткнёте ссылкой, а популярно расскажете, как напечатать отдельную страницу документа из командной строки, не правда ли?!

Отправлено: 17:55, 11-08-2018 | #5



Компьютерный форум OSzone.net » Сфера Microsoft » Microsoft Office (Word, Excel, Outlook и т.д.) » 2007 - [решено] Печать из командной строки.

Участник сейчас на форуме Участник сейчас на форуме Участник вне форума Участник вне форума Автор темы Автор темы Шапка темы Сообщение прикреплено

Похожие темы
Название темы Автор Информация о форуме Ответов Последнее сообщение
Как создать BMP файл из командной строки. Как работать с графикой из командной строки MKN Хочу все знать 22 23-03-2016 11:03
CMD/BAT - запуск командной строки от имени администратора из командной строки jah Скриптовые языки администрирования Windows 18 19-09-2015 08:59
CMD/BAT - Разное поведение SET при запуске из командной строки и из файла madeinussr Скриптовые языки администрирования Windows 6 09-05-2015 23:25
Доступ - [решено] Запуск командной строки от имени Администратора из командной строки emcee Microsoft Windows 8 и 8.1 10 17-05-2014 21:37
Печать файлов из командной строки Loki3D Microsoft Windows NT/2000/2003 4 12-07-2007 08:55




 
Переход