[Iska]

FIND: Invalid switch написал только. »

Что-то Вы не то скопировали, видимо.

важно отметить, это hyper-v server 2016, возможно не хватает каких-то компонентов. »

Э… Это банальная командная строка, внешняя утилита, родная.

Что говорит:

Код:

find.exe /?

?

[zegordo]

Что говорит: »

всё верно, как-то не так скопировал

теперь говорит

Код:

CLI Version: 4.1.10.16   RaidAPI Version: 5.0.0.1061
Welcome to RAID Command Line Interface.

> -o : invalid object '-vd'
> info: option -o is required
> Ambiguous command 'in'!
> Ambiguous command 'i'!
> Type 'exit' to exit CLI.

так же чуть ранее обновил пост предыдущий, после вашего нового сообщения. http://forum.oszone.net/post-2807225-10.html

[Iska]

zegordo, а если так, напрямую:

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

c:\mvsetup.exe info -0 -vd | find.exe /i "degraded" && (
	c:\mvsetup.exe info -0 -vd | find.exe /i "rebuilding" && (
		echo Status: Degraded and rebuilding
		exit /b 1
	) || (
		echo Status: Degraded
		exit /b 2
	)
) || (
	echo Status: Successfull
	exit /b 0
)

endlocal
exit /b 0

?

> -o : invalid object '-vd' > info: option -o is required »

Я брал отсюда:

Текст в первом посте выдаётся командой "info -o -vd" »

Смотрите сами, что там должно быть, «-0» или «-o».

[zegordo]

то выглядит так

Скрытый текст

и в конце ещё status: successful
если не зажимать мышкой

[Казбек]

Казбек, ваш вариант рабочий, только если есть и degraded и rebuilding выводит 2, потом 0 за одно исполнение »

Пробуйте так:

Код:

@echo off

>nul find "degraded" file.txt && >nul find "rebuilding" file.txt && (
echo 2
pause
exit /b
)

>nul find "rebuilding" file.txt || >nul find "degraded" file.txt || (
echo 1
pause
)

>nul find "degraded" file.txt && (
echo 0
pause
)

[Iska]

и в конце ещё status: successful если не зажимать мышкой »

1. Не зажимайте. Просто откройте командную строку и выполните в ней пакетный файл. Я не вижу смысла добавлять всяческие pause в пакетные файлы.
2. А какой на самом деле сейчас статус?

[zegordo]

Пробуйте так: »

Спасибо, пока выглядит рабочим, возьму как план Б, если не получится сделать без файлов ввода/вывода

Смотрите сами, что там должно быть, «-0» или «-o». »

там o, я неправильно в посте дал, но в вашем коде заметил свою ошибку и её исправлял, поэтому все мои ответы - верны.

1. Не зажимайте. Просто откройте командную строку и выполните в ней пакетный файл. Я не вижу смысла добавлять всяческие pause в пакетные файлы. 2. А какой на самом деле сейчас статус?»

без паузы или вывода результат в файл батник быстро отрабатывает, на миг оставляя "status: successful" в своём окне cmd (независимо от состояния рейда)


Вообще CLI этот схож с телнетом, если запускать его из командной строки - т.е. после команды telnet в батнике, команды что были после не сработают. Но думаю, вы это и так поняли уже

[Iska]

там o, я неправильно в посте дал, но в вашем коде заметил свою ошибку и её исправлял, поэтому все мои ответы - верны. »

Спасибо, ясно.

без паузы или вывода результат в файл батник быстро отрабатывает, на миг оставляя "status: successful" в своём окне cmd »

Я ж говорю — «ручками» откройте окно командной строки и в нём запускайте пакетный файл. Я вообще пользую Far Manager.

Вообще CLI этот схож с телнетом, если запускать его из командной строки - т.е. после команды telnet в батнике, команды что были после не сработают. »

Я бы сказал, что скорее на diskpart.

Тогда пробуем вернуться именно к варианту с echo, только добавив в него ещё и exit, наподобие:

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

(
	echo info -o -vd
	echo exit
) | c:\mvsetup.exe | find.exe /i "degraded" && (
	(
		echo info -o -vd
		echo exit
	) | c:\mvsetup.exe | find.exe /i "rebuilding" && (
		echo Status: Degraded and rebuilding
		exit /b 1
	) || (
		echo Status: Degraded
		exit /b 2
	)
) || (
	echo Status: Successfull
	exit /b 0
)

endlocal
exit /b 0

Можете даже выложить его (mvsetup.exe) вместе с потребными библиотеками куда-нибудь на обменник «на пощупать», упаковав в архив.

[zegordo]

Iska, выглядит так, что ничего не изменилось
https://drive.google.com/open?id=1HF...Jevi7OcUWQWY-d - инсталлятор, при установке надо галкой отметить CLI чтобы поставил,
https://support.hpe.com/hpsc/doc/pub...a00022850en_us - гайдик
не знаю, поставится ли если контроллера нет.

апдейт
https://drive.google.com/open?id=1ZS...Brf4E_EZne0A1L вот сама утилита с библиотеками
на другом компе выдаёт по команде info -o -vd "Unable to get info of vd (error 13: Invalid adapter id)" что, в принципе, тот же текст.

[megaloman]

Есть текстовый файл со следующим содержанием, в котором состояние логического диска рейда. »

Я бы предложил постановку:
1. Если нет ни rebuilding ни degraded, выводить 0 (это нормальное рабочее состояние системы, не нуль = уровень ошибки)
2. Если в тексте есть слово degraded и нет rebuilding, выводить "-1" (именно с минусом)
3. Если есть rebuilding и нет degraded выводить "-10"
4. Если есть rebuilding и degraded выводить "-11"
5. Если есть degraded с процентами, выводить проценты (в данном тексте 23 - тут бы я, вообще-то выводил бы 123, так как есть вероятность индикации 0% -легко подкорректировать)
Наверное, пункт 4 не реализуется никогда, так как его "перебьет" пункт 5.

Вот решение для текстового файла - проверял на Ваших текстах

Код:

@Echo Off
cls

Set "FileIn=Z:\Soft_In\text1.txt"
Set "Word1=degraded"
Set "Word2=rebuilding"

Set /A LWord1=0
find /i "%Word1%" "%FileIn%" >nul &&Set /A LWord1=-1

Set /A LWord2=0
Set "Proc="
FOR /F "usebackq tokens=1,5 delims= " %%r IN (`"find /i "%Word2%" "%FileIn%""`) DO (Set /A LWord2=-10 &Set "Proc=%%s")

If Not "%Proc%"=="" (
	Set /A OutErr=%Proc:~0,-1% 
) Else (
	Set /A OutErr=%LWord1%+%LWord2%
)

Echo %OutErr%
pause
Exit /B %OutErr%

Вот попытка решения без текстового файла. Проверялось частично: c:\mvsetup.exe моделировал More.com c файлом, так как иначе протестировать не на чем

Код:

@Echo Off
cls

Set "PRG=c:\mvsetup.exe"
Set "Word1=degraded"
Set "Word2=rebuilding"

Set /A LWord1=0
"%PRG%" |find /i "%Word1%" >nul &&Set /A LWord1=-1

Set /A LWord2=0
Set "Proc="

FOR /F "usebackq tokens=1,5 delims= " %%r IN (`""%PRG%" |find /i "%Word2%" "%FileIn%""`) DO (Set /A LWord2=-10 &Set "Proc=%%s")

If Not "%Proc%"=="" (
	Set /A OutErr=%Proc:~0,-1% 
) Else (
	Set /A OutErr=%LWord1%+%LWord2%
)

Echo %OutErr%
pause
Exit /B %OutErr%

Уточните, пожалуйста, как запускается "c:\mvsetup.exe", с какими ключами и параметрами

Значение работы скрипта присваивается переменной и отображается, если Вам это нужно. Скрипт возвращает Errorlevel c этим значением, если понадобится этот скрипт вызывать из другого скрипта.