[raddy]

Как отключить задание в Планировщике заданий с помощью CMD? »

SchTasks /Change /TN "\Microsoft\Windows\папка\задание" /Disable

Описание параметров - SchTasks /Change /?

[Сrack]

Система работает в двух режимах, обычный и защищенный фильтром UWF. Так вот, в защищенном режиме хочу "глушить" некоторые запланированные задачи. В скриптовых языках разбираюсь плохо, но хотелось бы реализовать именно через bat-ник.
Задача: остановить и отключить все задания из папки Microsoft\Windows\.NET Framework
То, что у меня есть:

Код:

SchTasks /End /TN "Microsoft\Windows\.NET Framework\.NET Framework NGEN v4.0.30319"
SchTasks /Change /TN "Microsoft\Windows\.NET Framework\.NET Framework NGEN v4.0.30319" /Disable

SchTasks /End /TN "Microsoft\Windows\.NET Framework\.NET Framework NGEN v4.0.30319 64"
SchTasks /Change /TN "Microsoft\Windows\.NET Framework\.NET Framework NGEN v4.0.30319 64" /Disable

SchTasks /End /TN "Microsoft\Windows\.NET Framework\.NET Framework NGEN v4.0.30319 64 Critical"
SchTasks /Change /TN "Microsoft\Windows\.NET Framework\.NET Framework NGEN v4.0.30319 64 Critical" /Disable

SchTasks /End /TN "Microsoft\Windows\.NET Framework\.NET Framework NGEN v4.0.30319 Critical"
SchTasks /Change /TN "Microsoft\Windows\.NET Framework\.NET Framework NGEN v4.0.30319 Critical" /Disable

в теории, версия может поменяться, хотелось бы реализовать универсальный метод.

[Iska]

Покажите вывод:

Код:

schtasks.exe /query /fo csv

(перенаправьте вывод в файл, упакуйте в архив и приложите к сообщению).

[Сrack]

Iska, Файл 156487

[Iska]

Сrack, попробуйте так (не проверялось; для реального применения уберите echo):

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

for /f "usebackq delims=," %%i in (
	`schtasks.exe /query /fo csv ^| find.exe /i "\Microsoft\Windows\.NET Framework\"`
) do (
	echo schtasks.exe /end    /tn "%%~i"
	echo schtasks.exe /change /tn "%%~i" /disable

)

endlocal
exit /b 0

[Сrack]

Iska, Все получилось.

[DJ Mogarych]

Powershell:

Код:

Disable-ScheduledTask <TaskName>

[Iska]

Powershell: »

Я первым делом полез в PowerShell, обрадовался было — ну, вот, наконец-то отелились! То увы — данный командлет (как и Get-ScheduledTask) доступен только под новыми ОС. Посему для реализации был выбран старичок schtasks.exe.