[K.A.V.]

FindWindow [HWND] [Class] [Title] работает почему то далеко не со всякими окнами... Есть окна (особливо в некоторых кейгенах), где даже с элемента на элемент нельзя переместиться никакими силами (ни конкретным указанием на, как будто найденные параметры элемента, ни эмуляцией нажатий стрелок, Tab_а и пр.) »

Это зависит уже не от FindWindow, а от того, как программист реализовал работу окна с элементами, можно отключить переход по элементам по Tab и вообще, все события можно перехватывать в процедуре окна, но думаю, ты об этом уже знаешь. Так что тут нужно смотреть по конкретному приложению, как оно написано

Насчет перебора допустим, кнопок, вот вам код, как это должно выглядеть, может кому пригодится
Пример на поиске кнопок и определения их текста в окне MakeNSISW (GUI-комплиятор в папке NSIS)

Скрытый текст

Код:

!include "LogicLib.nsh"
!include "WinMessages.nsh"

Name "TEST"
OutFile "TEST.exe"
                      
Function .onInit  
      StrCpy $1 "1" ; Чтобы while с первого же раза не закрылся
      FindWindow $0 "#32770" "MakeNSISW"
      IsWindow $0 +3 0 ; проверка на существование окна
      MessageBox MB_OK|MB_ICONSTOP "Окно MakeNSISW не найдено"
      quit     
    
      ${While} $1 != "0" ; когда кнопок больше не останется - выход из цикла
        FindWindow $1 "Button" "" $0 $2 ; $0 - указываем, что мы будем искать кнопки в окне MakeNSISW, т.е. указываем окно-родителя, $2 - мы указываем предыдущую найденную кнопку, чтобы не стоять на месте с определением первой кнопки
        SendMessage $1 ${WM_GETTEXTLENGTH} 0 0 $4 ; получаем количество символом текста на кнопке
        IntOp $4 $4 + 1 ; к количеству символов текста на кнопке прибавляем 1, т.к. кнопки у нас с "&"
        System::Call 'User32::GetWindowText(i$1, t.r3, i$4)' ; получаем текст на кнопке
        StrCpy $2 $1 ; помещаем в переменную $2 HWND найденной кнопки, чтобы продолжить поиск кнопок с этой найденной кнопки
        IsWindow $1 0 +2 ; проверяем существование кнопки, чтобы в конце определения не получить лишний мессадж
        MessageBox MB_OK|MB_ICONINFORMATION "HWND кнопки: $1$\nТекст на кнопке: '$3'"
      ${EndWhile}
quit  
FunctionEnd

Section
SectionEnd

Пример на поиске кнопки "Close" в MakeNSISW (GUI-комплиятор в папке NSIS)

Скрытый текст

Код:

!include "LogicLib.nsh"
!include "WinMessages.nsh"

Name "TEST"
OutFile "TEST.exe"
                      
Function .onInit  
      StrCpy $1 "1" ; Чтобы while с первого же раза не закрылся
      FindWindow $0 "#32770" "MakeNSISW"
      IsWindow $0 +3 0 ; проверка на существование окна
      MessageBox MB_OK|MB_ICONSTOP "Окно MakeNSISW не найдено"
      quit

      ${While} $1 != "0" ; когда кнопок больше не останется - выход из цикла
        FindWindow $1 "Button" "" $0 $2 ; $0 - указываем, что мы будем искать кнопки в окне MakeNSISW, т.е. указываем окно-родителя, $2 - мы указываем предыдущую найденную кнопку, чтобы не стоять на месте с определением первой кнопки
        SendMessage $1 ${WM_GETTEXTLENGTH} 0 0 $4 ; получаем количество символом текста на кнопке
        IntOp $4 $4 + 1 ; к количеству символов текста на кнопке прибавляем 1, т.к. кнопки у нас с "&"
        System::Call 'User32::GetWindowText(i$1, t.r3, i$4)' ; получаем текст на кнопке
        StrCpy $2 $1 ; помещаем в переменную $2 HWND найденной кнопки, чтобы продолжить поиск кнопок с этой найденной кнопки
           ${If} $1 != "0" ; проверяем существование кнопки, чтобы в конце определения не входить лишний раз в if
               ${If} $3 == "&Close" ; если текст на кнопке "&Close"  - это наша кнопка 
                  MessageBox MB_YESNO|MB_ICONQUESTION "Кнопка Close найдена, нажимаем?" idno +2
                  SendMessage $1 ${BM_CLICK} 0 0
               ${EndIf}   
           ${EndIf}
      ${EndWhile} 
quit  
FunctionEnd

Section
SectionEnd