[megaloman]

Александр_Кот@vk,

Как вариант, совместить перемещение файлов с их архивированием

Используем архиватор RAR. Ключ -m1 позволит задать минимальный уровень сжатия, что для бэкапа базы даст существенную экономию места при сравнительно небольших затратах по времени. Ключ -df удалит исходные файлы после успешной архивации.

Код:

@Echo off

Set "From=\\SQL\BackUp\*.bak"
Set "To=f:\SQL"

Set "Arc="C:\Program Files\WinRAR\WinRAR.exe" a -m1 -df"

FOR %%f IN ("%From%") DO %Arc% "%To%\%%~nxf.rar" "%%f"

Конечно, возможно использовать и другие архиваторы. Например, 7z

Код:

@Echo off

Set "From=\\SQL\BackUp\*.bak"
Set "To=f:\SQL"

Set "Arc="C:\Program Files\7-Zip\7zG.exe" a -mx=1 -sdel"

FOR %%f IN ("%From%") DO %Arc% "%To%\%%~nxf.7z" "%%f"

Можно копировать с последующим удалением исходного файла при успешном завершении процесса для каждого файла

Код:

@Echo off

Set "From=\\SQL\BackUp\*.bak"
Set "To=f:\SQL"
FOR %%f IN ("%From%") DO Copy "%%f" "%To%\" >nul &&Del "%%f"

[Александр_Кот@vk]

Используем архиватор RAR. Ключ -m1 позволит задать минимальный уровень сжатия, что для бэкапа базы даст существенную экономию места при сравнительно небольших затратах по времени. Ключ -df удалит исходные файлы после успешной архивации. Конечно, возможно использовать и другие архиваторы. Код: @Echo off Set "From=\\SQL\BackUp\*.bak" Set "To=f:\SQL" Set "Arc="C:\Program Files\WinRAR\WinRAR.exe" a -m1 -df" FOR %%f IN ("%From%") DO %Arc% "%To%\%%~nxf.rar" "%%f" »

Файл архивируется и копируется, но при удалении с сервера выскакивает сообщение: "отказано в доступе" (при удалении файла)... Как приписать логин и пароль администратора, чтобы были права? Спасибо.

[megaloman]

Александр_Кот@vk, Читайте хелп команды Net use /?
Мне не на чем отладить, попробуйте перед For вставить две строки

Код:

net use \\SQL\BackUp  /Delete     
net use \\SQL\BackUp  /User:Имя_домена\Имя_пользователя

Уже не упомню, но при этом система должна спросить пароль
ИМХО, раз Вы занимаетесь такой работой и знаете пароль администратора, я бы предложил повысить Ваши права доступа до возможности удаления на ресурсе \\SQL\BackUp чтобы не компрометировать лишний раз пароль администратора.


Дополнил первый пост работой с архиватором 7z

[Александр_Кот@vk]

megaloman,
Пароль не спросило, так же добавил права к ресурсу, но результат такой же...

[megaloman]

Александр_Кот@vk, Уберите Net Use, если он еще есть, перегрузите клиентский комп, попробуйте что-нибудь ручками записать с клиентского компа в папку \\SQL\BackUp и затем удалить это. Убедитесь, что Вам хватает прав.

[Александр_Кот@vk]

megaloman, Действительно не хватало прав. Спасибо!

[megaloman]

Александр_Кот@vk, Какой вариант решения Вы выбрали? Если с архиватором, какая экономия места и какие затраты по времени, приемлемые?

[Александр_Кот@vk]

Какой вариант решения Вы выбрали? Если с архиватором, какая экономия места и какие затраты по времени, приемлемые? »

Выбрал 1-й вариант с архивацией, т.к. экономия места очень значительная... Архивы с бэкапами занимают примерно в 10 раз меньше места, а затраты по времени фактически 1к1 с обычным копированием. Большое Вам спасибо!

Код:

@Echo off
Set "From=\\SQL\BackUp\*.bak"
Set "To=f:\SQL"
Set "Arc="C:\Program Files\WinRAR\WinRAR.exe" a -m1 -df"
FOR %%f IN ("%From%") DO %Arc% "%To%\%%~nxf.rar" "%%f"