[Iska]

dislike, вариантов масса. Всё зависит от того, что на самом деле Вам нужно, в каком именно виде. С какой периодичностью делать запросы. Надо ли отслеживать состояние, дабы не было дублирования информации при запросах. И т.д.

В общем виде это может быть любое средство, умеющее работать с xml.

LogParser

Код:

"C:\Program Files (x86)\Log Parser 2.2\LogParser.exe" "SELECT title, link, description, pubDate, yandex:full-text INTO DATAGRID FROM 'http://agro.tatarstan.ru/rss/agro.xml#/rss/channel/item'" -i:XML -fMode:Tree

Можно, разумеется, делать вывод не токмо в Grid, но и в текстовый документ, и в CSV.

VBScript

Код:

Option Explicit

Dim strUrl

Dim objDOMDocument
Dim objXMLDOMElement
Dim objXMLDOMSelection

Dim objWord


strUrl = "http://agro.tatarstan.ru/rss/agro.xml"

Set objDOMDocument = WScript.CreateObject("Microsoft.XMLDOM")

objDOMDocument.async = False

If objDOMDocument.load(strUrl) Then
	Set objXMLDOMSelection = objDOMDocument.selectNodes("/rss/channel/item")
	
	If Not objXMLDOMSelection Is Nothing Then
			Set objWord = WScript.CreateObject("Word.Application")
			
			With objWord.Documents.Add()
				For Each objXMLDOMElement In objXMLDOMSelection
					With .Range
						.InsertAfter objXMLDOMElement.selectSingleNode("title").text & vbLf
						.InsertAfter objXMLDOMElement.selectSingleNode("link").text & vbLf
						.InsertAfter objXMLDOMElement.selectSingleNode("description").text & vbLf
						.InsertAfter objXMLDOMElement.selectSingleNode("pubDate").text & vbLf
						.InsertAfter objXMLDOMElement.selectSingleNode("yandex:full-text").text & vbLf
						.InsertAfter vbLf
					End With
				Next
			End With
			
			objWord.Visible = True
			'objWord.Quit
			Set objWord = Nothing
	Else
		WScript.Echo "Can't parse RSS from [" & strUrl & "]."
		WScript.Quit 2
	End If
	
	Set objXMLDOMSelection = Nothing
Else
	WScript.Echo "Can't load RSS from [" & strUrl & "]."
	WScript.Quit 1
End If

WScript.Quit 0

Точно так же это может быть PowerShell, AutoIt, VB/VBA/VB.net, всяческие С/С++ и т.п.

В любом случае, мне лично ни текстовый документ, ни Word в качестве основы вывода не нравятся. Жду Вашего ответа на вопросы.