[Nordek]

Как создать Label в окне выбора папки, и сменить заголовок окна "Обзор папок" ? »

Не понятно. Вам на странице SelectDirPage под DirEdit нужно окно для выбора месторасположения установки?

Пример:

Код:

#define AppName "My Program"

[Setup]
AppName={#AppName}
AppVersion=1.5
DefaultDirName={pf}\{#AppName}
DefaultGroupName={#AppName}

[Files]
Source: C:\Program Files\Inno Setup 5\Examples\MyProg.exe; DestDir: {app}; Flags: ignoreversion

[Code]
var
 WTV_Window: TFolderTreeView;

procedure WTV_WindowChange(Sender: TObject);
begin
 WizardForm.DirEdit.Text:=AddBackslash(WTV_Window.Directory) + '{#AppName}'
end;

procedure InitializeWizard();
begin
  WTV_Window := TFolderTreeView.Create(WizardForm);
  with WTV_Window do
  begin
    Parent := WizardForm.SelectDirPage;
    SetBounds(ScaleX(0), ScaleY(96), ScaleX(417), ScaleY(113));
    OnChange := @WTV_WindowChange;
  end;
end;

[vadjliss]

ребята подскажите как сделать что бы компонент был включен как на скрине у меня стоят компоненты через Tasks

[vint56]

vadjliss,

Пример

#define MyAppName "My Program"
#define MyAppVersion "1.5"
#define MyAppExeName "MyProg.exe"

[Setup]
AppName={#MyAppName}
AppVersion={#MyAppVersion}
DefaultDirName={pf}\{#MyAppName}
DefaultGroupName={#MyAppName}
OutputBaseFilename=setup

[Tasks]
Name: ProgFiles; Description: Program Files
Name: HelpFile; Description: Help File
Name: ReadmeFile; Description: Readme File
Name: ReadmeFile\1; Description: English; Flags: exclusive
Name: ReadmeFile\2; Description: German; Flags: exclusive

[Icons]
Name: "{group}\{cm:UninstallProgram,{#MyAppName}}"; Filename: "{uninstallexe}"
//Name: "{commondesktop}\{#MyAppName}"; Filename: "{app}\{#MyAppExeName}"; Tasks: desktopicon

[code]
procedure CurPageChanged(CurPageID: Integer);
begin
if CurPageID = wpSelectTasks then
begin
WizardForm.TasksList.Checked[0] := True;
WizardForm.TasksList.Checked[3] := True;
WizardForm.TasksList.ItemEnabled[0] := False;
WizardForm.TasksList.TreeViewStyle := True;
WizardForm.TasksList.ShowLines := True;
end;
end;

[vadjliss]

У меня вот так
#define MyAppName "My Program"
#define MyAppVersion "1.5"
#define MyAppExeName "MyProg.exe"

[Setup]
AppName={#MyAppName}
AppVersion={#MyAppVersion}
DefaultDirName={pf}\{#MyAppName}
DefaultGroupName={#MyAppName}
OutputBaseFilename=setup

[Files]
Source: soft\Microsoft Visual C++.exe; DestDir: {tmp}; Tasks: fbrinst; Flags: deleteafterinstall
Source: soft\NET Framework 4.5.2(онлайн-установка).exe; DestDir: {tmp}; Tasks: aaa; Flags: deleteafterinstall
Source: soft\NET Framework 4.6(онлайн-установка).exe; DestDir: {tmp}; Tasks: ddd; Flags: deleteafterinstall
Source: soft\DirectX (онлайн-установка).exe; DestDir: {tmp}; Tasks: bbb; Flags: deleteafterinstall


[Tasks]
Name: fbrinst; Description: "Microsoft Visual C++"
Name: aaa; Description: "NET Framework 4.5.2(онлайн-установка)"
Name: ddd; Description: "NET Framework 4.6(онлайн-установка)"
Name: bbb; Description: "DirectX (онлайн-установка)"

[Run]
Filename: {tmp}\Microsoft Visual C++.exe; Description: "Launch Firebird Setup"; Tasks: fbrinst
Filename: {tmp}\NET Framework 4.5.2(онлайн-установка).exe; Description: "Launch Firebird Setup"; Tasks: aaa
Filename: {tmp}\NET Framework 4.6(онлайн-установка).exe; Description: "Launch Firebird Setup"; Tasks: ddd
Filename: {tmp}\DirectX (онлайн-установка).exe; Description: "Launch Firebird Setup"; Tasks: bbb

[Nordek]

vadjliss,

Пример:

Код:

#define MyAppName "My Program"
#define MyAppVersion "1.5"
#define MyAppExeName "MyProg.exe"

[Setup]
AppName={#MyAppName}
AppVersion={#MyAppVersion}
DefaultDirName={pf}\{#MyAppName}
DefaultGroupName={#MyAppName}
OutputBaseFilename=setup

[Files]
Source: soft\Microsoft Visual C++.exe; DestDir: {tmp}; Tasks: fbrinst; Flags: deleteafterinstall
Source: soft\NET Framework 4.5.2(онлайн-установка).exe; DestDir: {tmp}; Tasks: aaa; Flags: deleteafterinstall
Source: soft\NET Framework 4.6(онлайн-установка).exe; DestDir: {tmp}; Tasks: ddd; Flags: deleteafterinstall
Source: soft\DirectX (онлайн-установка).exe; DestDir: {tmp}; Tasks: bbb; Flags: deleteafterinstall

[Tasks]
Name: fbrinst; Description: Microsoft Visual C++
Name: aaa; Description: NET Framework 4.5.2(онлайн-установка)
Name: ddd; Description: NET Framework 4.6(онлайн-установка)
Name: bbb; Description: DirectX (онлайн-установка)

[Run]
Filename: {tmp}\Microsoft Visual C++.exe; Description: Launch Firebird Setup; Tasks: fbrinst
Filename: {tmp}\NET Framework 4.5.2(онлайн-установка).exe; Description: Launch Firebird Setup; Tasks: aaa
Filename: {tmp}\NET Framework 4.6(онлайн-установка).exe; Description: Launch Firebird Setup; Tasks: ddd
Filename: {tmp}\DirectX (онлайн-установка).exe; Description: Launch Firebird Setup; Tasks: bbb

[Code]
procedure CurPageChanged(CurPageID: Integer);
 begin
 if CurPageID = wpSelectTasks then
    begin
      WizardForm.TasksList.Checked[0] := True;
      WizardForm.TasksList.ItemEnabled[0] := False;
      WizardForm.TasksList.Checked[2] := True;
      WizardForm.TasksList.ItemEnabled[2] := False;
    end;
end;

Также обратите внимание на сообщение #1613, коллега vint56 поправил пример.

vadjliss, Пользуйтесь тегом [CODE][/CODE] для оформления кодов Inno Setup.

[Bajuyngaonau]

Скрытый текст

; Script generated by the Inno Setup Script Wizard.
; SEE THE DOCUMENTATION FOR DETAILS ON CREATING INNO SETUP SCRIPT FILES!

#define MyAppName "My Program"
#define MyAppVersion "1.5"
#define MyAppPublisher "My Company, Inc."
#define MyAppURL "http://www.example.com/"
#define MyAppExeName "MyProg.exe"

[Setup]
; NOTE: The value of AppId uniquely identifies this application.
; Do not use the same AppId value in installers for other applications.
; (To generate a new GUID, click Tools | Generate GUID inside the IDE.)
AppId={{C5AD9121-9AE4-48DB-9913-539017B5EF4D}
AppName={#MyAppName}
AppVersion={#MyAppVersion}
;AppVerName={#MyAppName} {#MyAppVersion}
AppPublisher={#MyAppPublisher}
AppPublisherURL={#MyAppURL}
AppSupportURL={#MyAppURL}
AppUpdatesURL={#MyAppURL}
DefaultDirName={pf}\{#MyAppName}
DefaultGroupName={#MyAppName}
DisableProgramGroupPage=yes
OutputBaseFilename=setup
Compression=lzma
SolidCompression=yes
DisableWelcomePage=no
DisableReadyMemo=yes
DisableReadyPage=yes

[Languages]
Name: "english"; MessagesFile: "compiler:Default.isl"

[Tasks]
Name: "desktopicon"; Description: "{cm:CreateDesktopIcon}"; GroupDescription: "{cm:AdditionalIcons}"; Flags: unchecked

[Files]
Source: "C:\Program Files (x86)\Inno Setup 5\Examples\MyProg.exe"; DestDir: "{app}"; Flags: ignoreversion
; NOTE: Don't use "Flags: ignoreversion" on any shared system files

[Icons]
Name: "{group}\{#MyAppName}"; Filename: "{app}\{#MyAppExeName}"
Name: "{commondesktop}\{#MyAppName}"; Filename: "{app}\{#MyAppExeName}"; Tasks: desktopicon


[code]
procedure CurPageChanged(CurPageID: Integer);
begin
if (CurPageID = wpSelectDir) or (CurPageID = wpReady) then
WizardForm.NextButton.Caption := SetupMessage(msgButtonInstall)
else if (CurPageID = wpFinished) then
WizardForm.NextButton.Caption := SetupMessage(msgButtonFinish)
else
WizardForm.NextButton.Caption := SetupMessage(msgButtonNext);
end;

const
MF_BYCOMMAND = $00000000;
MF_BYPOSITION = $00000400;

type
HMENU = THandle;

function GetSystemMenu(hWnd: HWND; bRevert: BOOL): HMENU; external 'GetSystemMenu@user32.dll stdcall';
function DeleteMenu(hMenu: HMENU; uPosition, uFlags: UINT): BOOL; external 'DeleteMenu@user32.dll stdcall';
function GetMenuItemCount(hMenu: HMENU): Integer; external 'GetMenuItemCount@user32.dll stdcall';

procedure InitializeWizard;
var
SystemMenu: HMENU;
begin
SystemMenu := GetSystemMenu(WizardForm.Handle, False);
DeleteMenu(SystemMenu, 9999, MF_BYCOMMAND);
DeleteMenu(SystemMenu, GetMenuItemCount(SystemMenu)-1, MF_BYPOSITION);
end;

Куда лучше вставить эту строку : WizardForm.SelectDirBrowseLabel.Caption:= 'To continue, click Install. If you would like to select a different folder, click Browse.'; ?

P.S
Знаю что можно использовать секцию [Messages], но мне нужно чтобы было в секции [code]

[ZVSRus]

Куда лучше вставить эту строку

Вставьте после begin в procedure InitializeWizard;

[Bajuyngaonau]

Вставьте после begin в procedure InitializeWizard; »

Спасибо, в таком случаи буду использовать секцию [Message] от нужны чтобы не мешать код :

А не скажите как сделать чтобы этот код был юникодным (Преобразовать из ANSI в Unicode) ?

[ZVSRus]

А не скажите как сделать чтобы этот код был юникодным (Преобразовать из ANSI в Unicode) ?

У меня ANSI. Как преобразовать ANSI в Unicode не знаю, так-как данные действия меня не интересовали.

[Nordek]

как сделать чтобы этот код был юникодным »

Используете AkelPad.

Код:

"C:\Program Files\AkelPad\AkelPad.exe" /OpenFile("Input_ISScript.iss", 1251) /SaveFile("Output_ISScript.iss", 65001, 1) /Quit

А не скажите как сделать чтобы этот код был юникодным (Преобразовать из ANSI в Unicode) ? »

Опять от вас пользователей никакой информации.
Выдавая предложение "Преобразовать из ANSI в Unicode", какую цель преследуете?
Если для галочки, то данное действие вам ненужно т.к программа Inno версии Ansi не понимает Unicode - иначе в Inno на выходе вместо этого, получите вот это.