[greg zakharov]

этот код я уже пробовал... Наверно чтото делаю не так...

Не наверное, а точно.

Как вариант могу предложить локаленезависимый способ.

Код:

@echo off
  setlocal enabledelayedexpansion
    for %%i in (lodctr.exe) do (
      if not exist "%%~$PATH:i" (
        call:err "could not retrieve required data"
        goto:eof
      )
    )
    set "i=0"
    for %%i in (%*) do set /a "i+=1"
    if !i! neq 1 call:err "argument is out of range"&goto:eof
    set "pc=%tmp%\perf.tmp"
    lodctr /s:"%pc%"
    call:findlocalestr 230 object
    call:findlocalestr 684 counter
    del /f /q "%pc%"
    for /f delims^=^"^ tokens^=3 %%i in (
      'typeperf "%object%(%~1)%counter%" -sc 1 ^| findstr /rc:":"'
    ) do 2>nul set /a "s=%%i"
    if !s! equ -1 call:err "process has not been found"&goto:eof
    set /a "ss=s%%60", "s/=60", "mm=s%%60", "s/=60", "hh=s%%24", "dd=s/24"
    for %%i in (%hh% %mm% %ss%) do (
      if %%i lss 10 (set "t=!t!0%%i:") else (set "t=!t!%%i:")
    )
    echo:%dd%.%t:~,-1%
  endlocal
exit /b

:err
  echo:=^>err : %~1
exit /b 1

:findlocalestr
  for /f "tokens=2 delims==" %%i in (
    'find "%~1=" "%pc%" ^| findstr /brc:"%~1="'
  ) do set "%2=\%%i"
exit /b