[Iska]

daradan, ясно. Давайте попробуем в первом приближении, пока без реального переименовывания:

Скрытый текст

Код:

Option Explicit

Dim strSourceFolder

Dim objFSO
Dim objFolder
Dim objSubFolder

Dim strSourceFile


If WScript.Arguments.Count = 1 Then
	strSourceFolder = WScript.Arguments.Item(0)
	
	Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
	
	If objFSO.FolderExists(strSourceFolder) Then
		For Each objFolder In objFSO.GetFolder(strSourceFolder).SubFolders
			'WScript.Echo objFolder.Name
			
			For Each objSubFolder In objFolder.SubFolders
				'WScript.Echo vbTab & objSubFolder.Name
				
				If StrComp(objFSO.GetExtensionName(objSubFolder.Name), ".apk", vbTextCompare) Then
					strSourceFile = objFSO.BuildPath(objSubFolder.Path, "AndroidManifest.xml")
					
					If objFSO.FileExists(strSourceFile) Then
						'WScript.Echo vbTab & vbTab & "[" & strSourceFile & "]"
						
						With WScript.CreateObject("Microsoft.XMLDOM")
							.load(strSourceFile)
							'WScript.Echo vbTab & vbTab & .selectSingleNode("/manifest").Attributes.getNamedItem("package").Text
							WScript.Echo "rename [" & objSubFolder.Path & "] into [" & .selectSingleNode("/manifest").Attributes.getNamedItem("package").Text & "]"
						End With
					End If
				End If
			Next
		Next
	Else
		WScript.Echo "Can't find source folder [" & strSourceFolder & "]."
		WScript.Quit 2
	End If
	
	Set objFSO = Nothing
Else
	WScript.Echo "Usage: cscript.exe //nologo """ & WScript.ScriptName & """ <Source folder>"
	WScript.Quit 1
End If

WScript.Quit 0

Это WSH VBScript. Сохраните код в файл с расширением ".vbs". Откройте командную строку и вызовите его на исполнение в виде:

Код:

cscript.exe //nologo "Путь\Имя скрипта.vbs" "Путь к исходной папке"

Посмотрите на вывод (я там в коде ввёл дополнительное условие, что папка второго уровня обязана иметь расширение «.apk»). Вам требуется именно такое переименование папок?