CMD/BAT - [решено] Определить разрядность системы и соответственно выполнить скрипт.

Foreigner · Отправлено: **16:17, 25-06-2016** | #2

Может просто так?

Код:

start firefox 
start iexplore

У меня отрабатывает без путей, хотя в %PATH% не прописаны. Нужно разобраться, что там еще есть в:

Код:

HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths

PS. ключи -private и -privatewindow не отрабатывают, браузер запускается в обычном режиме.

turbolover · Отправлено: **16:22, 25-06-2016** | #3

Цитата Foreigner:

PS. ключи -private и -privatewindow не отрабатывают, браузер запускается в обычном режиме. »

не отрабатывают потому что надо вырубить "Firefox", и потом запускать скрипт.

Foreigner · Отправлено: **16:30, 25-06-2016** | #4

turbolover, С перезапуском работает. Разрядность можно проверить наличием переменной %ProgramFiles(x86)% или значением %PROCESSOR_ARCHITECTURE%:

Код:

if defined ProgramFiles(x86) echo x64
if "%PROCESSOR_ARCHITECTURE%"=="AMD64" echo x64

Powershell:

Код:

if ([intptr]::size -eq 8) { 'x64' }

Iska · Отправлено: **16:51, 25-06-2016** | #5

Foreigner, есть ещё зависимость из-под какой подсистемы исполнять это. Уже обсуждалось ранее.

Foreigner · Отправлено: **17:12, 25-06-2016** | #6

Iska, С %PROCESSOR_ARCHITECTURE% согласен. Но %ProgramFiles(x86)% зависит не от подсистемы, а от разрядности системы.

Iska · Отправлено: **17:46, 25-06-2016** | #7

Foreigner, вообще-то, по большому, гамбургскому счёту — нет, не зависит. Точнее, только наличие данного каталога не даёт абсолютной гарантии, что ОС — x64.

Foreigner · Отправлено: **19:49, 25-06-2016** | #8

Iska, да и наличие каталога не дает гарантии.. Наверное нет решения )))

Iska · Отправлено: **22:01, 25-06-2016** | #9

Ну, меня вариант коллеги gora в принципе устраивает.

greg zakharov · Отправлено: **10:07, 26-06-2016** | #10

А как на счет определения разрядности системы по типу explorer.exe? В смысле прочитать поле MachineType самого PE:

Код:

@echo off
  setlocal enabledelayedexpansion
    rem получаем полный путь до explorer.exe
    for %%i in (explorer.exe) do (
      if exist "%%~$PATH:i" (
        rem ищем в PE поле e_lfanew структуры IMAGE_DOS_HEADER
        rem длина поля равна четырем байтам, смещение 0x3C
        for %%j in (C D E F) do (
          for /f "tokens=2" %%k in (
            'fc /b "%%~$PATH:i" "%~f0" ^| findstr /rc:"03%%j:"'
          ) do set "ofs=%%k!ofs!"
        )
        rem пропускаем сигнатуру PE\x00\x00
        set /a "ofs=0x!ofs!+4"
        rem получаем адреса двух байтов поля MachineType
        rem структуры IMAGE_FILE_HEADER и создаем из них
        rem строку - эдакий regexp для findstr
        for /l %%j in (0, 1, 1) do (
          cmd /c exit /b !ofs!
          set "str=!str!!=exitcode! "
          set /a "ofs+=1"
        )
        rem читаем значения поля MachineType
        for /f "tokens=2" %%j in (
          'fc /b "%%~$PATH:i" "%~f0" ^| findstr "!str:~0,-1!"'
        ) do set "mt=%%j!mt!"
        if "!mt!" equ "014C" echo:x86
        if "!mt!" equ "8664" echo:x64
      )
    )
  endlocal
exit /b

А если не усложнять:

Код:

wmic os get osarchitecture