[habib2302]

Iska, Меня интересует батник для изменения hosts с проверкой на наличие уже существующих записей. Подскажите пример этого батника!
Нашел один пример

Код:

@ECHO OFF
TITLE Блокировка адресов, ответственных за проверку лицензий Piriform

ECHO Блокировка в файле hosts адресов, ответственных за проверку
ECHO легитимности лицензий продуктов семейства Piriform
ECHO _______________________________________________________________________
ECHO.
REN %WINDIR%\system32\drivers\etc\hosts hosts77 > nul
IF %ERRORLEVEL% NEQ 0 (
  ECHO Файл hosts заблокирован для редактирования.
  ECHO.
  ECHO Либо Вы запустили данный патч не от имени администратора,
  ECHO либо внесение изменений блокирует установленный у Вас антивирус.
  ECHO.
  ECHO.
  PAUSE
  EXIT
)
REN %WINDIR%\system32\drivers\etc\hosts77 hosts > nul
FIND /c /i "license.piriform.com" %WINDIR%\system32\drivers\etc\hosts > nul
IF %ERRORLEVEL% NEQ 0 (
  ECHO ^127.0.0.1 license.piriform.com >> %WINDIR%\system32\drivers\etc\hosts
  ECHO Адрес license.piriform.com успешно добавлен в файл hosts.
) ELSE (
  ECHO Адрес license.piriform.com уже имеется в файле hosts.
)
ECHO.
ipconfig /flushdns > nul
ECHO Кэш сопоставителя DNS успешно очищен.
ECHO _______________________________________________________________________
ECHO.
ECHO Все необходимые изменения успешно внесены!
ECHO.
ECHO.
PAUSE