[Iska]

Попробуйте так (WSH):

Скрытый текст

Код:

Option Explicit

Dim strSourceFile
Dim strContent

If WScript.Arguments.Count = 1 Then
	strSourceFile = WScript.Arguments.Item(0)
	
	With WScript.CreateObject("Scripting.FileSystemObject")
		If .FileExists(strSourceFile) Then
			With .OpenTextFile(strSourceFile)
				strContent = .ReadAll()
				.Close
			End With
			
			With WScript.CreateObject("VBScript.RegExp")
				.Global = True
				.Pattern = "\d*-\d*-\d*"
				
				If .Test(strContent) Then
					WScript.Echo .Execute(strContent).Item(0).Value
				Else
					WScript.Echo "Nothing found"
					WScript.Quit 3
				End If
			End With
		Else
			WScript.Echo "Can't find source file [" & strSourceFile & "]."
			WScript.Quit 2
		End If
	End With
Else
	WScript.Echo "Usage: wscript.exe " & WScript.ScriptName & " <Source file>"
	WScript.Quit 1
End If

WScript.Quit 0

Сохраните приведённый код в файл с расширением «.vbs». Путь к искомому файлу указывается аргументом скрипта (также можно просто перетянуть исходный файл на скрипт в Проводнике).

P.S. Содержимое результирующего окна MessageBox можно скопировать в буфер обмена просто нажав в нём «Ctrl-C»:

Скрытый текст

Код:

---------------------------
Windows Script Host
---------------------------
3213333-2342342-999
---------------------------
ОК   
---------------------------